vala/valasetliteral.vala

   1 /* valasetliteral.vala
   2  *
   3  * Copyright (C) 2009-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 public class Vala.SetLiteral : Literal {
  24         private List<Expression> expression_list = new ArrayList<Expression> ();
  25
  26         public DataType element_type { get; private set; }
  27
  28         public SetLiteral (SourceReference? source_reference = null) {
  29                 this.source_reference = source_reference;
  30         }
  31
  32         public override void accept_children (CodeVisitor visitor) {
  33                 foreach (Expression expr in expression_list) {
  34                         expr.accept (visitor);
  35                 }
  36         }
  37
  38         public override void accept (CodeVisitor visitor) {
  39                 visitor.visit_set_literal (this);
  40
  41                 visitor.visit_expression (this);
  42         }
  43
  44         public void add_expression (Expression expr) {
  45                 expression_list.add (expr);
  46                 expr.parent_node = this;
  47         }
  48
  49         public List<Expression> get_expressions () {
  50                 return expression_list;
  51         }
  52
  53         public override bool is_pure () {
  54                 return false;
  55         }
  56
  57         public override void replace_expression (Expression old_node, Expression new_node) {
  58                 for (int i = 0; i < expression_list.size; i++) {
  59                         if (expression_list[i] == old_node) {
  60                                 expression_list[i] = new_node;
  61                         }
  62                 }
  63         }
  64
  65         public override bool check (CodeContext context) {
  66                 if (checked) {
  67                         return !error;
  68                 }
  69
  70                 checked = true;
  71
  72                 var set_type = new ObjectType ((Class) context.root.scope.lookup ("Dova").scope.lookup ("Set"));
  73                 set_type.value_owned = true;
  74
  75                 bool fixed_element_type = false;
  76                 if (target_type != null && target_type.data_type == set_type.data_type && target_type.get_type_arguments ().size == 1) {
  77                         element_type = target_type.get_type_arguments ().get (0).copy ();
  78                         element_type.value_owned = false;
  79                         fixed_element_type = true;
  80                 }
  81
  82                 for (int i = 0; i < expression_list.size; i++) {
  83                         var expr = expression_list[i];
  84
  85                         if (fixed_element_type) {
  86                                 expr.target_type = element_type;
  87                         }
  88                         if (!expr.check (context)) {
  89                                 return false;
  90                         }
  91
  92                         // expression might have been replaced in the list
  93                         expr = expression_list[i];
  94
  95                         if (element_type == null) {
  96                                 element_type = expr.value_type.copy ();
  97                                 element_type.value_owned = false;
  98                         }
  99                 }
 100
 101                 if (element_type == null) {
 102                         error = true;
 103                         Report.error (source_reference, "cannot infer element type for set literal");
 104                         return false;
 105                 }
 106
 107                 element_type = element_type.copy ();
 108                 element_type.value_owned = true;
 109                 set_type.add_type_argument (element_type);
 110                 value_type = set_type;
 111
 112                 return !error;
 113         }
 114
 115         public override void emit (CodeGenerator codegen) {
 116                 foreach (Expression expr in expression_list) {
 117                         expr.emit (codegen);
 118                 }
 119
 120                 codegen.visit_set_literal (this);
 121
 122                 codegen.visit_expression (this);
 123         }
 124 }