vapigen/valavapigen.vala

   1 /* valavapigen.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 class Vala.VAPIGen : Object {
  26         static string directory;
  27         static bool version;
  28         static bool quiet_mode;
  29         [CCode (array_length = false, array_null_terminated = true)]
  30         static string[] sources;
  31         [CCode (array_length = false, array_null_terminated = true)]
  32         static string[] vapi_directories;
  33         static string library;
  34         [CCode (array_length = false, array_null_terminated = true)]
  35         static string[] packages;
  36         static string metadata_filename;
  37         CodeContext context;
  38
  39         const OptionEntry[] options = {
  40                 { "vapidir", 0, 0, OptionArg.FILENAME_ARRAY, ref vapi_directories, "Look for package bindings in DIRECTORY", "DIRECTORY..." },
  41                 { "pkg", 0, 0, OptionArg.STRING_ARRAY, ref packages, "Include binding for PACKAGE", "PACKAGE..." },
  42                 { "library", 0, 0, OptionArg.STRING, ref library, "Library name", "NAME" },
  43                 { "metadata", 0, 0, OptionArg.FILENAME, ref metadata_filename, "Metadata filename", "FILE" },
  44                 { "directory", 'd', 0, OptionArg.FILENAME, ref directory, "Output directory", "DIRECTORY" },
  45                 { "version", 0, 0, OptionArg.NONE, ref version, "Display version number", null },
  46                 { "quiet", 'q', 0, OptionArg.NONE, ref quiet_mode, "Do not print messages to the console", null },
  47                 { "", 0, 0, OptionArg.FILENAME_ARRAY, ref sources, null, "FILE..." },
  48                 { null }
  49         };
  50
  51         private int quit () {
  52                 if (context.report.get_errors () == 0) {
  53                         if (!quiet_mode) {
  54                                 stdout.printf ("Generation succeeded - %d warning(s)\n", context.report.get_warnings ());
  55                         }
  56                         return 0;
  57                 } else {
  58                         if (!quiet_mode) {
  59                                 stdout.printf ("Generation failed: %d error(s), %d warning(s)\n", context.report.get_errors (), context.report.get_warnings ());
  60                         }
  61                         return 1;
  62                 }
  63         }
  64
  65         /* TODO: this is duplicated between here and the compiler. its should go somewhere on its own */
  66         private bool add_package (string pkg) {
  67                 if (context.has_package (pkg)) {
  68                         // ignore multiple occurences of the same package
  69                         return true;
  70                 }
  71
  72                 var package_path = context.get_package_path (pkg, vapi_directories);
  73
  74                 if (package_path == null) {
  75                         return false;
  76                 }
  77
  78                 context.add_package (pkg);
  79
  80                 context.add_source_file (new SourceFile (context, package_path, true));
  81
  82                 var deps_filename = Path.build_filename (Path.get_dirname (package_path), "%s.deps".printf (pkg));
  83                 if (FileUtils.test (deps_filename, FileTest.EXISTS)) {
  84                         try {
  85                                 string deps_content;
  86                                 ulong deps_len;
  87                                 FileUtils.get_contents (deps_filename, out deps_content, out deps_len);
  88                                 foreach (string dep in deps_content.split ("\n")) {
  89                                         dep = dep.strip ();
  90                                         if (dep != "") {
  91                                                 if (!add_package (dep)) {
  92                                                         Report.error (null, "%s, dependency of %s, not found in specified Vala API directories".printf (dep, pkg));
  93                                                 }
  94                                         }
  95                                 }
  96                         } catch (FileError e) {
  97                                 Report.error (null, "Unable to read dependency file: %s".printf (e.message));
  98                         }
  99                 }
 100
 101                 return true;
 102         }
 103
 104         private static string[]? get_packages_from_depsfile (string depsfile) {
 105                 try {
 106                         string contents;
 107                         FileUtils.get_contents (depsfile, out contents);
 108                         return contents.strip ().split ("\n");
 109                 } catch (FileError e) {
 110                         // deps files are optional
 111                         return null;
 112                 }
 113         }
 114
 115         private int run () {
 116                 context = new CodeContext ();
 117                 context.profile = Profile.GOBJECT;
 118                 CodeContext.push (context);
 119
 120                 /* default package */
 121                 if (!add_package ("glib-2.0")) {
 122                         Report.error (null, "glib-2.0 not found in specified Vala API directories");
 123                 }
 124                 if (!add_package ("gobject-2.0")) {
 125                         Report.error (null, "gobject-2.0 not found in specified Vala API directories");
 126                 }
 127
 128                 /* load packages from .deps file */
 129                 foreach (string source in sources) {
 130                         if (!source.has_suffix (".gi")) {
 131                                 continue;
 132                         }
 133
 134                         var depsfile = source.substring (0, source.len () - "gi".len ()) + "deps";
 135
 136                         if (!FileUtils.test (depsfile, FileTest.EXISTS)) continue;
 137
 138                         string[] deps = get_packages_from_depsfile (depsfile);
 139
 140                         foreach (string dep in deps) {
 141                                 if (!add_package (dep)) {
 142                                         Report.error (null, "%s not found in specified Vala API directories".printf (dep));
 143                                 }
 144                         }
 145                 }
 146
 147                 // depsfile for gir case
 148                 if (library != null) {
 149                         var depsfile = library + ".deps";
 150                         if (FileUtils.test (depsfile, FileTest.EXISTS)) {
 151
 152                                 string[] deps = get_packages_from_depsfile (depsfile);
 153
 154                                 foreach (string dep in deps) {
 155                                         if (!add_package (dep)) {
 156                                                 Report.error (null, "%s not found in specified Vala API directories".printf (dep));
 157                                         }
 158                                 }
 159                         }
 160                 } else {
 161                         Report.error (null, "--library option must be specified");
 162                 }
 163
 164                 if (packages != null) {
 165                         foreach (string package in packages) {
 166                                 if (!add_package (package)) {
 167                                         Report.error (null, "%s not found in specified Vala API directories".printf (package));
 168                                 }
 169                         }
 170                         packages = null;
 171                 }
 172
 173                 if (context.report.get_errors () > 0) {
 174                         return quit ();
 175                 }
 176
 177                 foreach (string source in sources) {
 178                         if (FileUtils.test (source, FileTest.EXISTS)) {
 179                                 context.add_source_file (new SourceFile (context, source, true));
 180                         } else {
 181                                 Report.error (null, "%s not found".printf (source));
 182                         }
 183                 }
 184                 sources = null;
 185
 186                 if (context.report.get_errors () > 0) {
 187                         return quit ();
 188                 }
 189
 190                 var parser = new Parser ();
 191                 parser.parse (context);
 192
 193                 if (context.report.get_errors () > 0) {
 194                         return quit ();
 195                 }
 196
 197                 var girparser = new GirParser ();
 198                 if (metadata_filename != null) {
 199                         girparser.parse_metadata (metadata_filename);
 200                 }
 201                 girparser.parse (context);
 202
 203                 if (context.report.get_errors () > 0) {
 204                         return quit ();
 205                 }
 206
 207                 var gidlparser = new GIdlParser ();
 208                 gidlparser.parse (context);
 209
 210                 if (context.report.get_errors () > 0) {
 211                         return quit ();
 212                 }
 213
 214                 var resolver = new SymbolResolver ();
 215                 resolver.resolve (context);
 216
 217                 if (context.report.get_errors () > 0) {
 218                         return quit ();
 219                 }
 220
 221                 var analyzer = new SemanticAnalyzer ();
 222                 analyzer.analyze (context);
 223
 224                 if (context.report.get_errors () > 0) {
 225                         return quit ();
 226                 }
 227
 228                 if (library == null && girparser.get_package_names () != null) {
 229                         var names = girparser.get_package_names ();
 230
 231                         if (names.length != 1) {
 232                                 Report.error (null, "multiple packages encountered and no library name given");
 233                                 return quit ();
 234                         }
 235
 236                         library = names[0];
 237                 }
 238
 239                 if (library != null) {
 240                         // interface writer ignores external packages
 241                         foreach (SourceFile file in context.get_source_files ()) {
 242                                 if (!file.filename.has_suffix (".vapi")) {
 243                                         file.external_package = false;
 244                                 }
 245                         }
 246
 247                         var interface_writer = new CodeWriter ();
 248                         interface_writer.write_file (context, "%s.vapi".printf (library));
 249
 250                         library = null;
 251                 }
 252
 253                 return quit ();
 254         }
 255
 256         static int main (string[] args) {
 257                 try {
 258                         var opt_context = new OptionContext ("- Vala API Generator");
 259                         opt_context.set_help_enabled (true);
 260                         opt_context.add_main_entries (options, null);
 261                         opt_context.parse (ref args);
 262                 } catch (OptionError e) {
 263                         stdout.printf ("%s\n", e.message);
 264                         stdout.printf ("Run '%s --help' to see a full list of available command line options.\n", args[0]);
 265                         return 1;
 266                 }
 267
 268                 if (version) {
 269                         stdout.printf ("Vala API Generator %s\n", Config.BUILD_VERSION);
 270                         return 0;
 271                 }
 272
 273                 if (sources == null) {
 274                         stderr.printf ("No source file specified.\n");
 275                         return 1;
 276                 }
 277
 278                 var vapigen = new VAPIGen ();
 279                 return vapigen.run ();
 280         }
 281 }