ccode/valaccodeforstatement.vala

   1 /* valaccodeforstatement.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24 using Gee;
  25
  26 /**
  27  * Represents a for iteration statement in the C code.
  28  */
  29 public class Vala.CCodeForStatement : CCodeStatement {
  30         /**
  31          * The loop condition.
  32          */
  33         public CCodeExpression? condition { get; set; }
  34
  35         /**
  36          * The loop body.
  37          */
  38         public CCodeStatement body { get; set; }
  39
  40         private Gee.List<CCodeExpression> initializer = new ArrayList<CCodeExpression> ();
  41         private Gee.List<CCodeExpression> iterator = new ArrayList<CCodeExpression> ();
  42
  43         public CCodeForStatement (CCodeExpression? condition, CCodeStatement? body = null) {
  44                 this.condition = condition;
  45                 this.body = body;
  46         }
  47
  48         /**
  49          * Appends the specified expression to the list of initializers.
  50          *
  51          * @param expr an initializer expression
  52          */
  53         public void add_initializer (CCodeExpression expr) {
  54                 initializer.add (expr);
  55         }
  56
  57         /**
  58          * Appends the specified expression to the iterator.
  59          *
  60          * @param expr an iterator expression
  61          */
  62         public void add_iterator (CCodeExpression expr) {
  63                 iterator.add (expr);
  64         }
  65
  66         public override void write (CCodeWriter writer) {
  67                 bool first;
  68
  69                 writer.write_indent (line);
  70                 writer.write_string ("for (");
  71
  72                 first = true;
  73                 foreach (CCodeExpression init_expr in initializer) {
  74                         if (!first) {
  75                                 writer.write_string (", ");
  76                         } else {
  77                                 first = false;
  78                         }
  79                         if (init_expr != null) {
  80                                 init_expr.write (writer);
  81                         }
  82                 }
  83
  84                 writer.write_string ("; ");
  85                 if (condition != null) {
  86                         condition.write (writer);
  87                 }
  88                 writer.write_string ("; ");
  89
  90                 first = true;
  91                 foreach (CCodeExpression it_expr in iterator) {
  92                         if (!first) {
  93                                 writer.write_string (", ");
  94                         } else {
  95                                 first = false;
  96                         }
  97                         if (it_expr != null) {
  98                                 it_expr.write (writer);
  99                         }
 100                 }
 101
 102                 writer.write_string (")");
 103                 body.write (writer);
 104         }
 105 }