ccode/valaccodestruct.vala

   1 /* valaccodestruct.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a struct declaration in the C code.
  27  */
  28 public class Vala.CCodeStruct : CCodeNode {
  29         /**
  30          * The struct name.
  31          */
  32         public string name { get; set; }
  33
  34         /**
  35          * Whether the struct is deprecated.
  36          */
  37         public bool deprecated { get; set; default = false; }
  38
  39         public bool is_empty { get { return declarations.size == 0; } }
  40
  41         private List<CCodeDeclaration> declarations = new ArrayList<CCodeDeclaration> ();
  42
  43         public CCodeStruct (string name) {
  44                 this.name = name;
  45         }
  46
  47         /**
  48          * Adds the specified declaration as member to this struct.
  49          *
  50          * @param decl a variable declaration
  51          */
  52         public void add_declaration (CCodeDeclaration decl) {
  53                 declarations.add (decl);
  54         }
  55
  56         /**
  57          * Adds a variable with the specified type and name to this struct.
  58          *
  59          * @param type_name field type
  60          * @param name      member name
  61          */
  62         public void add_field (string type_name, string name, string? declarator_suffix = null) {
  63                 var decl = new CCodeDeclaration (type_name);
  64                 decl.add_declarator (new CCodeVariableDeclarator (name, null, declarator_suffix));
  65                 add_declaration (decl);
  66         }
  67
  68         public override void write (CCodeWriter writer) {
  69                 writer.write_string ("struct ");
  70                 writer.write_string (name);
  71                 writer.write_begin_block ();
  72                 foreach (CCodeDeclaration decl in declarations) {
  73                         decl.write_declaration (writer);
  74                 }
  75
  76                 writer.write_end_block ();
  77                 if (deprecated) {
  78                         writer.write_string (" G_GNUC_DEPRECATED");
  79                 }
  80                 writer.write_string (";");
  81                 writer.write_newline ();
  82                 writer.write_newline ();
  83         }
  84 }