vala/valaattribute.vala

   1 /* valaattribute.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24 using Gee;
  25
  26 /**
  27  * Represents an attribute specified in the source code.
  28  */
  29 public class Vala.Attribute : CodeNode {
  30         /**
  31          * The name of the attribute type.
  32          */
  33         public string name { get; set; }
  34
  35         /**
  36          * Contains all specified attribute arguments.
  37          */
  38         public Gee.Map<string,Expression> args = new Gee.HashMap<string,Expression> (str_hash, str_equal);
  39
  40         /**
  41          * Creates a new attribute.
  42          *
  43          * @param name             attribute type name
  44          * @param source_reference reference to source code
  45          * @return                 newly created attribute
  46          */
  47         public Attribute (string name, SourceReference? source_reference = null) {
  48                 this.name = name;
  49                 this.source_reference = source_reference;
  50         }
  51
  52         /**
  53          * Adds an attribute argument.
  54          *
  55          * @param arg named argument
  56          */
  57         public void add_argument (string key, Expression value) {
  58                 args.set (key, value);
  59         }
  60
  61         /**
  62          * Returns whether this attribute has the specified named argument.
  63          *
  64          * @param name argument name
  65          * @return     true if the argument has been found, false otherwise
  66          */
  67         public bool has_argument (string name) {
  68                 return args.contains (name);
  69         }
  70
  71         /**
  72          * Returns the string value of the specified named argument.
  73          *
  74          * @param name argument name
  75          * @return     string value
  76          */
  77         public string? get_string (string name) {
  78                 var lit = args.get (name) as StringLiteral;
  79                 if (lit != null) {
  80                         return lit.eval ();
  81                 }
  82
  83                 return null;
  84         }
  85
  86         /**
  87          * Returns the integer value of the specified named argument.
  88          *
  89          * @param name argument name
  90          * @return     integer value
  91          */
  92         public int get_integer (string name) {
  93                 var lit = args.get (name) as IntegerLiteral;
  94                 if (lit != null) {
  95                         return lit.value.to_int ();
  96                 }
  97
  98                 return 0;
  99         }
 100
 101         /**
 102          * Returns the double value of the specified named argument.
 103          *
 104          * @param name argument name
 105          * @return     double value
 106          */
 107         public double get_double (string name) {
 108                 var arg = args.get (name);
 109                 if (arg is RealLiteral) {
 110                         var lit = (RealLiteral) arg;
 111                         return lit.value.to_double ();
 112                 } else if (arg is IntegerLiteral) {
 113                         var lit = (IntegerLiteral) arg;
 114                         return lit.value.to_int ();
 115                 } else if (arg is UnaryExpression) {
 116                         var unary = (UnaryExpression) arg;
 117                         if (unary.operator == UnaryOperator.MINUS) {
 118                                 if (unary.inner is RealLiteral) {
 119                                         var lit = (RealLiteral) unary.inner;
 120                                         return -lit.value.to_double ();
 121                                 } else if (unary.inner is IntegerLiteral) {
 122                                         var lit = (IntegerLiteral) unary.inner;
 123                                         return -lit.value.to_int ();
 124                                 }
 125                         }
 126                 }
 127
 128                 return 0;
 129         }
 130
 131         /**
 132          * Returns the boolean value of the specified named argument.
 133          *
 134          * @param name argument name
 135          * @return     boolean value
 136          */
 137         public bool get_bool (string name) {
 138                 var lit = args.get (name) as BooleanLiteral;
 139                 if (lit != null) {
 140                         return lit.value;
 141                 }
 142
 143                 return false;
 144         }
 145 }