codegen/valaccodecompiler.vala

   1 /* valaccodecompiler.vala
   2  *
   3  * Copyright (C) 2007-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Interface to the C compiler.
  27  */
  28 public class Vala.CCodeCompiler {
  29         public CCodeCompiler () {
  30         }
  31
  32         static bool package_exists(string package_name) {
  33                 string pc = "pkg-config --exists " + package_name;
  34                 int exit_status;
  35
  36                 try {
  37                         Process.spawn_command_line_sync (pc, null, null, out exit_status);
  38                         return (0 == exit_status);
  39                 } catch (SpawnError e) {
  40                         Report.error (null, e.message);
  41                         return false;
  42                 }
  43         }
  44
  45         /**
  46          * Compile generated C code to object code and optionally link object
  47          * files.
  48          *
  49          * @param context a code context
  50          */
  51         [NoArrayLength]
  52         public void compile (CodeContext context, string? cc_command, string[] cc_options) {
  53                 bool use_pkgconfig = false;
  54
  55                 string pc = "pkg-config --cflags";
  56                 if (!context.compile_only) {
  57                         pc += " --libs";
  58                 }
  59                 if (context.profile == Profile.GOBJECT) {
  60                         use_pkgconfig = true;
  61                         pc += " gobject-2.0";
  62                         if (context.thread) {
  63                                 pc += " gthread-2.0";
  64                         }
  65                 }
  66                 foreach (string pkg in context.get_packages ()) {
  67                         if (package_exists (pkg)) {
  68                                 use_pkgconfig = true;
  69                                 pc += " " + pkg;
  70                         }
  71                 }
  72                 string pkgflags = "";
  73                 if (use_pkgconfig) {
  74                         try {
  75                                 int exit_status;
  76                                 Process.spawn_command_line_sync (pc, out pkgflags, null, out exit_status);
  77                                 if (exit_status != 0) {
  78                                         Report.error (null, "pkg-config exited with status %d".printf (exit_status));
  79                                         return;
  80                                 }
  81                         } catch (SpawnError e) {
  82                                 Report.error (null, e.message);
  83                                 return;
  84                         }
  85                 }
  86
  87                 // TODO compile the C code files in parallel
  88
  89                 if (cc_command == null) {
  90                         cc_command = "cc";
  91                 }
  92                 string cmdline = cc_command;
  93                 if (context.debug) {
  94                         cmdline += " -g";
  95                 }
  96                 if (context.compile_only) {
  97                         cmdline += " -c";
  98                 } else if (context.output != null) {
  99                         string output = context.output;
 100                         if (context.directory != null && context.directory != "" && !Path.is_absolute (context.output)) {
 101                                 output = "%s%c%s".printf (context.directory, Path.DIR_SEPARATOR, context.output);
 102                         }
 103                         cmdline += " -o " + Shell.quote (output);
 104                 }
 105
 106                 /* we're only interested in non-pkg source files */
 107                 var source_files = context.get_source_files ();
 108                 foreach (SourceFile file in source_files) {
 109                         if (!file.external_package) {
 110                                 cmdline += " " + Shell.quote (file.get_csource_filename ());
 111                         }
 112                 }
 113                 var c_source_files = context.get_c_source_files ();
 114                 foreach (string file in c_source_files) {
 115                         cmdline += " " + Shell.quote (file);
 116                 }
 117
 118                 // add libraries after source files to fix linking
 119                 // with --as-needed and on Windows
 120                 cmdline += " " + pkgflags.strip ();
 121                 foreach (string cc_option in cc_options) {
 122                         cmdline += " " + Shell.quote (cc_option);
 123                 }
 124
 125                 if (context.verbose_mode) {
 126                         stdout.printf ("%s\n", cmdline);
 127                 }
 128
 129                 try {
 130                         int exit_status;
 131                         Process.spawn_command_line_sync (cmdline, null, null, out exit_status);
 132                         if (exit_status != 0) {
 133                                 Report.error (null, "cc exited with status %d".printf (exit_status));
 134                         }
 135                 } catch (SpawnError e) {
 136                         Report.error (null, e.message);
 137                 }
 138
 139                 /* remove generated C source and header files */
 140                 foreach (SourceFile file in source_files) {
 141                         if (!file.external_package) {
 142                                 if (!context.save_csources) {
 143                                         FileUtils.unlink (file.get_csource_filename ());
 144                                 }
 145                         }
 146                 }
 147         }
 148 }