vala/valainitializerlist.vala

   1 /* valainitializerlist.vala
   2  *
   3  * Copyright (C) 2006-2011  Jürg Billeter
   4  * Copyright (C) 2006-2008  Raffaele Sandrini
   5  *
   6  * This library is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10
  11  * This library is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with this library; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  19  *
  20  * Author:
  21  *      Jürg Billeter <j@bitron.ch>
  22  *      Raffaele Sandrini <raffaele@sandrini.ch>
  23  */
  24
  25 using GLib;
  26
  27 /**
  28  * Represents an array or struct initializer list in the source code.
  29  */
  30 public class Vala.InitializerList : Expression {
  31         private List<Expression> initializers = new ArrayList<Expression> ();
  32
  33         /**
  34          * Appends the specified expression to this initializer
  35          *
  36          * @param expr an expression
  37          */
  38         public void append (Expression expr) {
  39                 initializers.add (expr);
  40                 expr.parent_node = this;
  41         }
  42
  43         /**
  44          * Returns a copy of the expression
  45          *
  46          * @return expression list
  47          */
  48         public List<Expression> get_initializers () {
  49                 return initializers;
  50         }
  51
  52         /**
  53          * Returns the initializer count in this initializer
  54          */
  55         public int size {
  56                 get { return initializers.size; }
  57         }
  58
  59         /**
  60          * Creates a new initializer
  61          *
  62          * @param source_reference reference to source code
  63          * @return                 newly created initializer list
  64          */
  65         public InitializerList (SourceReference source_reference) {
  66                 this.source_reference = source_reference;
  67         }
  68
  69         public override void accept_children (CodeVisitor visitor) {
  70                 foreach (Expression expr in initializers) {
  71                         expr.accept (visitor);
  72                 }
  73         }
  74
  75         public override void accept (CodeVisitor visitor) {
  76                 visitor.visit_initializer_list (this);
  77         }
  78
  79         public override bool is_constant () {
  80                 foreach (Expression initializer in initializers) {
  81                         if (!initializer.is_constant ()) {
  82                                 return false;
  83                         }
  84                 }
  85                 return true;
  86         }
  87
  88         public override bool is_pure () {
  89                 foreach (Expression initializer in initializers) {
  90                         if (!initializer.is_pure ()) {
  91                                 return false;
  92                         }
  93                 }
  94                 return true;
  95         }
  96
  97         public override void replace_expression (Expression old_node, Expression new_node) {
  98                 for (int i = 0; i < initializers.size; i++) {
  99                         if (initializers[i] == old_node) {
 100                                 initializers[i] = new_node;
 101                         }
 102                 }
 103         }
 104
 105         public override bool check (CodeContext context) {
 106                 if (checked) {
 107                         return !error;
 108                 }
 109
 110                 checked = true;
 111
 112                 if (target_type == null) {
 113                         error = true;
 114                         Report.error (source_reference, "initializer list used for unknown type");
 115                         return false;
 116                 } else if (target_type is ArrayType) {
 117                         /* initializer is used as array initializer */
 118                         var array_type = (ArrayType) target_type;
 119
 120                         if (!(parent_node is ArrayCreationExpression)
 121                               && !(parent_node is Constant)
 122                               && !(parent_node is InitializerList)) {
 123                                 // transform shorthand form
 124                                 //     int[] array = { 42 };
 125                                 // into
 126                                 //     int[] array = new int[] { 42 };
 127
 128                                 var old_parent_node = parent_node;
 129
 130                                 var array_creation = new ArrayCreationExpression (array_type.element_type.copy (), array_type.rank, this, source_reference);
 131                                 array_creation.target_type = target_type;
 132                                 old_parent_node.replace_expression (this, array_creation);
 133
 134                                 checked = false;
 135                                 return array_creation.check (context);
 136                         }
 137
 138                         DataType inner_target_type;
 139                         if (array_type.rank > 1) {
 140                                 // allow initialization of multi-dimensional arrays
 141                                 var inner_array_type = (ArrayType) array_type.copy ();
 142                                 inner_array_type.rank--;
 143                                 inner_target_type = inner_array_type;
 144                         } else {
 145                                 inner_target_type = array_type.element_type.copy ();
 146                         }
 147
 148                         foreach (Expression e in get_initializers ()) {
 149                                 e.target_type = inner_target_type;
 150                         }
 151                 } else if (target_type.data_type is Struct) {
 152                         /* initializer is used as struct initializer */
 153                         var st = (Struct) target_type.data_type;
 154
 155                         var field_it = st.get_fields ().iterator ();
 156                         foreach (Expression e in get_initializers ()) {
 157                                 Field field = null;
 158                                 while (field == null) {
 159                                         if (!field_it.next ()) {
 160                                                 error = true;
 161                                                 Report.error (e.source_reference, "too many expressions in initializer list for `%s'".printf (target_type.to_string ()));
 162                                                 return false;
 163                                         }
 164                                         field = field_it.get ();
 165                                         if (field.binding != MemberBinding.INSTANCE) {
 166                                                 // we only initialize instance fields
 167                                                 field = null;
 168                                         }
 169                                 }
 170
 171                                 e.target_type = field.variable_type.copy ();
 172                                 if (!target_type.value_owned) {
 173                                         e.target_type.value_owned = false;
 174                                 }
 175                         }
 176                 } else {
 177                         error = true;
 178                         Report.error (source_reference, "initializer list used for `%s', which is neither array nor struct".printf (target_type.to_string ()));
 179                         return false;
 180                 }
 181
 182                 foreach (Expression expr in initializers) {
 183                         expr.check (context);
 184                 }
 185
 186                 bool error = false;
 187                 foreach (Expression e in get_initializers ()) {
 188                         if (e.value_type == null) {
 189                                 error = true;
 190                                 Report.error (e.source_reference, "expression type not allowed as initializer");
 191                                 continue;
 192                         }
 193
 194                         var unary = e as UnaryExpression;
 195                         if (unary != null && (unary.operator == UnaryOperator.REF || unary.operator == UnaryOperator.OUT)) {
 196                                 // TODO check type for ref and out expressions
 197                         } else if (!e.value_type.compatible (e.target_type)) {
 198                                 error = true;
 199                                 e.error = true;
 200                                 Report.error (e.source_reference, "Expected initializer of type `%s' but got `%s'".printf (e.target_type.to_string (), e.value_type.to_string ()));
 201                         }
 202                 }
 203
 204                 if (!error) {
 205                         /* everything seems to be correct */
 206                         value_type = target_type;
 207                 }
 208
 209                 return !error;
 210         }
 211
 212         public override void emit (CodeGenerator codegen) {
 213                 foreach (Expression expr in initializers) {
 214                         expr.emit (codegen);
 215                 }
 216
 217                 codegen.visit_initializer_list (this);
 218         }
 219 }