vala/valaattribute.vala

   1 /* valaattribute.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an attribute specified in the source code.
  27  */
  28 public class Vala.Attribute : CodeNode {
  29         /**
  30          * The name of the attribute type.
  31          */
  32         public string name { get; set; }
  33
  34         /**
  35          * Contains all specified attribute arguments.
  36          */
  37         public Vala.Map<string,Expression> args = new HashMap<string,Expression> (str_hash, str_equal);
  38
  39         /**
  40          * Creates a new attribute.
  41          *
  42          * @param name             attribute type name
  43          * @param source_reference reference to source code
  44          * @return                 newly created attribute
  45          */
  46         public Attribute (string name, SourceReference? source_reference = null) {
  47                 this.name = name;
  48                 this.source_reference = source_reference;
  49         }
  50
  51         /**
  52          * Adds an attribute argument.
  53          *
  54          * @param arg named argument
  55          */
  56         public void add_argument (string key, Expression value) {
  57                 args.set (key, value);
  58         }
  59
  60         /**
  61          * Returns whether this attribute has the specified named argument.
  62          *
  63          * @param name argument name
  64          * @return     true if the argument has been found, false otherwise
  65          */
  66         public bool has_argument (string name) {
  67                 return args.contains (name);
  68         }
  69
  70         /**
  71          * Returns the string value of the specified named argument.
  72          *
  73          * @param name argument name
  74          * @return     string value
  75          */
  76         public string? get_string (string name) {
  77                 var lit = args.get (name) as StringLiteral;
  78                 if (lit != null) {
  79                         return lit.eval ();
  80                 }
  81
  82                 return null;
  83         }
  84
  85         /**
  86          * Returns the integer value of the specified named argument.
  87          *
  88          * @param name argument name
  89          * @return     integer value
  90          */
  91         public int get_integer (string name) {
  92                 var lit = args.get (name) as IntegerLiteral;
  93                 if (lit != null) {
  94                         return lit.value.to_int ();
  95                 }
  96
  97                 return 0;
  98         }
  99
 100         /**
 101          * Returns the double value of the specified named argument.
 102          *
 103          * @param name argument name
 104          * @return     double value
 105          */
 106         public double get_double (string name) {
 107                 var arg = args.get (name);
 108                 if (arg is RealLiteral) {
 109                         var lit = (RealLiteral) arg;
 110                         return lit.value.to_double ();
 111                 } else if (arg is IntegerLiteral) {
 112                         var lit = (IntegerLiteral) arg;
 113                         return lit.value.to_int ();
 114                 } else if (arg is UnaryExpression) {
 115                         var unary = (UnaryExpression) arg;
 116                         if (unary.operator == UnaryOperator.MINUS) {
 117                                 if (unary.inner is RealLiteral) {
 118                                         var lit = (RealLiteral) unary.inner;
 119                                         return -lit.value.to_double ();
 120                                 } else if (unary.inner is IntegerLiteral) {
 121                                         var lit = (IntegerLiteral) unary.inner;
 122                                         return -lit.value.to_int ();
 123                                 }
 124                         }
 125                 }
 126
 127                 return 0;
 128         }
 129
 130         /**
 131          * Returns the boolean value of the specified named argument.
 132          *
 133          * @param name argument name
 134          * @return     boolean value
 135          */
 136         public bool get_bool (string name) {
 137                 var lit = args.get (name) as BooleanLiteral;
 138                 if (lit != null) {
 139                         return lit.value;
 140                 }
 141
 142                 return false;
 143         }
 144 }