vala/valaswitchsection.vala

   1 /* valaswitchsection.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a switch section in the source code.
  27  */
  28 public class Vala.SwitchSection : Block {
  29         private List<SwitchLabel> labels = new ArrayList<SwitchLabel> ();
  30
  31         /**
  32          * Creates a new switch section.
  33          *
  34          * @param source_reference reference to source code
  35          * @return                 newly created switch section
  36          */
  37         public SwitchSection (SourceReference? source_reference) {
  38                 base (source_reference);
  39         }
  40
  41         /**
  42          * Appends the specified label to the list of switch labels.
  43          *
  44          * @param label a switch label
  45          */
  46         public void add_label (SwitchLabel label) {
  47                 labels.add (label);
  48                 label.section = this;
  49         }
  50
  51         /**
  52          * Returns a copy of the list of switch labels.
  53          *
  54          * @return switch label list
  55          */
  56         public List<SwitchLabel> get_labels () {
  57                 return labels;
  58         }
  59
  60         public bool has_default_label () {
  61                 foreach (SwitchLabel label in labels) {
  62                         if (label.expression == null) {
  63                                 return true;
  64                         }
  65                 }
  66
  67                 return false;
  68         }
  69
  70         public override void accept (CodeVisitor visitor) {
  71                 visitor.visit_switch_section (this);
  72         }
  73
  74         public override void accept_children (CodeVisitor visitor) {
  75                 foreach (SwitchLabel label in labels) {
  76                         label.accept (visitor);
  77                 }
  78
  79                 foreach (Statement st in get_statements ()) {
  80                         st.accept (visitor);
  81                 }
  82         }
  83
  84         public override bool check (CodeContext context) {
  85                 if (checked) {
  86                         return !error;
  87                 }
  88
  89                 checked = true;
  90
  91                 foreach (SwitchLabel label in get_labels ()) {
  92                         label.check (context);
  93                 }
  94
  95                 owner = context.analyzer.current_symbol.scope;
  96
  97                 var old_symbol = context.analyzer.current_symbol;
  98                 var old_insert_block = context.analyzer.insert_block;
  99                 context.analyzer.current_symbol = this;
 100                 context.analyzer.insert_block = this;
 101
 102                 foreach (Statement st in get_statements ()) {
 103                         st.check (context);
 104                 }
 105
 106                 foreach (LocalVariable local in get_local_variables ()) {
 107                         local.active = false;
 108                 }
 109
 110                 // use get_statements () instead of statement_list to not miss errors within StatementList objects
 111                 foreach (Statement stmt in get_statements ()) {
 112                         add_error_types (stmt.get_error_types ());
 113                 }
 114
 115                 context.analyzer.current_symbol = old_symbol;
 116                 context.analyzer.insert_block = old_insert_block;
 117
 118                 return !error;
 119         }
 120
 121         public override void emit (CodeGenerator codegen) {
 122                 foreach (SwitchLabel label in labels) {
 123                         label.emit (codegen);
 124                 }
 125
 126                 base.emit (codegen);
 127         }
 128 }