vala/valacodenode.vala

   1 /* valacodenode.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a part of the parsed source code.
  27  *
  28  * Code nodes get created by the parser and are used throughout the whole
  29  * compilation process.
  30  */
  31 public abstract class Vala.CodeNode {
  32         /**
  33          * Parent of this code node.
  34          */
  35         public weak CodeNode? parent_node { get; set; }
  36
  37         /**
  38          * References the location in the source file where this code node has
  39          * been written.
  40          */
  41         public SourceReference? source_reference { get; set; }
  42
  43         public bool unreachable { get; set; }
  44
  45         /**
  46          * Contains all attributes that have been specified for this code node.
  47          */
  48         public GLib.List<Attribute> attributes;
  49
  50         public string type_name {
  51                 get { return Type.from_instance (this).name (); }
  52         }
  53
  54         public bool checked { get; set; }
  55
  56         /**
  57          * Specifies whether a fatal error has been detected in this code node.
  58          */
  59         public bool error { get; set; }
  60
  61         /**
  62          * Specifies that this node or a child node may throw an exception.
  63          */
  64         public bool tree_can_fail {
  65                 get { return _error_types != null && _error_types.size > 0; }
  66         }
  67
  68         private List<DataType> _error_types;
  69         private static List<DataType> _empty_type_list;
  70
  71         static int last_temp_nr = 0;
  72
  73         /**
  74          * Specifies the exceptions that can be thrown by this node or a child node
  75          */
  76         public List<DataType> get_error_types () {
  77                 if (_error_types != null) {
  78                         return _error_types;
  79                 }
  80                 if (_empty_type_list == null) {
  81                         _empty_type_list = new ArrayList<DataType> ();
  82                 }
  83                 return _empty_type_list;
  84         }
  85
  86         /**
  87          * Adds an error type to the exceptions that can be thrown by this node
  88          * or a child node
  89          */
  90         public void add_error_type (DataType error_type) {
  91                 if (_error_types == null) {
  92                         _error_types = new ArrayList<DataType> ();
  93                 }
  94                 _error_types.add (error_type);
  95                 error_type.parent_node = this;
  96         }
  97
  98         /**
  99          * Adds a collection of error types to the exceptions that can be thrown by this node
 100          * or a child node
 101          */
 102         public void add_error_types (List<DataType> error_types) {
 103                 foreach (DataType error_type in error_types) {
 104                         add_error_type (error_type);
 105                 }
 106         }
 107
 108         /**
 109          * Visits this code node with the specified CodeVisitor.
 110          *
 111          * @param visitor the visitor to be called while traversing
 112          */
 113         public virtual void accept (CodeVisitor visitor) {
 114         }
 115
 116         /**
 117          * Visits all children of this code node with the specified CodeVisitor.
 118          *
 119          * @param visitor the visitor to be called while traversing
 120          */
 121         public virtual void accept_children (CodeVisitor visitor) {
 122         }
 123
 124         public virtual bool check (SemanticAnalyzer analyzer) {
 125                 return true;
 126         }
 127
 128         public virtual void emit (CodeGenerator codegen) {
 129         }
 130
 131         public virtual void replace_type (DataType old_type, DataType new_type) {
 132         }
 133
 134         public virtual void replace_expression (Expression old_node, Expression new_node) {
 135         }
 136
 137         /**
 138          * Returns the specified attribute.
 139          *
 140          * @param name attribute name
 141          * @return     attribute
 142          */
 143         public Attribute? get_attribute (string name) {
 144                 // FIXME: use hash table
 145                 foreach (Attribute a in attributes) {
 146                         if (a.name == name) {
 147                                 return a;
 148                         }
 149                 }
 150
 151                 return null;
 152         }
 153
 154         /**
 155          * Returns a string that represents this code node.
 156          *
 157          * @return a string representation
 158          */
 159         public virtual string to_string () {
 160                 var str = new StringBuilder ();
 161
 162                 str.append ("/* ");
 163
 164                 if (source_reference != null) {
 165                         str.append ("@").append (source_reference.to_string ());
 166                 }
 167
 168                 return str.append (" */").str;
 169         }
 170
 171         public virtual void get_defined_variables (Collection<LocalVariable> collection) {
 172         }
 173
 174         public virtual void get_used_variables (Collection<LocalVariable> collection) {
 175         }
 176
 177         public static string get_temp_name () {
 178                 return "." + (++last_temp_nr).to_string ();
 179         }
 180 }