vala/valaunaryexpression.vala

   1 /* valaunaryexpression.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23
  24 /**
  25  * Represents an expression with one operand in the source code.
  26  *
  27  * Supports +, -, !, ~, ref, out.
  28  */
  29 public class Vala.UnaryExpression : Expression {
  30         /**
  31          * The unary operator.
  32          */
  33         public UnaryOperator operator { get; set; }
  34
  35         /**
  36          * The operand.
  37          */
  38         public Expression inner {
  39                 get {
  40                         return _inner;
  41                 }
  42                 set {
  43                         _inner = value;
  44                         _inner.parent_node = this;
  45                 }
  46         }
  47
  48         private Expression _inner;
  49
  50         /**
  51          * Creates a new unary expression.
  52          *
  53          * @param op     unary operator
  54          * @param inner  operand
  55          * @param source reference to source code
  56          * @return       newly created binary expression
  57          */
  58         public UnaryExpression (UnaryOperator op, Expression _inner, SourceReference source) {
  59                 operator = op;
  60                 inner = _inner;
  61                 source_reference = source;
  62         }
  63
  64         public override void accept (CodeVisitor visitor) {
  65                 visitor.visit_unary_expression (this);
  66
  67                 visitor.visit_expression (this);
  68         }
  69
  70         public override void accept_children (CodeVisitor visitor) {
  71                 inner.accept (visitor);
  72         }
  73
  74         public override void replace_expression (Expression old_node, Expression new_node) {
  75                 if (inner == old_node) {
  76                         inner = new_node;
  77                 }
  78         }
  79
  80         private string get_operator_string () {
  81                 switch (_operator) {
  82                 case UnaryOperator.PLUS: return "+";
  83                 case UnaryOperator.MINUS: return "-";
  84                 case UnaryOperator.LOGICAL_NEGATION: return "!";
  85                 case UnaryOperator.BITWISE_COMPLEMENT: return "~";
  86                 case UnaryOperator.INCREMENT: return "++";
  87                 case UnaryOperator.DECREMENT: return "--";
  88                 case UnaryOperator.REF: return "ref ";
  89                 case UnaryOperator.OUT: return "out ";
  90                 default: assert_not_reached ();
  91                 }
  92         }
  93
  94         public override string to_string () {
  95                 return get_operator_string () + _inner.to_string ();
  96         }
  97
  98         public override bool is_constant () {
  99                 if (operator == UnaryOperator.INCREMENT || operator == UnaryOperator.DECREMENT) {
 100                         return false;
 101                 }
 102
 103                 return inner.is_constant ();
 104         }
 105
 106         public override bool is_pure () {
 107                 if (operator == UnaryOperator.INCREMENT || operator == UnaryOperator.DECREMENT) {
 108                         return false;
 109                 }
 110
 111                 return inner.is_pure ();
 112         }
 113
 114         bool is_numeric_type (DataType type) {
 115                 if (!(type.data_type is Struct)) {
 116                         return false;
 117                 }
 118
 119                 var st = (Struct) type.data_type;
 120                 return st.is_integer_type () || st.is_floating_type ();
 121         }
 122
 123         bool is_integer_type (DataType type) {
 124                 if (!(type.data_type is Struct)) {
 125                         return false;
 126                 }
 127
 128                 var st = (Struct) type.data_type;
 129                 return st.is_integer_type ();
 130         }
 131
 132         MemberAccess? find_member_access (Expression expr) {
 133                 if (expr is MemberAccess) {
 134                         return (MemberAccess) expr;
 135                 }
 136
 137                 return null;
 138         }
 139
 140         public override bool check (CodeContext context) {
 141                 if (checked) {
 142                         return !error;
 143                 }
 144
 145                 checked = true;
 146
 147                 if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 148                         inner.lvalue = true;
 149                         inner.target_type = target_type;
 150                 }
 151
 152                 if (!inner.check (context)) {
 153                         /* if there was an error in the inner expression, skip type check */
 154                         error = true;
 155                         return false;
 156                 }
 157
 158                 if (inner.value_type is FieldPrototype) {
 159                         error = true;
 160                         Report.error (inner.source_reference, "Access to instance member `%s' denied".printf (inner.symbol_reference.get_full_name ()));
 161                         return false;
 162                 }
 163
 164                 if (operator == UnaryOperator.PLUS || operator == UnaryOperator.MINUS) {
 165                         // integer or floating point type
 166                         if (!is_numeric_type (inner.value_type)) {
 167                                 error = true;
 168                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 169                                 return false;
 170                         }
 171
 172                         value_type = inner.value_type;
 173                 } else if (operator == UnaryOperator.LOGICAL_NEGATION) {
 174                         // boolean type
 175                         if (!inner.value_type.compatible (context.analyzer.bool_type)) {
 176                                 error = true;
 177                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 178                                 return false;
 179                         }
 180
 181                         value_type = inner.value_type;
 182                 } else if (operator == UnaryOperator.BITWISE_COMPLEMENT) {
 183                         // integer type
 184                         if (!is_integer_type (inner.value_type) && !(inner.value_type is EnumValueType)) {
 185                                 error = true;
 186                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 187                                 return false;
 188                         }
 189
 190                         value_type = inner.value_type;
 191                 } else if (operator == UnaryOperator.INCREMENT ||
 192                            operator == UnaryOperator.DECREMENT) {
 193                         // integer type
 194                         if (!is_integer_type (inner.value_type)) {
 195                                 error = true;
 196                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 197                                 return false;
 198                         }
 199
 200                         var ma = find_member_access (inner);
 201                         if (ma == null) {
 202                                 error = true;
 203                                 Report.error (source_reference, "Prefix operators not supported for this expression");
 204                                 return false;
 205                         }
 206
 207                         var old_value = new MemberAccess (ma.inner, ma.member_name, inner.source_reference);
 208                         var bin = new BinaryExpression (operator == UnaryOperator.INCREMENT ? BinaryOperator.PLUS : BinaryOperator.MINUS, old_value, new IntegerLiteral ("1"), source_reference);
 209
 210                         var assignment = new Assignment (ma, bin, AssignmentOperator.SIMPLE, source_reference);
 211                         assignment.target_type = target_type;
 212                         context.analyzer.replaced_nodes.add (this);
 213                         parent_node.replace_expression (this, assignment);
 214                         assignment.check (context);
 215                         return true;
 216                 } else if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 217                         var ea = inner as ElementAccess;
 218                         if (inner.symbol_reference is Field || inner.symbol_reference is Parameter || inner.symbol_reference is LocalVariable ||
 219                             (ea != null && ea.container.value_type is ArrayType)) {
 220                                 // ref and out can only be used with fields, parameters, local variables, and array element access
 221                                 lvalue = true;
 222                                 value_type = inner.value_type;
 223                         } else {
 224                                 error = true;
 225                                 Report.error (source_reference, "ref and out method arguments can only be used with fields, parameters, local variables, and array element access");
 226                                 return false;
 227                         }
 228                 } else {
 229                         error = true;
 230                         Report.error (source_reference, "internal error: unsupported unary operator");
 231                         return false;
 232                 }
 233
 234                 return !error;
 235         }
 236
 237         public override void emit (CodeGenerator codegen) {
 238                 inner.emit (codegen);
 239
 240                 codegen.visit_unary_expression (this);
 241
 242                 codegen.visit_expression (this);
 243         }
 244
 245         public override void get_defined_variables (Collection<LocalVariable> collection) {
 246                 inner.get_defined_variables (collection);
 247                 if (operator == UnaryOperator.OUT || operator == UnaryOperator.REF) {
 248                         var local = inner.symbol_reference as LocalVariable;
 249                         if (local != null) {
 250                                 collection.add (local);
 251                         }
 252                 }
 253         }
 254
 255         public override void get_used_variables (Collection<LocalVariable> collection) {
 256                 if (operator != UnaryOperator.OUT) {
 257                         inner.get_used_variables (collection);
 258                 }
 259         }
 260 }
 261
 262 public enum Vala.UnaryOperator {
 263         NONE,
 264         PLUS,
 265         MINUS,
 266         LOGICAL_NEGATION,
 267         BITWISE_COMPLEMENT,
 268         INCREMENT,
 269         DECREMENT,
 270         REF,
 271         OUT
 272 }