vala/valaenumvalue.vala

   1 /* valaenumvalue.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an enum member in the source code.
  27  */
  28 public class Vala.EnumValue : Symbol {
  29         /**
  30          * Specifies the numerical representation of this enum value.
  31          */
  32         public Expression value { get; set; }
  33
  34         public Comment comment { get; set; }
  35
  36         private string cname;
  37
  38         /**
  39          * Creates a new enum value.
  40          *
  41          * @param name enum value name
  42          * @return     newly created enum value
  43          */
  44         public EnumValue (string name, SourceReference? source_reference = null, Comment? comment = null) {
  45                 base (name, source_reference);
  46                 this.comment = comment;
  47         }
  48
  49         /**
  50          * Creates a new enum value with the specified numerical representation.
  51          *
  52          * @param name  enum value name
  53          * @param value numerical representation
  54          * @return      newly created enum value
  55          */
  56         public EnumValue.with_value (string name, Expression value, SourceReference? source_reference = null, Comment? comment = null) {
  57                 this (name, source_reference, comment);
  58                 this.value = value;
  59         }
  60
  61         /**
  62          * Returns the string literal of this signal to be used in C code.
  63          * (FIXME: from vlaasignal.vala)
  64          *
  65          * @return string literal to be used in C code
  66          */
  67         public CCodeConstant get_canonical_cconstant () {
  68                 var str = new StringBuilder ("\"");
  69
  70                 string i = name;
  71
  72                 while (i.len () > 0) {
  73                         unichar c = i.get_char ();
  74                         if (c == '_') {
  75                                 str.append_c ('-');
  76                         } else {
  77                                 str.append_unichar (c.tolower ());
  78                         }
  79
  80                         i = i.next_char ();
  81                 }
  82
  83                 str.append_c ('"');
  84
  85                 return new CCodeConstant (str.str);
  86         }
  87
  88         public override void accept (CodeVisitor visitor) {
  89                 visitor.visit_enum_value (this);
  90         }
  91
  92         public override void accept_children (CodeVisitor visitor) {
  93                 if (value != null) {
  94                         value.accept (visitor);
  95                 }
  96         }
  97
  98         /**
  99          * Process all associated attributes.
 100          */
 101         public void process_attributes () {
 102                 foreach (Attribute a in attributes) {
 103                         if (a.name == "CCode" && a.has_argument("cname")) {
 104                                 cname = a.get_string ("cname");
 105                         }
 106                 }
 107         }
 108
 109         /**
 110          * Returns the name of this enum value as it is used in C code.
 111          *
 112          * @return the name to be used in C code
 113          */
 114         public string get_cname () {
 115                 if (cname == null) {
 116                         cname = get_default_cname ();
 117                 }
 118                 return cname;
 119         }
 120
 121         public string get_default_cname () {
 122                 var en = (Enum) parent_symbol;
 123                 return "%s%s".printf (en.get_cprefix (), name);
 124         }
 125
 126         /**
 127          * Sets the name of this enum value to be used in C code.
 128          *
 129          * @param cname the name to be used in C code
 130          */
 131         public void set_cname (string cname) {
 132                 this.cname = cname;
 133         }
 134
 135         public override bool check (SemanticAnalyzer analyzer) {
 136                 if (checked) {
 137                         return !error;
 138                 }
 139
 140                 checked = true;
 141
 142                 process_attributes ();
 143
 144                 if (value != null) {
 145                         value.check (analyzer);
 146                 }
 147
 148                 return !error;
 149         }
 150 }