vala/valatypecheck.vala

   1 /* valatypecheck.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a type check (`is') expression in the source code.
  27  */
  28 public class Vala.TypeCheck : Expression {
  29         /**
  30          * The expression to be checked.
  31          */
  32         public Expression expression {
  33                 get { return _expression; }
  34                 set {
  35                         _expression = value;
  36                         _expression.parent_node = this;
  37                 }
  38         }
  39
  40         /**
  41          * The type to be matched against.
  42          */
  43         public DataType type_reference {
  44                 get { return _data_type; }
  45                 set {
  46                         _data_type = value;
  47                         _data_type.parent_node = this;
  48                 }
  49         }
  50
  51         Expression _expression;
  52         private DataType _data_type;
  53
  54         /**
  55          * Creates a new type check expression.
  56          *
  57          * @param expr   an expression
  58          * @param type   a data type
  59          * @param source reference to source code
  60          * @return       newly created type check expression
  61          */
  62         public TypeCheck (Expression expr, DataType type, SourceReference source) {
  63                 expression = expr;
  64                 type_reference = type;
  65                 source_reference = source;
  66         }
  67
  68         public override void accept (CodeVisitor visitor) {
  69                 expression.accept (visitor);
  70
  71                 type_reference.accept (visitor);
  72
  73                 visitor.visit_type_check (this);
  74
  75                 visitor.visit_expression (this);
  76         }
  77
  78         public override bool is_pure () {
  79                 return expression.is_pure ();
  80         }
  81
  82         public override void replace_type (DataType old_type, DataType new_type) {
  83                 if (type_reference == old_type) {
  84                         type_reference = new_type;
  85                 }
  86         }
  87
  88         public override void replace_expression (Expression old_node, Expression new_node) {
  89                 if (expression == old_node) {
  90                         expression = new_node;
  91                 }
  92         }
  93
  94         public override bool check (SemanticAnalyzer analyzer) {
  95                 if (checked) {
  96                         return !error;
  97                 }
  98
  99                 checked = true;
 100
 101                 expression.check (analyzer);
 102
 103                 type_reference.check (analyzer);
 104
 105                 if (type_reference.data_type == null) {
 106                         /* if type resolving didn't succeed, skip this check */
 107                         error = true;
 108                         return false;
 109                 }
 110
 111                 value_type = analyzer.bool_type;
 112
 113                 return !error;
 114         }
 115 }