ccode/valaccodefunction.vala

   1 /* valaccodefunction.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a function declaration in the C code.
  27  */
  28 public class Vala.CCodeFunction : CCodeNode {
  29         /**
  30          * The name of this function.
  31          */
  32         public string name { get; set; }
  33
  34         /**
  35          * The function modifiers.
  36          */
  37         public CCodeModifiers modifiers { get; set; }
  38
  39         /**
  40          * The function return type.
  41          */
  42         public string return_type { get; set; }
  43
  44         /**
  45          * The function body.
  46          */
  47         public CCodeBlock block { get; set; }
  48
  49         private List<CCodeFormalParameter> parameters = new ArrayList<CCodeFormalParameter> ();
  50
  51         public CCodeFunction (string name, string return_type = "void") {
  52                 this.name = name;
  53                 this.return_type = return_type;
  54         }
  55
  56         /**
  57          * Appends the specified parameter to the list of function parameters.
  58          *
  59          * @param param a formal parameter
  60          */
  61         public void add_parameter (CCodeFormalParameter param) {
  62                 parameters.add (param);
  63         }
  64
  65         /**
  66          * Returns a copy of this function.
  67          *
  68          * @return copied function
  69          */
  70         public CCodeFunction copy () {
  71                 var func = new CCodeFunction (name, return_type);
  72                 func.modifiers = modifiers;
  73
  74                 /* no deep copy for lists available yet
  75                  * func.parameters = parameters.copy ();
  76                  */
  77                 foreach (CCodeFormalParameter param in parameters) {
  78                         func.parameters.add (param);
  79                 }
  80
  81                 func.block = block;
  82                 return func;
  83         }
  84
  85         public override void write (CCodeWriter writer) {
  86                 writer.write_indent (line);
  87                 if (CCodeModifiers.STATIC in modifiers) {
  88                         writer.write_string ("static ");
  89                 }
  90                 if (CCodeModifiers.INLINE in modifiers) {
  91                         writer.write_string ("inline ");
  92                 }
  93                 writer.write_string (return_type);
  94                 writer.write_string (" ");
  95                 writer.write_string (name);
  96                 writer.write_string (" (");
  97
  98                 bool first = true;
  99                 foreach (CCodeFormalParameter param in parameters) {
 100                         if (!first) {
 101                                 writer.write_string (", ");
 102                         } else {
 103                                 first = false;
 104                         }
 105                         param.write (writer);
 106                 }
 107                 if (first) {
 108                         writer.write_string ("void");
 109                 }
 110
 111                 writer.write_string (")");
 112                 if (block == null) {
 113                         writer.write_string (";");
 114                 } else {
 115                         block.write (writer);
 116                         writer.write_newline ();
 117                 }
 118                 writer.write_newline ();
 119         }
 120 }