ccode/valaccodewriter.vala

   1 /* valaccodewriter.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a writer to write C source files.
  27  */
  28 public class Vala.CCodeWriter {
  29         /**
  30          * Specifies the file to be written.
  31          */
  32         public string filename { get; set; }
  33
  34         /**
  35          * Specifies the source file used to generate this one.
  36          */
  37         private string source_filename;
  38
  39         /**
  40          * Specifies whether to emit line directives.
  41          */
  42         public bool line_directives { get; set; }
  43
  44         /**
  45          * Specifies whether the output stream is at the beginning of a line.
  46          */
  47         public bool bol {
  48                 get { return _bol; }
  49         }
  50
  51         private string temp_filename;
  52         private bool file_exists;
  53
  54         private FileStream stream;
  55
  56         private int indent;
  57         private int current_line_number = 1;
  58         private bool using_line_directive;
  59
  60         /* at begin of line */
  61         private bool _bol = true;
  62
  63         public CCodeWriter (string filename, string? source_filename = null) {
  64                 this.filename = filename;
  65                 this.source_filename = source_filename;
  66         }
  67
  68         /**
  69          * Opens the file.
  70          *
  71          * @return true if the file has been opened successfully,
  72          *         false otherwise
  73          */
  74         public bool open () {
  75                 file_exists = FileUtils.test (filename, FileTest.EXISTS);
  76                 if (file_exists) {
  77                         temp_filename = "%s.valatmp".printf (filename);
  78                         stream = FileStream.open (temp_filename, "w");
  79                 } else {
  80                         stream = FileStream.open (filename, "w");
  81                 }
  82
  83                 write_string ("/* %s generated by valac, the Vala compiler".printf (Path.get_basename (filename)));
  84
  85                 // Write the file name if known
  86                 if (source_filename != null) {
  87                         write_newline ();
  88                         write_string (" * generated from %s".printf (Path.get_basename (source_filename)));
  89                 }
  90
  91                 write_string (", do not modify */");
  92                 write_newline ();
  93                 write_newline ();
  94
  95                 return (stream != null);
  96         }
  97
  98         /**
  99          * Closes the file.
 100          */
 101         public void close () {
 102                 stream = null;
 103
 104                 if (file_exists) {
 105                         var changed = true;
 106
 107                         try {
 108                                 var old_file = new MappedFile (filename, false);
 109                                 var new_file = new MappedFile (temp_filename, false);
 110                                 var len = old_file.get_length ();
 111                                 if (len == new_file.get_length ()) {
 112                                         if (Memory.cmp (old_file.get_contents (), new_file.get_contents (), len) == 0) {
 113                                                 changed = false;
 114                                         }
 115                                 }
 116                                 old_file = null;
 117                                 new_file = null;
 118                         } catch (FileError e) {
 119                                 // assume changed if mmap comparison doesn't work
 120                         }
 121
 122                         if (changed) {
 123                                 FileUtils.rename (temp_filename, filename);
 124                         } else {
 125                                 FileUtils.unlink (temp_filename);
 126                         }
 127                 }
 128         }
 129
 130         /**
 131          * Writes tabs according to the current indent level.
 132          */
 133         public void write_indent (CCodeLineDirective? line = null) {
 134                 if (line_directives) {
 135                         if (line != null) {
 136                                 line.write (this);
 137                                 using_line_directive = true;
 138                         } else if (using_line_directive) {
 139                                 // no corresponding Vala line, emit line directive for C line
 140                                 write_string ("#line %d \"%s\"".printf (current_line_number + 1, Path.get_basename (filename)));
 141                                 write_newline ();
 142                                 using_line_directive = false;
 143                         }
 144                 }
 145
 146                 if (!bol) {
 147                         write_newline ();
 148                 }
 149
 150                 for (int i = 0; i < indent; i++) {
 151                         stream.putc ('\t');
 152                 }
 153
 154                 _bol = false;
 155         }
 156
 157         /**
 158          * Writes the specified string.
 159          *
 160          * @param s a string
 161          */
 162         public void write_string (string s) {
 163                 stream.puts (s);
 164                 _bol = false;
 165         }
 166
 167         /**
 168          * Writes a newline.
 169          */
 170         public void write_newline () {
 171                 stream.putc ('\n');
 172                 current_line_number++;
 173                 _bol = true;
 174         }
 175
 176         /**
 177          * Opens a new block, increasing the indent level.
 178          */
 179         public void write_begin_block () {
 180                 if (!bol) {
 181                         stream.putc (' ');
 182                 } else {
 183                         write_indent ();
 184                 }
 185                 stream.putc ('{');
 186                 write_newline ();
 187                 indent++;
 188         }
 189
 190         /**
 191          * Closes the current block, decreasing the indent level.
 192          */
 193         public void write_end_block () {
 194                 assert (indent > 0);
 195
 196                 indent--;
 197                 write_indent ();
 198                 stream.putc ('}');
 199         }
 200
 201         /**
 202          * Writes the specified text as comment.
 203          *
 204          * @param text the comment text
 205          */
 206         public void write_comment (string text) {
 207                 write_indent ();
 208                 stream.puts ("/*");
 209                 bool first = true;
 210
 211                 /* separate declaration due to missing memory management in foreach statements */
 212                 var lines = text.split ("\n");
 213
 214                 foreach (string line in lines) {
 215                         if (!first) {
 216                                 write_indent ();
 217                         } else {
 218                                 first = false;
 219                         }
 220
 221                         var lineparts = line.split ("*/");
 222
 223                         for (int i = 0; lineparts[i] != null; i++) {
 224                                 stream.puts (lineparts[i]);
 225                                 if (lineparts[i+1] != null) {
 226                                         stream.puts ("* /");
 227                                 }
 228                         }
 229                 }
 230                 stream.puts ("*/");
 231                 write_newline ();
 232         }
 233 }