vala/valacastexpression.vala

   1 /* valacastexpression.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23
  24 /**
  25  * Represents a type cast in the source code.
  26  */
  27 public class Vala.CastExpression : Expression {
  28         /**
  29          * The expression to be cast.
  30          */
  31         public Expression inner {
  32                 get {
  33                         return _inner;
  34                 }
  35                 set {
  36                         _inner = value;
  37                         _inner.parent_node = this;
  38                 }
  39         }
  40
  41         /**
  42          * The target type.
  43          */
  44         public DataType type_reference {
  45                 get { return _data_type; }
  46                 set {
  47                         _data_type = value;
  48                         _data_type.parent_node = this;
  49                 }
  50         }
  51
  52         /**
  53          * Checked casts return NULL instead of raising an error.
  54          */
  55         public bool is_silent_cast { get; set; }
  56
  57         public bool is_non_null_cast { get; set; }
  58
  59         private Expression _inner;
  60
  61         private DataType _data_type;
  62
  63         /**
  64          * Creates a new cast expression.
  65          *
  66          * @param inner expression to be cast
  67          * @param type  target type
  68          * @return      newly created cast expression
  69          */
  70         public CastExpression (Expression inner, DataType type_reference, SourceReference source_reference, bool is_silent_cast) {
  71                 this.type_reference = type_reference;
  72                 this.source_reference = source_reference;
  73                 this.is_silent_cast = is_silent_cast;
  74                 this.inner = inner;
  75         }
  76
  77         public CastExpression.non_null (Expression inner, SourceReference source_reference) {
  78                 this.inner = inner;
  79                 this.is_non_null_cast = true;
  80                 this.source_reference = source_reference;
  81         }
  82
  83         public override void accept (CodeVisitor visitor) {
  84                 inner.accept (visitor);
  85                 if (!is_non_null_cast) {
  86                         type_reference.accept (visitor);
  87                 }
  88
  89                 visitor.visit_cast_expression (this);
  90
  91                 visitor.visit_expression (this);
  92         }
  93
  94         public override void replace_expression (Expression old_node, Expression new_node) {
  95                 if (inner == old_node) {
  96                         inner = new_node;
  97                 }
  98         }
  99
 100         public override bool is_pure () {
 101                 return inner.is_pure ();
 102         }
 103
 104         public override void replace_type (DataType old_type, DataType new_type) {
 105                 if (type_reference == old_type) {
 106                         type_reference = new_type;
 107                 }
 108         }
 109
 110         public override bool check (SemanticAnalyzer analyzer) {
 111                 if (checked) {
 112                         return !error;
 113                 }
 114
 115                 checked = true;
 116
 117                 if (!inner.check (analyzer)) {
 118                         error = true;
 119                         return false;
 120                 }
 121
 122                 if (is_non_null_cast) {
 123                         // (!) non-null cast
 124                         value_type = inner.value_type.copy ();
 125                         value_type.nullable = false;
 126
 127                         inner.target_type = inner.value_type.copy ();
 128
 129                         return !error;
 130                 }
 131
 132                 type_reference.check (analyzer);
 133
 134                 // FIXME: check whether cast is allowed
 135
 136                 value_type = type_reference;
 137                 value_type.value_owned = inner.value_type.value_owned;
 138
 139                 inner.target_type = inner.value_type.copy ();
 140
 141                 return !error;
 142         }
 143
 144         public override void get_defined_variables (Collection<LocalVariable> collection) {
 145                 inner.get_defined_variables (collection);
 146         }
 147
 148         public override void get_used_variables (Collection<LocalVariable> collection) {
 149                 inner.get_used_variables (collection);
 150         }
 151 }