ccode/valaccodedeclaration.vala

   1 /* valaccodedeclaration.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a local variable declaration in the C code.
  27  */
  28 public class Vala.CCodeDeclaration : CCodeStatement {
  29         /**
  30          * The type of the local variable.
  31          */
  32         public string type_name { get; set; }
  33
  34         /**
  35          * The declaration modifier.
  36          */
  37         public CCodeModifiers modifiers { get; set; }
  38
  39         private List<CCodeDeclarator> declarators = new ArrayList<CCodeDeclarator> ();
  40
  41         public CCodeDeclaration (string type_name) {
  42                 this.type_name = type_name;
  43         }
  44
  45         /**
  46          * Adds the specified declarator to this declaration.
  47          *
  48          * @param decl a declarator
  49          */
  50         public void add_declarator (CCodeDeclarator decl) {
  51                 declarators.add (decl);
  52         }
  53
  54         public override void write (CCodeWriter writer) {
  55                 if ((modifiers & (CCodeModifiers.STATIC | CCodeModifiers.EXTERN)) == 0) {
  56                         foreach (CCodeDeclarator decl in declarators) {
  57                                 decl.write_initialization (writer);
  58                         }
  59                 }
  60         }
  61
  62         private bool has_initializer () {
  63                 foreach (CCodeDeclarator decl in declarators) {
  64                         var var_decl = decl as CCodeVariableDeclarator;
  65                         if (var_decl != null && var_decl.initializer == null) {
  66                                 return false;
  67                         }
  68                 }
  69                 return true;
  70         }
  71
  72         public override void write_declaration (CCodeWriter writer) {
  73                 if ((modifiers & (CCodeModifiers.STATIC | CCodeModifiers.EXTERN)) != 0) {
  74                         // combined declaration and initialization for static and extern variables
  75                         writer.write_indent (line);
  76                         if ((modifiers & CCodeModifiers.STATIC) != 0) {
  77                                 writer.write_string ("static ");
  78                         }
  79                         if ((modifiers & CCodeModifiers.VOLATILE) != 0) {
  80                                 writer.write_string ("volatile ");
  81                         }
  82                         if ((modifiers & CCodeModifiers.EXTERN) != 0 && !has_initializer ()) {
  83                                 writer.write_string ("extern ");
  84                         }
  85                         if ((modifiers & CCodeModifiers.THREAD_LOCAL) != 0) {
  86                                 writer.write_string ("thread_local ");
  87                         }
  88                         writer.write_string (type_name);
  89                         writer.write_string (" ");
  90
  91                         bool first = true;
  92                         foreach (CCodeDeclarator decl in declarators) {
  93                                 if (!first) {
  94                                         writer.write_string (", ");
  95                                 } else {
  96                                         first = false;
  97                                 }
  98                                 decl.write (writer);
  99                         }
 100
 101                         if (CCodeModifiers.DEPRECATED in modifiers) {
 102                                 writer.write_string (" G_GNUC_DEPRECATED");
 103                         }
 104
 105                         writer.write_string (";");
 106                         writer.write_newline ();
 107                         return;
 108                 }
 109
 110                 writer.write_indent ();
 111                 if ((modifiers & CCodeModifiers.REGISTER) == CCodeModifiers.REGISTER) {
 112                         writer.write_string ("register ");
 113                 }
 114                 writer.write_string (type_name);
 115                 writer.write_string (" ");
 116
 117                 bool first = true;
 118                 foreach (CCodeDeclarator decl in declarators) {
 119                         if (!first) {
 120                                 writer.write_string (", ");
 121                         } else {
 122                                 first = false;
 123                         }
 124                         decl.write_declaration (writer);
 125                 }
 126
 127                 writer.write_string (";");
 128                 writer.write_newline ();
 129         }
 130 }