vala/valaerrordomain.vala

   1 /* valaerrordomain.vala
   2  *
   3  * Copyright (C) 2008-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an error domain declaration in the source code.
  27  */
  28 public class Vala.ErrorDomain : TypeSymbol {
  29         private List<ErrorCode> codes = new ArrayList<ErrorCode> ();
  30         private List<Method> methods = new ArrayList<Method> ();
  31         private string cname;
  32         private string cprefix;
  33         private string lower_case_cprefix;
  34         private string lower_case_csuffix;
  35
  36         /**
  37          * Creates a new error domain.
  38          *
  39          * @param name             type name
  40          * @param source_reference reference to source code
  41          * @return                 newly created error domain
  42          */
  43         public ErrorDomain (string name, SourceReference? source_reference = null, Comment? comment = null) {
  44                 base (name, source_reference, comment);
  45         }
  46
  47         /**
  48          * Appends the specified code to the list of error codes.
  49          *
  50          * @param ecode an error code
  51          */
  52         public void add_code (ErrorCode ecode) {
  53                 codes.add (ecode);
  54                 scope.add (ecode.name, ecode);
  55         }
  56
  57         /**
  58          * Adds the specified method as a member to this error domain.
  59          *
  60          * @param m a method
  61          */
  62         public override void add_method (Method m) {
  63                 if (m is CreationMethod) {
  64                         Report.error (m.source_reference, "construction methods may only be declared within classes and structs");
  65
  66                         m.error = true;
  67                         return;
  68                 }
  69                 if (m.binding == MemberBinding.INSTANCE) {
  70                         m.this_parameter = new Parameter ("this", new ErrorType (this, null));
  71                         m.scope.add (m.this_parameter.name, m.this_parameter);
  72                 }
  73
  74                 methods.add (m);
  75                 scope.add (m.name, m);
  76         }
  77
  78         /**
  79          * Returns a copy of the list of error codes.
  80          *
  81          * @return list of error codes
  82          */
  83         public List<ErrorCode> get_codes () {
  84                 return codes;
  85         }
  86
  87         /**
  88          * Returns a copy of the list of methods.
  89          *
  90          * @return list of methods
  91          */
  92         public List<Method> get_methods () {
  93                 return methods;
  94         }
  95
  96         public override void accept (CodeVisitor visitor) {
  97                 visitor.visit_error_domain (this);
  98         }
  99
 100         public override void accept_children (CodeVisitor visitor) {
 101                 foreach (ErrorCode ecode in codes) {
 102                         ecode.accept (visitor);
 103                 }
 104
 105                 foreach (Method m in methods) {
 106                         m.accept (visitor);
 107                 }
 108         }
 109
 110         public override string get_cname (bool const_type = false) {
 111                 if (cname == null) {
 112                         cname = "%s%s".printf (parent_symbol.get_cprefix (), name);
 113                 }
 114                 return cname;
 115         }
 116
 117         public override string get_lower_case_cprefix () {
 118                 if (lower_case_cprefix == null) {
 119                         lower_case_cprefix = "%s_".printf (get_lower_case_cname (null));
 120                 }
 121                 return lower_case_cprefix;
 122         }
 123
 124         private string get_lower_case_csuffix () {
 125                 if (lower_case_csuffix == null) {
 126                         lower_case_csuffix = camel_case_to_lower_case (name);
 127                 }
 128                 return lower_case_csuffix;
 129         }
 130
 131         public override string? get_lower_case_cname (string? infix) {
 132                 if (infix == null) {
 133                         infix = "";
 134                 }
 135
 136                 string cprefix = "";
 137                 if (parent_symbol != null) {
 138                         cprefix = parent_symbol.get_lower_case_cprefix ();
 139                 }
 140
 141                 return "%s%s%s".printf (cprefix, infix, get_lower_case_csuffix ());
 142         }
 143
 144         public override string? get_upper_case_cname (string? infix) {
 145                 return get_lower_case_cname (infix).up ();
 146         }
 147
 148         public override bool is_reference_type () {
 149                 return false;
 150         }
 151
 152         public void set_cname (string cname) {
 153                 this.cname = cname;
 154         }
 155
 156         public override string get_cprefix () {
 157                 if (cprefix == null) {
 158                         cprefix = "%s_".printf (get_upper_case_cname (null));
 159                 }
 160                 return cprefix;
 161         }
 162
 163         /**
 164          * Sets the string to be prepended to the name of members of this error
 165          * domain when used in C code.
 166          *
 167          * @param cprefix the prefix to be used in C code
 168          */
 169         public void set_cprefix (string cprefix) {
 170                 this.cprefix = cprefix;
 171         }
 172
 173         private void process_ccode_attribute (Attribute a) {
 174                 if (a.has_argument ("cname")) {
 175                         set_cname (a.get_string ("cname"));
 176                 }
 177                 if (a.has_argument ("cprefix")) {
 178                         set_cprefix (a.get_string ("cprefix"));
 179                 }
 180                 if (a.has_argument ("lower_case_csuffix")) {
 181                         lower_case_csuffix = a.get_string ("lower_case_csuffix");
 182                 }
 183                 if (a.has_argument ("cheader_filename")) {
 184                         var val = a.get_string ("cheader_filename");
 185                         foreach (string filename in val.split (",")) {
 186                                 add_cheader_filename (filename);
 187                         }
 188                 }
 189         }
 190
 191         /**
 192          * Process all associated attributes.
 193          */
 194         public void process_attributes () {
 195                 foreach (Attribute a in attributes) {
 196                         if (a.name == "CCode") {
 197                                 process_ccode_attribute (a);
 198                         } else if (a.name == "Deprecated") {
 199                                 process_deprecated_attribute (a);
 200                         } else if (a.name == "Experimental") {
 201                                 process_experimental_attribute (a);
 202                         }
 203                 }
 204         }
 205
 206         public override string? get_type_id () {
 207                 return "G_TYPE_POINTER";
 208         }
 209
 210         public override string? get_marshaller_type_name () {
 211                 return "POINTER";
 212         }
 213
 214         public override string? get_get_value_function () {
 215                 return "g_value_get_pointer";
 216         }
 217
 218         public override string? get_set_value_function () {
 219                 return "g_value_set_pointer";
 220         }
 221
 222         public override bool check (CodeContext context) {
 223                 if (checked) {
 224                         return !error;
 225                 }
 226
 227                 checked = true;
 228
 229                 process_attributes ();
 230
 231                 foreach (ErrorCode ecode in codes) {
 232                         ecode.check (context);
 233                 }
 234
 235                 foreach (Method m in methods) {
 236                         m.check (context);
 237                 }
 238
 239                 return !error;
 240         }
 241 }