coregrind/m_syswrap/syscall-arm-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-arm-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2008-2017 Evan Geller (gaze@bea.ms)
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25   The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_arm_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35
  36 /*----------------------------------------------------------------*/
  37 /*
  38         Perform a syscall for the client.  This will run a syscall
  39         with the client's specific per-thread signal mask.
  40
  41         The structure of this function is such that, if the syscall is
  42         interrupted by a signal, we can determine exactly what
  43         execution state we were in with respect to the execution of
  44         the syscall by examining the value of IP in the signal
  45         handler.  This means that we can always do the appropriate
  46         thing to precisely emulate the kernel's signal/syscall
  47         interactions.
  48
  49         The syscall number is taken from the argument, even though it
  50         should also be in regs->m_R7.  The syscall result is written
  51         back to regs->m_R0 on completion.
  52
  53         Returns 0 if the syscall was successfully called (even if the
  54         syscall itself failed), or a nonzero error code in the lowest
  55         8 bits if one of the sigprocmasks failed (there's no way to
  56         determine which one failed).  And there's no obvious way to
  57         recover from that either, but nevertheless we want to know.
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65    UWord ML_(do_syscall_for_client_WRK)(
  66               Int syscallno,                 // r0
  67               void* guest_state,             // r1
  68               const vki_sigset_t *sysmask,   // r2
  69               const vki_sigset_t *postmask,  // r3
  70               Int nsigwords)                 // [sp, #0]
  71 */
  72 /* from vki_arch.h */
  73 #define VKI_SIG_SETMASK 2
  74
  75 .globl ML_(do_syscall_for_client_WRK)
  76 ML_(do_syscall_for_client_WRK):
  77
  78    /* Stash callee-saves and our args on the stack */
  79    push {r0, r1, r3, r4, r5, r7, fp, lr}
  80
  81 1:
  82
  83    mov r7, #__NR_rt_sigprocmask
  84    mov r0, #VKI_SIG_SETMASK
  85    mov r1, r2 /* sysmask */
  86    mov r2, r3 /* postmask */
  87    ldr r3, [sp, #32] /* nsigwords */
  88    svc 0x00000000
  89
  90
  91    ldr r5, [sp, #4] /* guest_state */
  92
  93    ldr r7, [sp, #0] /* syscall# */
  94    ldr r0, [r5, #OFFSET_arm_R0]
  95    ldr r1, [r5, #OFFSET_arm_R1]
  96    ldr r2, [r5, #OFFSET_arm_R2]
  97    ldr r3, [r5, #OFFSET_arm_R3]
  98    ldr r4, [r5, #OFFSET_arm_R4]
  99    ldr r5, [r5, #OFFSET_arm_R5]
 100
 101 2: svc 0x00000000
 102 3:
 103    ldr r5, [sp, #4] /* guest_state */
 104    str r0, [r5, #OFFSET_arm_R0]
 105
 106 4:
 107    mov r7, #__NR_rt_sigprocmask
 108    mov r0, #VKI_SIG_SETMASK
 109    ldr r1, [sp, #8] /* postmask */
 110    mov r2, #0
 111    ldr r3, [sp, #32] /* nsigwords */
 112    svc 0x00000000
 113
 114    cmp r0, #0
 115    blt 7f
 116    add sp, sp, #4 /* r0 contains return value */
 117
 118 5: /* Success */
 119    mov r0, #0
 120    pop {r1, r3, r4, r5, r7, fp, pc}
 121
 122 7: /* Failure: return 0x8000 | error code */
 123    orr r0, r0, #0x8000
 124    pop {r1, r3, r4, r5, r7, fp, pc}
 125
 126
 127 .section .rodata
 128 /* export the ranges so that
 129    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 130    right thing */
 131
 132 .globl ML_(blksys_setup)
 133 .globl ML_(blksys_restart)
 134 .globl ML_(blksys_complete)
 135 .globl ML_(blksys_committed)
 136 .globl ML_(blksys_finished)
 137 ML_(blksys_setup):      .long 1b
 138 ML_(blksys_restart):    .long 2b
 139 ML_(blksys_complete):   .long 3b
 140 ML_(blksys_committed):  .long 4b
 141 ML_(blksys_finished):   .long 5b
 142
 143 #endif // defined(VGP_arm_linux)
 144
 145 /* Let the linker know we don't need an executable stack */
 146 MARK_STACK_NO_EXEC
 147
 148 /*--------------------------------------------------------------------*/
 149 /*--- end                                                          ---*/
 150 /*--------------------------------------------------------------------*/