coregrind/m_syswrap/syscall-mips32-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.      syscall-mips32-linux.S  ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7    This file is part of Valgrind, a dynamic binary instrumentation
   8    framework.
   9
  10    Copyright (C) 2010-2017 RT-RK
  11
  12    This program is free software; you can redistribute it and/or
  13    modify it under the terms of the GNU General Public License as
  14    published by the Free Software Foundation; either version 2 of the
  15    License, or (at your option) any later version.
  16
  17    This program is distributed in the hope that it will be useful, but
  18    WITHOUT ANY WARRANTY; without even the implied warranty of
  19    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20    General Public License for more details.
  21
  22    You should have received a copy of the GNU General Public License
  23    along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25    The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_mips32_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35
  36 /*----------------------------------------------------------------*/
  37 /*
  38         Perform a syscall for the client.  This will run a syscall
  39         with the client's specific per-thread signal mask.
  40
  41         The structure of this function is such that, if the syscall is
  42         interrupted by a signal, we can determine exactly what
  43         execution state we were in with respect to the execution of
  44         the syscall by examining the value of IP in the signal
  45         handler.  This means that we can always do the appropriate
  46         thing to precisely emulate the kernel's signal/syscall
  47         interactions.
  48
  49         The syscall number is taken from the argument, even though it
  50         should also be in regs->v0.  The syscall result is written
  51         back to regs->v0 on completion.
  52
  53         Returns 0 if the syscall was successfully called (even if the
  54         syscall itself failed), or a nonzero error code in the lowest
  55         8 bits if one of the sigprocmasks failed (there's no way to
  56         determine which one failed).  And there's no obvious way to
  57         recover from that either, but nevertheless we want to know.
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65    UWord ML_(do_syscall_for_client_WRK)(
  66               Int syscallno,                 // $4 - a0
  67               void* guest_state,             // $5 - a1
  68               const vki_sigset_t *sysmask,   // $6 - a2
  69               const vki_sigset_t *postmask,  // $7 - a3
  70               Int nsigwords)                 // stack
  71 */
  72 /* from vki_arch.h */
  73 #define VKI_SIG_SETMASK 3
  74
  75 .globl ML_(do_syscall_for_client_WRK)
  76 ML_(do_syscall_for_client_WRK):
  77
  78     subu $29, $29, 56  #set up the steck frame,
  79     sw $4, 52($29)
  80     sw $5, 48($29)
  81     sw $6, 44($29)
  82     sw $7, 40($29)
  83     sw $31, 36($29)
  84     sw $30, 32($29)
  85     sw $16, 28($29)
  86     sw $17, 24($29)
  87     sw $18, 20($29)
  88     sw $19, 16($29)
  89     sw $20, 12($29)
  90     sw $21, 8($29)
  91     sw $22, 4($29)
  92     sw $23, 0($29)
  93     addu $30, $29, 56
  94
  95
  96     /* Set the signal mask which should be current during the syscall. */
  97
  98 1:  li $2, __NR_rt_sigprocmask
  99     li $4, VKI_SIG_SETMASK
 100     move $5, $6 /* sysmask */
 101     move $6, $7 /* postmask */
 102     lw $7, 72($29) /* nsigwords */
 103     syscall
 104     nop
 105
 106 # TODO: this should remain, keep it just for now
 107     bnez $7, 7f
 108     nop
 109
 110     lw $8, 48($29)    /* t0 == ThreadState */
 111
 112     lw $2, OFFSET_mips32_r2($8) /* v0 == guest_v0 */
 113     lw $4, OFFSET_mips32_r4($8)
 114     lw $5, OFFSET_mips32_r5($8)
 115     lw $6, OFFSET_mips32_r6($8)
 116     lw $7, OFFSET_mips32_r7($8)
 117     subu $29, $29, 32  #set up the steck frame,
 118     lw $9, OFFSET_mips32_r29($8)
 119     lw $10, 16($9)
 120     sw $10, 16($29)
 121     lw $10, 20($9)
 122     sw $10, 20($29)
 123     lw $10, 24($9)
 124     sw $10, 24($29)
 125
 126 2:  syscall
 127
 128 3:  addu $29, $29, 32  #set up the steck frame,
 129
 130     lw $8, 48($29) /* t0 == ThreadState */
 131     sw $2, OFFSET_mips32_r2($8)
 132     sw $3, OFFSET_mips32_r3($8)
 133     sw $7, OFFSET_mips32_r7($8)
 134
 135 4:  li $2, __NR_rt_sigprocmask
 136     li $4, VKI_SIG_SETMASK
 137     lw $5, 40($29)
 138     li $6, 0
 139     lw $7, 72($29) /* nsigwords */
 140     syscall
 141     nop
 142
 143     bnez $7, 7f
 144     nop
 145
 146     /* Success */
 147     li $2, 0
 148
 149 5:  lw $4, 52($29)
 150     lw $5, 48($29)
 151     lw $6, 44($29)
 152     lw $7, 40($29)
 153     lw $31, 36($29)
 154     lw $30, 32($29)
 155     lw $16, 28($29)
 156     lw $17, 24($29)
 157     lw $18, 20($29)
 158     lw $19, 16($29)
 159     lw $20, 12($29)
 160     lw $21, 8($29)
 161     lw $22, 4($29)
 162     lw $23, 0($29)
 163     addu $29, $29, 56 #release the stack frame.
 164
 165     jr $31
 166     nop
 167
 168 7:  /* Failure: return 0x8000 | error code */
 169     li $2, 0x8000
 170
 171     lw $4, 52($29)
 172     lw $5, 48($29)
 173     lw $6, 44($29)
 174     lw $7, 40($29)
 175     lw $31, 36($29)
 176     lw $30, 32($29)
 177     lw $16, 28($29)
 178     lw $17, 24($29)
 179     lw $18, 20($29)
 180     lw $19, 16($29)
 181     lw $20, 12($29)
 182     lw $21, 8($29)
 183     lw $22, 4($29)
 184     lw $23, 0($29)
 185     addu $29, $29, 56 #release the stack frame.
 186
 187     jr $31
 188     nop
 189
 190 .section .rodata
 191 /* export the ranges so that
 192    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 193    right thing */
 194
 195 .globl ML_(blksys_setup)
 196 .globl ML_(blksys_restart)
 197 .globl ML_(blksys_complete)
 198 .globl ML_(blksys_committed)
 199 .globl ML_(blksys_finished)
 200 ML_(blksys_setup):      .long 1b
 201 ML_(blksys_restart):    .long 2b
 202 ML_(blksys_complete):   .long 3b
 203 ML_(blksys_committed):  .long 4b
 204 ML_(blksys_finished):   .long 5b
 205
 206 #endif // defined(VGP_mips32_linux)
 207
 208 /* Let the linker know we don't need an executable stack */
 209 MARK_STACK_NO_EXEC
 210
 211 /*--------------------------------------------------------------------*/
 212 /*--- end                                                          ---*/
 213 /*--------------------------------------------------------------------*/