coregrind/m_syswrap/syscall-ppc64le-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-ppc64-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2005-2017 Paul Mackerras <paulus@samba.org>
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25   The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_ppc64le_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35
  36 /*----------------------------------------------------------------*/
  37 /*
  38         Perform a syscall for the client.  This will run a syscall
  39         with the client's specific per-thread signal mask.
  40
  41         The structure of this function is such that, if the syscall is
  42         interrupted by a signal, we can determine exactly what
  43         execution state we were in with respect to the execution of
  44         the syscall by examining the value of NIP in the signal
  45         handler.  This means that we can always do the appropriate
  46         thing to precisely emulate the kernel's signal/syscall
  47         interactions.
  48
  49         The syscall number is taken from the argument, even though it
  50         should also be in regs->m_gpr[0].  The syscall result is written
  51         back to regs->m_gpr[3]/m_xer/m_result on completion.
  52
  53         Returns 0 if the syscall was successfully called (even if the
  54         syscall itself failed), or a nonzero error code in the lowest
  55         8 bits if one of the sigprocmasks failed (there's no way to
  56         determine which one failed).  And there's no obvious way to
  57         recover from that either, but nevertheless we want to know.
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65         UWord ML_(do_syscall_for_client_WRK)(
  66                                   Int syscallno,                // r3
  67                                   void* guest_state,            // r4
  68                                   const vki_sigset_t *sysmask,  // r5
  69                                   const vki_sigset_t *postmask, // r6
  70                                   Int sigsetSzB)                // r7
  71 */
  72 /* from vki_arch.h */
  73 #define VKI_SIG_SETMASK 2
  74
  75 .align 2
  76 .globl ML_(do_syscall_for_client_WRK)
  77 #if _CALL_ELF == 2
  78 .type .ML_(do_syscall_for_client_WRK),@function
  79 ML_(do_syscall_for_client_WRK):
  80 0:      addis         2,12,.TOC.-0b@ha
  81         addi          2,2,.TOC.-0b@l
  82         .localentry   ML_(do_syscall_for_client_WRK), .-ML_(do_syscall_for_client_WRK)
  83 #else
  84 .section ".opd","aw"
  85 .align 3
  86 ML_(do_syscall_for_client_WRK):
  87 .quad .ML_(do_syscall_for_client_WRK),.TOC.@tocbase,0
  88 .previous
  89 #endif
  90 #if _CALL_ELF == 2
  91 0:      addis        2,12,.TOC.-0b@ha
  92         addi         2,2,.TOC.-0b@l
  93         .localentry  ML_(do_syscall_for_client_WRK), .-ML_(do_syscall_for_client_WRK)
  94 #endif
  95 .type  .ML_(do_syscall_for_client_WRK),@function
  96 .globl .ML_(do_syscall_for_client_WRK)
  97 .ML_(do_syscall_for_client_WRK):
  98         /* make a stack frame */
  99         stdu    1,-80(1)
 100         std     31,72(1)
 101         std     30,64(1)
 102         std     29,56(1)
 103         std     28,48(1)
 104         mr      31,3            /* syscall number */
 105         mr      30,4            /* guest_state */
 106         mr      29,6            /* postmask */
 107         mr      28,7            /* sigsetSzB */
 108
 109         /* set the signal mask for doing the system call */
 110         /* set up for sigprocmask(SIG_SETMASK, sysmask, postmask) */
 111 1:      li      0,__NR_rt_sigprocmask
 112         li      3,VKI_SIG_SETMASK
 113         mr      4,5
 114         mr      5,6
 115         mr      6,7
 116         sc                      /* set the mask */
 117         bso     7f              /* if the sigprocmask fails */
 118
 119         /* load up syscall args from the threadstate */
 120         ld      3,OFFSET_ppc64_GPR3(30)
 121         ld      4,OFFSET_ppc64_GPR4(30)
 122         ld      5,OFFSET_ppc64_GPR5(30)
 123         ld      6,OFFSET_ppc64_GPR6(30)
 124         ld      7,OFFSET_ppc64_GPR7(30)
 125         ld      8,OFFSET_ppc64_GPR8(30)
 126         mr      0,31            /* syscall number */
 127 2:      sc                      /* do the syscall */
 128
 129         /* put the result back in the threadstate  */
 130 3:      std     3,OFFSET_ppc64_GPR3(30)     /* gst->GPR3 = sc result */
 131         /* copy cr0.so back to simulated state */
 132         mfcr    5                           /* r5 = CR               */
 133         rlwinm  5,5,4,31,31                 /* r5 = (CR >> 28) & 1   */
 134         stb     5,OFFSET_ppc64_CR0_0(30)    /* gst->CR0.SO = cr0.so  */
 135
 136         /* block signals again */
 137         /* set up for sigprocmask(SIG_SETMASK, postmask, NULL) */
 138 4:      li      0,__NR_rt_sigprocmask
 139         li      3,VKI_SIG_SETMASK
 140         mr      4,29
 141         li      5,0
 142         mr      6,28
 143         sc                      /* set the mask */
 144         bso     7f              /* if the sigprocmask fails */
 145         /* now safe from signals */
 146         li      3,0             /* SUCCESS */
 147
 148         /* pop off stack frame */
 149 5:      ld      28,48(1)
 150         ld      29,56(1)
 151         ld      30,64(1)
 152         ld      31,72(1)
 153         addi    1,1,80
 154         blr
 155
 156         /* failure: return 0x8000 | error code */
 157 7:      ori     3,3,0x8000      /* FAILURE -- ensure return value is nonzero */
 158         b       5b
 159 #if _CALL_ELF == 2
 160         .size .ML_(do_syscall_for_client_WRK),.-.ML_(do_syscall_for_client_WRK)
 161 #else
 162         .size .ML_(do_syscall_for_client_WRK),.-.ML_(do_syscall_for_client_WRK)
 163 #endif
 164 .section .rodata
 165 /* export the ranges so that
 166    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 167    right thing */
 168
 169 .globl ML_(blksys_setup)
 170 .globl ML_(blksys_restart)
 171 .globl ML_(blksys_complete)
 172 .globl ML_(blksys_committed)
 173 .globl ML_(blksys_finished)
 174 ML_(blksys_setup):     .quad 1b
 175 ML_(blksys_restart):   .quad 2b
 176 ML_(blksys_complete):  .quad 3b
 177 ML_(blksys_committed): .quad 4b
 178 ML_(blksys_finished):  .quad 5b
 179
 180 #endif // defined(VGP_ppc64le_linux)
 181
 182 /* Let the linker know we don't need an executable stack */
 183 MARK_STACK_NO_EXEC
 184
 185 /*--------------------------------------------------------------------*/
 186 /*--- end                                                          ---*/
 187 /*--------------------------------------------------------------------*/