coregrind/m_syswrap/syscall-mips32-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.      syscall-mips32-linux.S  ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7    This file is part of Valgrind, a dynamic binary instrumentation
   8    framework.
   9
  10    Copyright (C) 2010-2017 RT-RK
  11       mips-valgrind@rt-rk.com
  12
  13    This program is free software; you can redistribute it and/or
  14    modify it under the terms of the GNU General Public License as
  15    published by the Free Software Foundation; either version 2 of the
  16    License, or (at your option) any later version.
  17
  18    This program is distributed in the hope that it will be useful, but
  19    WITHOUT ANY WARRANTY; without even the implied warranty of
  20    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21    General Public License for more details.
  22
  23    You should have received a copy of the GNU General Public License
  24    along with this program; if not, write to the Free Software
  25    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  26    02111-1307, USA.
  27
  28    The GNU General Public License is contained in the file COPYING.
  29 */
  30
  31 #include "pub_core_basics_asm.h"
  32
  33 #if defined(VGP_mips32_linux)
  34
  35 #include "pub_core_vkiscnums_asm.h"
  36 #include "libvex_guest_offsets.h"
  37
  38
  39 /*----------------------------------------------------------------*/
  40 /*
  41         Perform a syscall for the client.  This will run a syscall
  42         with the client's specific per-thread signal mask.
  43
  44         The structure of this function is such that, if the syscall is
  45         interrupted by a signal, we can determine exactly what
  46         execution state we were in with respect to the execution of
  47         the syscall by examining the value of IP in the signal
  48         handler.  This means that we can always do the appropriate
  49         thing to precisely emulate the kernel's signal/syscall
  50         interactions.
  51
  52         The syscall number is taken from the argument, even though it
  53         should also be in regs->v0.  The syscall result is written
  54         back to regs->v0 on completion.
  55
  56         Returns 0 if the syscall was successfully called (even if the
  57         syscall itself failed), or a nonzero error code in the lowest
  58         8 bits if one of the sigprocmasks failed (there's no way to
  59         determine which one failed).  And there's no obvious way to
  60         recover from that either, but nevertheless we want to know.
  61
  62         VG_(fixup_guest_state_after_syscall_interrupted) does the
  63         thread state fixup in the case where we were interrupted by a
  64         signal.
  65
  66         Prototype:
  67
  68    UWord ML_(do_syscall_for_client_WRK)(
  69               Int syscallno,                 // $4 - a0
  70               void* guest_state,             // $5 - a1
  71               const vki_sigset_t *sysmask,   // $6 - a2
  72               const vki_sigset_t *postmask,  // $7 - a3
  73               Int nsigwords)                 // stack
  74 */
  75 /* from vki_arch.h */
  76 #define VKI_SIG_SETMASK 3
  77
  78 .globl ML_(do_syscall_for_client_WRK)
  79 ML_(do_syscall_for_client_WRK):
  80
  81     subu $29, $29, 56  #set up the steck frame,
  82     sw $4, 52($29)
  83     sw $5, 48($29)
  84     sw $6, 44($29)
  85     sw $7, 40($29)
  86     sw $31, 36($29)
  87     sw $30, 32($29)
  88     sw $16, 28($29)
  89     sw $17, 24($29)
  90     sw $18, 20($29)
  91     sw $19, 16($29)
  92     sw $20, 12($29)
  93     sw $21, 8($29)
  94     sw $22, 4($29)
  95     sw $23, 0($29)
  96     addu $30, $29, 56
  97
  98
  99     /* Set the signal mask which should be current during the syscall. */
 100
 101 1:  li $2, __NR_rt_sigprocmask
 102     li $4, VKI_SIG_SETMASK
 103     move $5, $6 /* sysmask */
 104     move $6, $7 /* postmask */
 105     lw $7, 72($29) /* nsigwords */
 106     syscall
 107     nop
 108
 109 # TODO: this should remain, keep it just for now
 110     bnez $7, 7f
 111     nop
 112
 113     lw $8, 48($29)    /* t0 == ThreadState */
 114
 115     lw $2, 52($29) /* v0 == syscallno */
 116     lw $4, OFFSET_mips32_r4($8)
 117     lw $5, OFFSET_mips32_r5($8)
 118     lw $6, OFFSET_mips32_r6($8)
 119     lw $7, OFFSET_mips32_r7($8)
 120     subu $29, $29, 24  #set up the steck frame,
 121     lw $9, OFFSET_mips32_r29($8)
 122     lw $10, 16($9)
 123     sw $10, 16($29)
 124     lw $10, 20($9)
 125     sw $10, 20($29)
 126
 127 2:  syscall
 128
 129 3:  addu $29, $29, 24  #set up the steck frame,
 130
 131     lw $8, 48($29) /* t0 == ThreadState */
 132     sw $2, OFFSET_mips32_r2($8)
 133     sw $3, OFFSET_mips32_r3($8)
 134     sw $7, OFFSET_mips32_r7($8)
 135
 136 4:  li $2, __NR_rt_sigprocmask
 137     li $4, VKI_SIG_SETMASK
 138     lw $5, 40($29)
 139     li $6, 0
 140     lw $7, 72($29) /* nsigwords */
 141     syscall
 142     nop
 143
 144     bnez $7, 7f
 145     nop
 146
 147     /* Success */
 148     li $2, 0
 149
 150 5:  lw $4, 52($29)
 151     lw $5, 48($29)
 152     lw $6, 44($29)
 153     lw $7, 40($29)
 154     lw $31, 36($29)
 155     lw $30, 32($29)
 156     lw $16, 28($29)
 157     lw $17, 24($29)
 158     lw $18, 20($29)
 159     lw $19, 16($29)
 160     lw $20, 12($29)
 161     lw $21, 8($29)
 162     lw $22, 4($29)
 163     lw $23, 0($29)
 164     addu $29, $29, 56 #release the stack frame.
 165
 166     jr $31
 167     nop
 168
 169 7:  /* Failure: return 0x8000 | error code */
 170     li $2, 0x8000
 171
 172     lw $4, 52($29)
 173     lw $5, 48($29)
 174     lw $6, 44($29)
 175     lw $7, 40($29)
 176     lw $31, 36($29)
 177     lw $30, 32($29)
 178     lw $16, 28($29)
 179     lw $17, 24($29)
 180     lw $18, 20($29)
 181     lw $19, 16($29)
 182     lw $20, 12($29)
 183     lw $21, 8($29)
 184     lw $22, 4($29)
 185     lw $23, 0($29)
 186     addu $29, $29, 56 #release the stack frame.
 187
 188     jr $31
 189     nop
 190
 191 .section .rodata
 192 /* export the ranges so that
 193    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 194    right thing */
 195
 196 .globl ML_(blksys_setup)
 197 .globl ML_(blksys_restart)
 198 .globl ML_(blksys_complete)
 199 .globl ML_(blksys_committed)
 200 .globl ML_(blksys_finished)
 201 ML_(blksys_setup):      .long 1b
 202 ML_(blksys_restart):    .long 2b
 203 ML_(blksys_complete):   .long 3b
 204 ML_(blksys_committed):  .long 4b
 205 ML_(blksys_finished):   .long 5b
 206
 207 #endif // defined(VGP_mips32_linux)
 208
 209 /* Let the linker know we don't need an executable stack */
 210 MARK_STACK_NO_EXEC
 211
 212 /*--------------------------------------------------------------------*/
 213 /*--- end                                                          ---*/
 214 /*--------------------------------------------------------------------*/