coregrind/m_syswrap/syscall-mips64-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.      syscall-mips64-linux.S  ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10    Copyright (C) 2010-2017 RT-RK
  11       mips-valgrind@rt-rk.com
  12
  13    This program is free software; you can redistribute it and/or
  14    modify it under the terms of the GNU General Public License as
  15    published by the Free Software Foundation; either version 2 of the
  16    License, or (at your option) any later version.
  17
  18    This program is distributed in the hope that it will be useful, but
  19    WITHOUT ANY WARRANTY; without even the implied warranty of
  20    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21    General Public License for more details.
  22
  23    You should have received a copy of the GNU General Public License
  24    along with this program; if not, write to the Free Software
  25    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  26    02111-1307, USA.
  27
  28    The GNU General Public License is contained in the file COPYING.
  29 */
  30
  31 #include "pub_core_basics_asm.h"
  32
  33 #if defined(VGP_mips64_linux)
  34
  35 #include "pub_core_vkiscnums_asm.h"
  36 #include "libvex_guest_offsets.h"
  37
  38 /*----------------------------------------------------------------*/
  39 /*
  40    Perform a syscall for the client. This will run a syscall
  41    with the client's specific per-thread signal mask.
  42
  43    The structure of this function is such that, if the syscall is
  44    interrupted by a signal, we can determine exactly what
  45    execution state we were in with respect to the execution of
  46    the syscall by examining the value of PC in the signal
  47    handler. This means that we can always do the appropriate
  48    thing to precisely emulate the kernel's signal/syscall
  49    interactions.
  50
  51    The syscall number is taken from the argument, even though it
  52    should also be in regs->v0. The syscall result is written
  53    back to regs->v0 on completion.
  54
  55    VG_(fixup_guest_state_after_syscall_interrupted) does the
  56    thread state fixup in the case where we were interrupted by a
  57    signal.
  58
  59    Prototype:
  60
  61    UWord ML_(do_syscall_for_client_WRK)(
  62              Int syscallno,                 // $4 - a0
  63              void* guest_state,             // $5 - a1
  64              const vki_sigset_t *sysmask,   // $6 - a2
  65              const vki_sigset_t *postmask,  // $7 - a3
  66              Int nsigwords)                 // $8 - a4
  67 */
  68
  69 /* from vki_arch.h */
  70 #define VKI_SIG_SETMASK 3
  71
  72 .globl ML_(do_syscall_for_client_WRK)
  73 ML_(do_syscall_for_client_WRK):
  74
  75    /* save regs $a0 - $a4 on stack */
  76    daddiu  $29, $29, -48
  77    sd      $4, 0($29)                /* syscallno */
  78    sd      $5, 8($29)                /* guest_state */
  79    sd      $6, 16($29)               /* sysmask */
  80    sd      $7, 24($29)               /* postmask */
  81    sd      $8, 32($29)               /* nsigwords */
  82
  83 1: li      $2, __NR_rt_sigprocmask
  84    li      $4, VKI_SIG_SETMASK
  85    move    $5, $6                    /* sysmask */
  86    move    $6, $7                    /* postmask */
  87    move    $7, $8                    /* nsigwords */
  88    syscall
  89
  90    bnez    $7, 7f
  91    nop
  92
  93    /* Actually do the client syscall */
  94    ld      $5, 8($29)                /* guest_state */
  95    ld      $4, OFFSET_mips64_r4($5)  /* a0 */
  96
  97    ld      $6, OFFSET_mips64_r6($5)  /* a2 */
  98    ld      $7, OFFSET_mips64_r7($5)  /* a3 */
  99    ld      $8, OFFSET_mips64_r8($5)  /* a4 */
 100    ld      $9, OFFSET_mips64_r9($5)  /* a5 */
 101
 102    ld      $5, OFFSET_mips64_r5($5)  /* a1 */
 103    ld      $2, 0($29)                /* syscallno */
 104
 105 2: syscall
 106
 107    /* Saving return values into Guest state  */
 108 3: ld      $5, 8($29)                /* guest_state */
 109    sd      $2, OFFSET_mips64_r2($5)  /* v0 */
 110    sd      $7, OFFSET_mips64_r7($5)  /* a3 */
 111
 112 4: li      $2, __NR_rt_sigprocmask
 113    li      $4, VKI_SIG_SETMASK
 114    ld      $5, 24($29)               /* postmask */
 115    move    $6, $0                    /* 0 (zero) */
 116    ld      $7, 32($29)               /* nsigwords */
 117    syscall
 118
 119    bnez    $7, 7f
 120    nop
 121
 122 5: /* restore 29 and return */
 123    daddiu  $29, $29, 48
 124    jr      $31
 125    nop
 126
 127 7: /* error */
 128    daddiu  $29, $29, 48
 129    li      $2, 0x8000
 130    jr      $31
 131    nop
 132
 133 .section .rodata
 134 /* export the ranges so that
 135    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 136    right thing */
 137
 138 .globl ML_(blksys_setup)
 139 .globl ML_(blksys_restart)
 140 .globl ML_(blksys_complete)
 141 .globl ML_(blksys_committed)
 142 .globl ML_(blksys_finished)
 143 ML_(blksys_setup):      .quad 1b
 144 ML_(blksys_restart):    .quad 2b
 145 ML_(blksys_complete):   .quad 3b
 146 ML_(blksys_committed):  .quad 4b
 147 ML_(blksys_finished):   .quad 5b
 148
 149 #endif // defined(VGP_mips64_linux)
 150
 151 /* Let the linker know we don't need an executable stack */
 152 MARK_STACK_NO_EXEC
 153
 154 /*--------------------------------------------------------------------*/
 155 /*--- end                                                          ---*/
 156 /*--------------------------------------------------------------------*/