coregrind/m_syswrap/syscall-ppc32-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-ppc32-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2005-2017 Paul Mackerras (paulus@samba.org)
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, write to the Free Software
  24   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  25   02111-1307, USA.
  26
  27   The GNU General Public License is contained in the file COPYING.
  28 */
  29
  30 #include "pub_core_basics_asm.h"
  31
  32 #if defined(VGP_ppc32_linux)
  33
  34 #include "pub_core_vkiscnums_asm.h"
  35 #include "libvex_guest_offsets.h"
  36
  37
  38 /*----------------------------------------------------------------*/
  39 /*
  40         Perform a syscall for the client.  This will run a syscall
  41         with the client's specific per-thread signal mask.
  42
  43         The structure of this function is such that, if the syscall is
  44         interrupted by a signal, we can determine exactly what
  45         execution state we were in with respect to the execution of
  46         the syscall by examining the value of NIP in the signal
  47         handler.  This means that we can always do the appropriate
  48         thing to precisely emulate the kernel's signal/syscall
  49         interactions.
  50
  51         The syscall number is taken from the argument, even though it
  52         should also be in regs->m_gpr[0].  The syscall result is written
  53         back to regs->m_gpr[3]/m_xer/m_result on completion.
  54
  55         Returns 0 if the syscall was successfully called (even if the
  56         syscall itself failed), or a nonzero error code in the lowest
  57         8 bits if one of the sigprocmasks failed (there's no way to
  58         determine which one failed).  And there's no obvious way to
  59         recover from that either, but nevertheless we want to know.
  60
  61         VG_(fixup_guest_state_after_syscall_interrupted) does the
  62         thread state fixup in the case where we were interrupted by a
  63         signal.
  64
  65         Prototype:
  66
  67         UWord ML_(do_syscall_for_client_WRK)(
  68                                   Int syscallno,                // r3
  69                                   void* guest_state,            // r4
  70                                   const vki_sigset_t *sysmask,  // r5
  71                                   const vki_sigset_t *postmask, // r6
  72                                   Int sigsetSzB)                // r7
  73 */
  74 /* from vki_arch.h */
  75 #define VKI_SIG_SETMASK 2
  76
  77 .globl ML_(do_syscall_for_client_WRK)
  78 ML_(do_syscall_for_client_WRK):
  79         /* make a stack frame */
  80         stwu    1,-32(1)
  81         stw     31,28(1)
  82         stw     30,24(1)
  83         stw     29,20(1)
  84         stw     28,16(1)
  85         mr      31,3            /* syscall number */
  86         mr      30,4            /* guest_state */
  87         mr      29,6            /* postmask */
  88         mr      28,7            /* sigsetSzB */
  89
  90         /* set the signal mask for doing the system call */
  91         /* set up for sigprocmask(SIG_SETMASK, sysmask, postmask) */
  92 1:      li      0,__NR_rt_sigprocmask
  93         li      3,VKI_SIG_SETMASK
  94         mr      4,5
  95         mr      5,6
  96         mr      6,7
  97         sc                      /* set the mask */
  98         bso     7f              /* if the sigprocmask fails */
  99
 100         /* load up syscall args from the threadstate */
 101         lwz     3,OFFSET_ppc32_GPR3(30)
 102         lwz     4,OFFSET_ppc32_GPR4(30)
 103         lwz     5,OFFSET_ppc32_GPR5(30)
 104         lwz     6,OFFSET_ppc32_GPR6(30)
 105         lwz     7,OFFSET_ppc32_GPR7(30)
 106         lwz     8,OFFSET_ppc32_GPR8(30)
 107         mr      0,31            /* syscall number */
 108 2:      sc                      /* do the syscall */
 109
 110         /* put the result back in the threadstate  */
 111 3:      stw     3,OFFSET_ppc32_GPR3(30)     /* gst->GPR3 = sc result */
 112         /* copy cr0.so back to simulated state */
 113         mfcr    5                           /* r5 = CR               */
 114         rlwinm  5,5,4,31,31                 /* r5 = (CR >> 28) & 1   */
 115         stb     5,OFFSET_ppc32_CR0_0(30)    /* gst->CR0.SO = cr0.so  */
 116
 117         /* block signals again */
 118         /* set up for sigprocmask(SIG_SETMASK, postmask, NULL) */
 119 4:      li      0,__NR_rt_sigprocmask
 120         li      3,VKI_SIG_SETMASK
 121         mr      4,29
 122         li      5,0
 123         mr      6,28
 124         sc                      /* set the mask */
 125         bso     7f              /* if the sigprocmask fails */
 126         /* now safe from signals */
 127         li      3,0             /* SUCCESS */
 128
 129         /* pop off stack frame */
 130 5:      lwz     28,16(1)
 131         lwz     29,20(1)
 132         lwz     30,24(1)
 133         lwz     31,28(1)
 134         addi    1,1,32
 135         blr
 136
 137         /* failure: return 0x8000 | error code */
 138 7:      ori     3,3,0x8000      /* FAILURE -- ensure return value is nonzero */
 139         b       5b
 140
 141 .section .rodata
 142 /* export the ranges so that
 143    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 144    right thing */
 145
 146 .globl ML_(blksys_setup)
 147 .globl ML_(blksys_restart)
 148 .globl ML_(blksys_complete)
 149 .globl ML_(blksys_committed)
 150 .globl ML_(blksys_finished)
 151 ML_(blksys_setup):     .long 1b
 152 ML_(blksys_restart):   .long 2b
 153 ML_(blksys_complete):  .long 3b
 154 ML_(blksys_committed): .long 4b
 155 ML_(blksys_finished):  .long 5b
 156
 157 #endif // defined(VGP_ppc32_linux)
 158
 159 /* Let the linker know we don't need an executable stack */
 160 MARK_STACK_NO_EXEC
 161
 162 /*--------------------------------------------------------------------*/
 163 /*--- end                                                          ---*/
 164 /*--------------------------------------------------------------------*/