coregrind/m_syswrap/syscall-ppc64be-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-ppc64-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2005-2017 Paul Mackerras <paulus@samba.org>
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, write to the Free Software
  24   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  25   02111-1307, USA.
  26
  27   The GNU General Public License is contained in the file COPYING.
  28 */
  29
  30 #include "pub_core_basics_asm.h"
  31
  32 #if defined(VGP_ppc64be_linux)
  33
  34 #include "pub_core_vkiscnums_asm.h"
  35 #include "libvex_guest_offsets.h"
  36
  37
  38 /*----------------------------------------------------------------*/
  39 /*
  40         Perform a syscall for the client.  This will run a syscall
  41         with the client's specific per-thread signal mask.
  42
  43         The structure of this function is such that, if the syscall is
  44         interrupted by a signal, we can determine exactly what
  45         execution state we were in with respect to the execution of
  46         the syscall by examining the value of NIP in the signal
  47         handler.  This means that we can always do the appropriate
  48         thing to precisely emulate the kernel's signal/syscall
  49         interactions.
  50
  51         The syscall number is taken from the argument, even though it
  52         should also be in regs->m_gpr[0].  The syscall result is written
  53         back to regs->m_gpr[3]/m_xer/m_result on completion.
  54
  55         Returns 0 if the syscall was successfully called (even if the
  56         syscall itself failed), or a nonzero error code in the lowest
  57         8 bits if one of the sigprocmasks failed (there's no way to
  58         determine which one failed).  And there's no obvious way to
  59         recover from that either, but nevertheless we want to know.
  60
  61         VG_(fixup_guest_state_after_syscall_interrupted) does the
  62         thread state fixup in the case where we were interrupted by a
  63         signal.
  64
  65         Prototype:
  66
  67         UWord ML_(do_syscall_for_client_WRK)(
  68                                   Int syscallno,                // r3
  69                                   void* guest_state,            // r4
  70                                   const vki_sigset_t *sysmask,  // r5
  71                                   const vki_sigset_t *postmask, // r6
  72                                   Int sigsetSzB)                // r7
  73 */
  74 /* from vki_arch.h */
  75 #define VKI_SIG_SETMASK 2
  76
  77 .align 2
  78 .globl ML_(do_syscall_for_client_WRK)
  79 .section ".opd","aw"
  80 .align 3
  81 ML_(do_syscall_for_client_WRK):
  82 .quad .ML_(do_syscall_for_client_WRK),.TOC.@tocbase,0
  83 .previous
  84 .type .ML_(do_syscall_for_client_WRK),@function
  85 .globl .ML_(do_syscall_for_client_WRK)
  86 .ML_(do_syscall_for_client_WRK):
  87         /* make a stack frame */
  88         stdu    1,-80(1)
  89         std     31,72(1)
  90         std     30,64(1)
  91         std     29,56(1)
  92         std     28,48(1)
  93         mr      31,3            /* syscall number */
  94         mr      30,4            /* guest_state */
  95         mr      29,6            /* postmask */
  96         mr      28,7            /* sigsetSzB */
  97
  98         /* set the signal mask for doing the system call */
  99         /* set up for sigprocmask(SIG_SETMASK, sysmask, postmask) */
 100 1:      li      0,__NR_rt_sigprocmask
 101         li      3,VKI_SIG_SETMASK
 102         mr      4,5
 103         mr      5,6
 104         mr      6,7
 105         sc                      /* set the mask */
 106         bso     7f              /* if the sigprocmask fails */
 107
 108         /* load up syscall args from the threadstate */
 109         ld      3,OFFSET_ppc64_GPR3(30)
 110         ld      4,OFFSET_ppc64_GPR4(30)
 111         ld      5,OFFSET_ppc64_GPR5(30)
 112         ld      6,OFFSET_ppc64_GPR6(30)
 113         ld      7,OFFSET_ppc64_GPR7(30)
 114         ld      8,OFFSET_ppc64_GPR8(30)
 115         mr      0,31            /* syscall number */
 116 2:      sc                      /* do the syscall */
 117
 118         /* put the result back in the threadstate  */
 119 3:      std     3,OFFSET_ppc64_GPR3(30)     /* gst->GPR3 = sc result */
 120         /* copy cr0.so back to simulated state */
 121         mfcr    5                           /* r5 = CR               */
 122         rlwinm  5,5,4,31,31                 /* r5 = (CR >> 28) & 1   */
 123         stb     5,OFFSET_ppc64_CR0_0(30)    /* gst->CR0.SO = cr0.so  */
 124
 125         /* block signals again */
 126         /* set up for sigprocmask(SIG_SETMASK, postmask, NULL) */
 127 4:      li      0,__NR_rt_sigprocmask
 128         li      3,VKI_SIG_SETMASK
 129         mr      4,29
 130         li      5,0
 131         mr      6,28
 132         sc                      /* set the mask */
 133         bso     7f              /* if the sigprocmask fails */
 134         /* now safe from signals */
 135         li      3,0             /* SUCCESS */
 136
 137         /* pop off stack frame */
 138 5:      ld      28,48(1)
 139         ld      29,56(1)
 140         ld      30,64(1)
 141         ld      31,72(1)
 142         addi    1,1,80
 143         blr
 144
 145         /* failure: return 0x8000 | error code */
 146 7:      ori     3,3,0x8000      /* FAILURE -- ensure return value is nonzero */
 147         b       5b
 148
 149 .section .rodata
 150 /* export the ranges so that
 151    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 152    right thing */
 153
 154 .globl ML_(blksys_setup)
 155 .globl ML_(blksys_restart)
 156 .globl ML_(blksys_complete)
 157 .globl ML_(blksys_committed)
 158 .globl ML_(blksys_finished)
 159 ML_(blksys_setup):     .quad 1b
 160 ML_(blksys_restart):   .quad 2b
 161 ML_(blksys_complete):  .quad 3b
 162 ML_(blksys_committed): .quad 4b
 163 ML_(blksys_finished):  .quad 5b
 164
 165 #endif // defined(VGP_ppc64be_linux)
 166
 167 /* Let the linker know we don't need an executable stack */
 168 MARK_STACK_NO_EXEC
 169
 170 /*--------------------------------------------------------------------*/
 171 /*--- end                                                          ---*/
 172 /*--------------------------------------------------------------------*/