coregrind/m_syswrap/syscall-amd64-darwin.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.       syscall-amd64-darwin.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2000-2017 Julian Seward
  11      jseward@acm.org
  12
  13   This program is free software; you can redistribute it and/or
  14   modify it under the terms of the GNU General Public License as
  15   published by the Free Software Foundation; either version 2 of the
  16   License, or (at your option) any later version.
  17
  18   This program is distributed in the hope that it will be useful, but
  19   WITHOUT ANY WARRANTY; without even the implied warranty of
  20   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21   General Public License for more details.
  22
  23   You should have received a copy of the GNU General Public License
  24   along with this program; if not, write to the Free Software
  25   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  26   02111-1307, USA.
  27
  28   The GNU General Public License is contained in the file COPYING.
  29 */
  30
  31 #include "pub_core_basics_asm.h"
  32
  33 #if defined(VGP_amd64_darwin)
  34
  35 #include "pub_core_vkiscnums_asm.h"
  36 #include "libvex_guest_offsets.h"
  37
  38
  39 /*----------------------------------------------------------------*/
  40 /*
  41         Perform a syscall for the client.  This will run a syscall
  42         with the client's specific per-thread signal mask.
  43
  44         The structure of this function is such that, if the syscall is
  45         interrupted by a signal, we can determine exactly what
  46         execution state we were in with respect to the execution of
  47         the syscall by examining the value of %eip in the signal
  48         handler.  This means that we can always do the appropriate
  49         thing to precisely emulate the kernel's signal/syscall
  50         interactions.
  51
  52         The syscall number is taken from the argument, even though it
  53         should also be in guest_state->guest_RAX.  The syscall result
  54         is written back to guest_state->guest_RAX on completion.
  55
  56         Returns 0 if the syscall was successfully called (even if the
  57         syscall itself failed), or a -ve error code if one of the
  58         sigprocmasks failed (there's no way to determine which one
  59         failed).
  60
  61         VG_(fixup_guest_state_after_syscall_interrupted) does the
  62         thread state fixup in the case where we were interrupted by a
  63         signal.
  64
  65         Prototype:
  66
  67         Int ML_(do_syscall_for_client_WRK(
  68                                   Int syscallno,                // rdi
  69                                   void* guest_state,            // rsi
  70                                   const vki_sigset_t *sysmask,  // rdx
  71                                   const vki_sigset_t *postmask, // rcx
  72                                   Int sigsetSzB)                // r8
  73
  74         Note that sigsetSzB is totally ignored (and irrelevant).
  75 */
  76
  77 /* from vki_arch.h */
  78 #define VKI_SIG_SETMASK 3
  79
  80 /* DO_SYSCALL MACH|MDEP|UNIX */
  81 #define MACH 1
  82 #define MDEP 2
  83 #define UNIX 3
  84
  85 .macro DO_SYSCALL
  86         /* save callee-saved regs */
  87         pushq   %rbp
  88         movq    %rsp, %rbp
  89         // stack is now aligned
  90         pushq   %rdi  // -8(%rbp)   syscallno
  91         pushq   %rsi  // -16(%rbp)  guest_state
  92         pushq   %rdx  // -24(%rbp)  sysmask
  93         pushq   %rcx  // -32(%rbp)  postmask
  94         pushq   %r8   // -40(%rbp)  sigsetSzB
  95         // stack is now aligned
  96
  97 L_$0_1: /* Even though we can't take a signal until the sigprocmask completes,
  98            start the range early.
  99            If rip is in the range [1,2), the syscall hasn't been started yet */
 100
 101         /* Set the signal mask which should be current during the syscall. */
 102         /* GrP fixme signals
 103            DDD: JRS fixme: use __NR___pthread_sigmask, not __NR_rt_sigprocmask
 104         movq    $__NR_rt_sigprocmask, %rax      // syscall #
 105         movq    $VKI_SIG_SETMASK, %rdi          // how
 106         movq    -24(%rbp), %rsi                 // sysmask
 107         movq    -32(%rbp), %rdx                 // postmask
 108         movq    -40(%rbp), %r10                 // sigsetSzB in r10 not rcx
 109         DDD: fixme return address
 110         syscall
 111
 112         jnc     7f      // sigprocmask failed
 113         */
 114
 115         /* OK, that worked.  Now do the syscall proper. */
 116
 117         /* 6 register parameters */
 118         movq    -16(%rbp), %r11 /* r11 = VexGuestAMD64State * */
 119         movq    OFFSET_amd64_RDI(%r11), %rdi
 120         movq    OFFSET_amd64_RSI(%r11), %rsi
 121         movq    OFFSET_amd64_RDX(%r11), %rdx
 122         movq    OFFSET_amd64_RCX(%r11), %r10 /* rcx is passed in r10 instead */
 123         movq    OFFSET_amd64_R8(%r11), %r8
 124         movq    OFFSET_amd64_R9(%r11), %r9
 125         /* 2 stack parameters plus return address (ignored by syscall) */
 126         movq    OFFSET_amd64_RSP(%r11), %r11 /* r11 = simulated RSP */
 127         movq    16(%r11), %rax
 128         pushq   %rax
 129         movq    8(%r11), %rax
 130         pushq   %rax
 131         /* stack is currently aligned - return address misaligns */
 132         movq    0(%r11), %rax
 133         pushq   %rax
 134         /* syscallno */
 135         movq    -8(%rbp), %rax
 136
 137         /* If rip==2, then the syscall was either just about
 138            to start, or was interrupted and the kernel was
 139            restarting it. */
 140 L_$0_2: syscall
 141 L_$0_3: /* In the range [3, 4), the syscall result is in %rax,
 142            but hasn't been committed to RAX. */
 143
 144         /* stack contents: 3 words for syscall above, plus our prologue */
 145         setc    0(%rsp)         /* stash returned carry flag */
 146
 147         movq    -16(%rbp), %r11 /* r11 = VexGuestAMD64State * */
 148         movq    %rax, OFFSET_amd64_RAX(%r11)    /* save back to RAX */
 149         movq    %rdx, OFFSET_amd64_RDX(%r11)    /* save back to RDX */
 150
 151 .if $0 == UNIX
 152         /* save carry flag to VEX */
 153         xor     %rax, %rax
 154         movb    0(%rsp), %al
 155         movq    %rax, %rdi      /* arg1 = new flag */
 156         movq    %r11, %rsi      /* arg2 = vex state */
 157         addq    $$24, %rsp      /* remove syscall parameters */
 158         call    _LibVEX_GuestAMD64_put_rflag_c
 159 .else
 160         addq    $$24, %rsp      /* remove syscall parameters*/
 161 .endif
 162
 163 L_$0_4: /* Re-block signals.  If eip is in [4,5), then the syscall
 164            is complete and we needn't worry about it. */
 165         /* GrP fixme signals
 166            DDD: JRS fixme: use __NR___pthread_sigmask, not __NR_rt_sigprocmask
 167         PUSH_di_si_dx_cx_8
 168
 169         movq    $__NR_rt_sigprocmask, %rax      // syscall #
 170         movq    $VKI_SIG_SETMASK, %rdi          // how
 171         movq    %rcx, %rsi                      // postmask
 172         xorq    %rdx, %rdx                      // NULL
 173         movq    %r8, %r10                       // sigsetSzB
 174         DDD: fixme return address
 175         syscall
 176
 177         POP_di_si_dx_cx_8
 178
 179         jnc     7f      // sigprocmask failed
 180         */
 181 L_$0_5: /* now safe from signals */
 182         movq    $$0, %rax       /* SUCCESS */
 183         movq    %rbp, %rsp
 184         popq    %rbp
 185         ret
 186
 187 /* GrP fixme signals
 188 L_$0_7: // failure:      return 0x8000 | error code
 189         DDD: fixme return value
 190         movq    %rbp, %rsp
 191         popq    %rbp
 192         ret
 193 */
 194
 195 .endmacro
 196
 197
 198 .globl ML_(do_syscall_for_client_unix_WRK)
 199 ML_(do_syscall_for_client_unix_WRK):
 200         DO_SYSCALL UNIX
 201
 202 .globl ML_(do_syscall_for_client_mach_WRK)
 203 ML_(do_syscall_for_client_mach_WRK):
 204         DO_SYSCALL MACH
 205
 206 .globl ML_(do_syscall_for_client_mdep_WRK)
 207 ML_(do_syscall_for_client_mdep_WRK):
 208         DO_SYSCALL MDEP
 209
 210 .data
 211 /* export the ranges so that
 212    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 213    right thing */
 214
 215 /* eg MK_L_SCLASS_N(UNIX,99) produces L_3_99
 216    since UNIX is #defined to 3 at the top of this file */
 217 #define FOO(scclass,labelno) L_##scclass##_##labelno
 218 #define MK_L_SCCLASS_N(scclass,labelno) FOO(scclass,labelno)
 219
 220 .globl ML_(blksys_setup_MACH)
 221 .globl ML_(blksys_restart_MACH)
 222 .globl ML_(blksys_complete_MACH)
 223 .globl ML_(blksys_committed_MACH)
 224 .globl ML_(blksys_finished_MACH)
 225 ML_(blksys_setup_MACH): .quad MK_L_SCCLASS_N(MACH,1)
 226 ML_(blksys_restart_MACH):       .quad MK_L_SCCLASS_N(MACH,2)
 227 ML_(blksys_complete_MACH):      .quad MK_L_SCCLASS_N(MACH,3)
 228 ML_(blksys_committed_MACH):     .quad MK_L_SCCLASS_N(MACH,4)
 229 ML_(blksys_finished_MACH):      .quad MK_L_SCCLASS_N(MACH,5)
 230
 231 .globl ML_(blksys_setup_MDEP)
 232 .globl ML_(blksys_restart_MDEP)
 233 .globl ML_(blksys_complete_MDEP)
 234 .globl ML_(blksys_committed_MDEP)
 235 .globl ML_(blksys_finished_MDEP)
 236 ML_(blksys_setup_MDEP): .quad MK_L_SCCLASS_N(MDEP,1)
 237 ML_(blksys_restart_MDEP):       .quad MK_L_SCCLASS_N(MDEP,2)
 238 ML_(blksys_complete_MDEP):      .quad MK_L_SCCLASS_N(MDEP,3)
 239 ML_(blksys_committed_MDEP):     .quad MK_L_SCCLASS_N(MDEP,4)
 240 ML_(blksys_finished_MDEP):      .quad MK_L_SCCLASS_N(MDEP,5)
 241
 242 .globl ML_(blksys_setup_UNIX)
 243 .globl ML_(blksys_restart_UNIX)
 244 .globl ML_(blksys_complete_UNIX)
 245 .globl ML_(blksys_committed_UNIX)
 246 .globl ML_(blksys_finished_UNIX)
 247 ML_(blksys_setup_UNIX): .quad MK_L_SCCLASS_N(UNIX,1)
 248 ML_(blksys_restart_UNIX):       .quad MK_L_SCCLASS_N(UNIX,2)
 249 ML_(blksys_complete_UNIX):      .quad MK_L_SCCLASS_N(UNIX,3)
 250 ML_(blksys_committed_UNIX):     .quad MK_L_SCCLASS_N(UNIX,4)
 251 ML_(blksys_finished_UNIX):      .quad MK_L_SCCLASS_N(UNIX,5)
 252
 253 #endif // defined(VGP_amd64_darwin)
 254
 255 /* Let the linker know we don't need an executable stack */
 256 MARK_STACK_NO_EXEC
 257
 258 /*--------------------------------------------------------------------*/
 259 /*--- end                                                          ---*/
 260 /*--------------------------------------------------------------------*/