installer/vsinstaller.iss

   1 #define AppName = 'VapourSynth'
   2 #define Version = 'R14'
   3
   4 [Setup]
   5 OutputDir=Compiled
   6 OutputBaseFilename=vapoursynth_installer
   7 Compression=lzma2/max
   8 InternalCompressLevel=max
   9 SolidCompression=yes
  10 LZMAUseSeparateProcess=yes
  11 VersionInfoDescription={#= AppName} {#= Version} Installer
  12 AppId={#= AppName}
  13 AppName={#= AppName}
  14 AppVersion={#= Version}
  15 AppVerName={#= AppName} {#= Version}
  16 AppPublisher=Fredrik Mellbin
  17 AppPublisherURL=http://www.vapoursynth.com/
  18 AppSupportURL=http://www.vapoursynth.com/
  19 AppUpdatesURL=http://www.vapoursynth.com/
  20 VersionInfoVersion=0.9.0.2
  21 DefaultDirName={pf}\VapourSynth
  22 DefaultGroupName=VapourSynth
  23 AllowCancelDuringInstall=no
  24 AllowNoIcons=yes
  25 AllowUNCPath=no
  26 MinVersion=0,5.1
  27 PrivilegesRequired=poweruser
  28 FlatComponentsList=yes
  29
  30 [Types]
  31 Name: Full; Description: Full installation
  32
  33 [Components]
  34 Name: Core; Description: {#= AppName} {#= Version}; Types: Full; Flags: fixed
  35
  36 [Tasks]
  37 Name: newvpyfile; Description: "Add new .vpy shortcut"; GroupDescription: "New File Shortcuts:"
  38
  39 [Files]
  40 Source: vapoursynth.dll; DestDir: {code:GetPythonPath}; Flags: ignoreversion uninsrestartdelete restartreplace
  41 Source: vapoursynth.dll; DestDir: {app}; Flags: ignoreversion uninsrestartdelete restartreplace
  42 Source: vapoursynth.pyd; DestDir: {code:GetPythonPath}; Flags: ignoreversion uninsrestartdelete restartreplace
  43 Source: QtCore4.dll; DestDir: {code:GetPythonPath}; Flags: ignoreversion uninsrestartdelete restartreplace
  44 Source: vsfs.dll; DestDir: {app}; Flags: ignoreversion uninsrestartdelete restartreplace
  45 Source: template.vpy; DestDir: {app}; Flags: ignoreversion uninsrestartdelete restartreplace
  46 Source: vsvfw.dll; DestDir: {sys}; Flags: ignoreversion uninsrestartdelete restartreplace
  47 Source: msvcr100.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile
  48 Source: msvcp100.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile
  49
  50 [Icons]
  51 Name: {group}\VapourSynth Website; Filename: http://www.vapoursynth.com/
  52 Name: {group}\VapourSynth Documentation; Filename: http://www.vapoursynth.com/doc/
  53
  54 [Registry]
  55 Root: HKLM; Subkey: SOFTWARE\Classes\CLSID\{{58F74CA0-BD0E-4664-A49B-8D10E6F0C131}; ValueType: string; ValueName: ""; ValueData: "VapourSynth"; Flags: uninsdeletevalue uninsdeletekeyifempty
  56 Root: HKLM; Subkey: SOFTWARE\Classes\CLSID\{{58F74CA0-BD0E-4664-A49B-8D10E6F0C131}\InProcServer32; ValueType: string; ValueName: ""; ValueData: "vsvfw.dll"; Flags: uninsdeletevalue uninsdeletekeyifempty
  57 Root: HKLM; Subkey: SOFTWARE\Classes\CLSID\{{58F74CA0-BD0E-4664-A49B-8D10E6F0C131}\InProcServer32; ValueType: string; ValueName: "ThreadingModel"; ValueData: "Apartment"; Flags: uninsdeletevalue uninsdeletekeyifempty
  58 Root: HKLM; Subkey: SOFTWARE\Classes\Media Type\Extensions\.vpy; ValueType: string; ValueName: ""; ValueData: ""; Flags: uninsdeletevalue uninsdeletekeyifempty
  59 Root: HKLM; Subkey: SOFTWARE\Classes\Media Type\Extensions\.vpy; ValueType: string; ValueName: "Source Filter"; ValueData: "{{D3588AB0-0781-11CE-B03A-0020AF0BA770}"; Flags: uninsdeletevalue uninsdeletekeyifempty
  60 Root: HKLM; Subkey: SOFTWARE\Classes\.vpy; ValueType: string; ValueName: ""; ValueData: "vsfile"; Flags: uninsdeletevalue uninsdeletekeyifempty
  61 Root: HKLM; Subkey: SOFTWARE\Classes\vsfile; ValueType: string; ValueName: ""; ValueData: "VapourSynth Python Script"; Flags: uninsdeletevalue uninsdeletekeyifempty
  62 Root: HKLM; Subkey: SOFTWARE\Classes\vsfile\DefaultIcon; ValueType: string; ValueName: ""; ValueData: "vsvfw.dll,0"; Flags: uninsdeletevalue uninsdeletekeyifempty
  63 Root: HKLM; Subkey: SOFTWARE\Classes\AVIFile\Extensions\VPY; ValueType: string; ValueName: ""; ValueData: "{{58F74CA0-BD0E-4664-A49B-8D10E6F0C131}"; Flags: uninsdeletevalue uninsdeletekeyifempty
  64 Root: HKLM; Subkey: SOFTWARE\Classes\.vpy\ShellNew; ValueType: string; ValueName: "FileName"; ValueData: "{app}\template.vpy"; Flags: uninsdeletevalue uninsdeletekeyifempty; Tasks: newvpyfile
  65
  66 [Code]
  67
  68 var PythonPath: string;
  69
  70 function InitializeSetup(): Boolean;
  71 begin
  72   Result := RegQueryStringValue(HKLM, 'SOFTWARE\Python\PythonCore\3.3\InstallPath', '', PythonPath);
  73   if not Result then
  74     MsgBox('Python 3.3 installation not found.', mbCriticalError, MB_OK);
  75 end;
  76
  77 function GetPythonPath(Param: String): String;
  78 begin
  79   Result := PythonPath + '\Lib\site-packages';
  80 end;