plugin/fugitive.vim

   1 " fugitive.vim - A Git wrapper so awesome, it should be illegal
   2 " Maintainer:   Tim Pope <http://tpo.pe/>
   3 " Version:      2.4
   4 " GetLatestVimScripts: 2975 1 :AutoInstall: fugitive.vim
   5
   6 if exists('g:loaded_fugitive')
   7   finish
   8 endif
   9 let g:loaded_fugitive = 1
  10
  11 function! FugitiveGitDir(...) abort
  12   if !a:0 || a:1 ==# -1
  13     return get(b:, 'git_dir', '')
  14   elseif type(a:1) == type(0)
  15     return getbufvar(a:1, 'git_dir')
  16   elseif type(a:1) == type('')
  17     return substitute(s:Slash(a:1), '/$', '', '')
  18   else
  19     return ''
  20   endif
  21 endfunction
  22
  23 function! FugitiveCommonDir(...) abort
  24   let dir = FugitiveGitDir(a:0 ? a:1 : -1)
  25   if empty(dir)
  26     return ''
  27   endif
  28   return fugitive#CommonDir(dir)
  29 endfunction
  30
  31 function! FugitiveWorkTree(...) abort
  32   return FugitiveTreeForGitDir(FugitiveGitDir(a:0 ? a:1 : -1))
  33 endfunction
  34
  35 function! FugitiveReal(...) abort
  36   let file = a:0 ? a:1 : @%
  37   if file =~# '^\a\a\+:' || a:0 > 1
  38     return call('fugitive#Real', [file] + a:000[1:-1])
  39   elseif file =~# '^/\|^\a:\|^$'
  40     return file
  41   else
  42     return fnamemodify(file, ':p' . (file =~# '[\/]$' ? '' : ':s?[\/]$??'))
  43   endif
  44 endfunction
  45
  46 function! FugitiveRoute(...) abort
  47   return fugitive#Route(a:0 ? a:1 : bufnr(''), FugitiveGitDir(a:0 > 1 ? a:2 : -1))
  48 endfunction
  49
  50 function! FugitivePath(...) abort
  51   if a:0 > 1
  52     return fugitive#Path(a:1, a:2, FugitiveGitDir(a:0 > 2 ? a:3 : -1))
  53   else
  54     return FugitiveReal(a:0 ? a:1 : @%)
  55   endif
  56 endfunction
  57
  58 function! FugitiveParse(...) abort
  59   let path = s:Slash(a:0 ? a:1 : @%)
  60   let vals = matchlist(path, '\c^fugitive:\%(//\)\=\(.\{-\}\)\%(//\|::\)\(\x\{40\}\|[0-3]\)\(/.*\)\=$')
  61   if len(vals)
  62     return [(vals[2] =~# '^.$' ? ':' : '') . vals[2] . substitute(vals[3], '^/', ':', ''), vals[1]]
  63   endif
  64   let v:errmsg = 'fugitive: invalid Fugitive URL ' . path
  65   throw v:errmsg
  66 endfunction
  67
  68 function! FugitiveConfig(key, ...) abort
  69   return fugitive#Config(a:key, FugitiveGitDir(a:0 ? a:1 : -1))
  70 endfunction
  71
  72 function! FugitiveRemoteUrl(...) abort
  73   return fugitive#RemoteUrl(a:0 ? a:1 : '', FugitiveGitDir(a:0 > 1 ? a:2 : -1))
  74 endfunction
  75
  76 function! FugitiveHead(...) abort
  77   let dir = FugitiveGitDir(a:0 > 1 ? a:2 : -1)
  78   if empty(dir)
  79     return ''
  80   endif
  81   return fugitive#Head(a:0 ? a:1 : 0, dir)
  82 endfunction
  83
  84 function! FugitiveStatusline(...) abort
  85   if !exists('b:git_dir')
  86     return ''
  87   endif
  88   return fugitive#Statusline()
  89 endfunction
  90
  91 function! FugitiveIsGitDir(path) abort
  92   let path = substitute(a:path, '[\/]$', '', '') . '/'
  93   return getfsize(path.'HEAD') > 10 && (
  94         \ isdirectory(path.'objects') && isdirectory(path.'refs') ||
  95         \ getftype(path.'commondir') ==# 'file')
  96 endfunction
  97
  98 let s:worktree_for_dir = {}
  99 let s:dir_for_worktree = {}
 100 function! FugitiveTreeForGitDir(path) abort
 101   let dir = a:path
 102   if dir =~# '/\.git$'
 103     return len(dir) ==# 5 ? '/' : dir[0:-6]
 104   endif
 105   if !has_key(s:worktree_for_dir, dir)
 106     let s:worktree_for_dir[dir] = ''
 107     let config_file = dir . '/config'
 108     if filereadable(config_file)
 109       let config = readfile(config_file,'',10)
 110       call filter(config,'v:val =~# "^\\s*worktree *="')
 111       if len(config) == 1
 112         let worktree = matchstr(config[0], '= *\zs.*')
 113       endif
 114     elseif filereadable(dir . '/gitdir')
 115       let worktree = fnamemodify(readfile(dir . '/gitdir')[0], ':h')
 116       if worktree ==# '.'
 117         unlet! worktree
 118       endif
 119     endif
 120     if exists('worktree')
 121       let s:worktree_for_dir[dir] = worktree
 122       let s:dir_for_worktree[s:worktree_for_dir[dir]] = dir
 123     endif
 124   endif
 125   if s:worktree_for_dir[dir] =~# '^\.'
 126     return simplify(dir . '/' . s:worktree_for_dir[dir])
 127   else
 128     return s:worktree_for_dir[dir]
 129   endif
 130 endfunction
 131
 132 function! FugitiveExtractGitDir(path) abort
 133   let path = s:Slash(a:path)
 134   if path =~# '^fugitive:'
 135     return matchstr(path, '\C^fugitive:\%(//\)\=\zs.\{-\}\ze\%(//\|::\|$\)')
 136   elseif isdirectory(path)
 137     let path = fnamemodify(path, ':p:s?/$??')
 138   else
 139     let path = fnamemodify(path, ':p:h:s?/$??')
 140   endif
 141   let pre = substitute(matchstr(path, '^\a\a\+\ze:'), '^.', '\u&', '')
 142   if len(pre) && exists('*' . pre . 'Real')
 143     let path = s:Slash({pre}Real(path))
 144   endif
 145   let root = resolve(path)
 146   if root !=# path
 147     silent! exe haslocaldir() ? 'lcd .' : 'cd .'
 148   endif
 149   let previous = ""
 150   while root !=# previous
 151     if root =~# '\v^//%([^/]+/?)?$'
 152       break
 153     endif
 154     if index(split($GIT_CEILING_DIRECTORIES, ':'), root) >= 0
 155       break
 156     endif
 157     if root ==# $GIT_WORK_TREE && FugitiveIsGitDir($GIT_DIR)
 158       return simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??'))
 159     endif
 160     if FugitiveIsGitDir($GIT_DIR)
 161       call FugitiveWorkTree(simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??')))
 162       if has_key(s:dir_for_worktree, root)
 163         return s:dir_for_worktree[root]
 164       endif
 165     endif
 166     let dir = substitute(root, '[\/]$', '', '') . '/.git'
 167     let type = getftype(dir)
 168     if type ==# 'dir' && FugitiveIsGitDir(dir)
 169       return dir
 170     elseif type ==# 'link' && FugitiveIsGitDir(dir)
 171       return resolve(dir)
 172     elseif type !=# '' && filereadable(dir)
 173       let line = get(readfile(dir, '', 1), 0, '')
 174       if line =~# '^gitdir: \.' && FugitiveIsGitDir(root.'/'.line[8:-1])
 175         return simplify(root.'/'.line[8:-1])
 176       elseif line =~# '^gitdir: ' && FugitiveIsGitDir(line[8:-1])
 177         return line[8:-1]
 178       endif
 179     elseif FugitiveIsGitDir(root)
 180       return root
 181     endif
 182     let previous = root
 183     let root = fnamemodify(root, ':h')
 184   endwhile
 185   return ''
 186 endfunction
 187
 188 function! FugitiveDetect(path) abort
 189   if exists('b:git_dir') && b:git_dir =~# '^$\|/$\|^fugitive:'
 190     unlet b:git_dir
 191   endif
 192   if !exists('b:git_dir')
 193     let dir = FugitiveExtractGitDir(a:path)
 194     if dir !=# ''
 195       let b:git_dir = dir
 196     endif
 197   endif
 198   if exists('b:git_dir')
 199     return fugitive#Init()
 200   endif
 201 endfunction
 202
 203 function! FugitiveFind(...) abort
 204   return call('FugitiveRoute', a:000)
 205 endfunction
 206
 207 function! FugitiveGenerate(...) abort
 208   return call('FugitiveRoute', a:000)
 209 endfunction
 210
 211 function! s:Slash(path) abort
 212   if exists('+shellslash')
 213     return tr(a:path, '\', '/')
 214   else
 215     return a:path
 216   endif
 217 endfunction
 218
 219 function! s:ProjectionistDetect() abort
 220   let file = s:Slash(get(g:, 'projectionist_file', ''))
 221   let dir = FugitiveExtractGitDir(file)
 222   let base = matchstr(file, '^fugitive://.\{-\}//\x\+')
 223   if empty(base)
 224     let base = FugitiveTreeForGitDir(dir)
 225   endif
 226   if len(base)
 227     if exists('+shellslash') && !&shellslash
 228       let base = tr(base, '/', '\')
 229     endif
 230     call projectionist#append(base, FugitiveCommonDir(dir) . '/info/projections.json')
 231   endif
 232 endfunction
 233
 234 augroup fugitive
 235   autocmd!
 236
 237   autocmd BufNewFile,BufReadPost * call FugitiveDetect(expand('<amatch>:p'))
 238   autocmd FileType           netrw call FugitiveDetect(fnamemodify(get(b:, 'netrw_curdir', expand('<amatch>')), ':p'))
 239   autocmd User NERDTreeInit,NERDTreeNewRoot
 240         \ if exists('b:NERDTree.root.path.str') |
 241         \   call FugitiveDetect(b:NERDTree.root.path.str()) |
 242         \ endif
 243   autocmd VimEnter * if empty(expand('<amatch>'))|call FugitiveDetect(getcwd())|endif
 244   autocmd CmdWinEnter * call FugitiveDetect(expand('#:p'))
 245
 246   autocmd FileType git
 247         \ if exists('b:git_dir') |
 248         \   call fugitive#MapJumps() |
 249         \   call fugitive#MapCfile() |
 250         \ endif
 251   autocmd FileType gitcommit
 252         \ if exists('b:git_dir') |
 253         \   call fugitive#MapCfile('fugitive#StatusCfile()') |
 254         \ endif
 255   autocmd FileType gitrebase
 256         \ let &l:include = '^\%(pick\|squash\|edit\|reword\|fixup\|drop\|[pserfd]\)\>' |
 257         \ if exists('b:git_dir') |
 258         \   let &l:includeexpr = 'v:fname =~# ''^\x\{4,40\}$'' ? FugitiveRoute(v:fname) : ' .
 259         \   (len(&l:includeexpr) ? &l:includeexpr : 'v:fname') |
 260         \ endif |
 261         \ let b:undo_ftplugin = get(b:, 'undo_ftplugin', 'exe') . '|setl inex= inc='
 262
 263   autocmd BufReadCmd index{,.lock}
 264         \ if FugitiveIsGitDir(expand('<amatch>:p:h')) |
 265         \   let b:git_dir = s:Slash(expand('<amatch>:p:h')) |
 266         \   exe fugitive#BufReadStatus() |
 267         \ elseif filereadable(expand('<amatch>')) |
 268         \   read <amatch> |
 269         \   1delete_ |
 270         \ endif
 271   autocmd BufReadCmd    fugitive://*//*             exe fugitive#BufReadCmd()
 272   autocmd BufWriteCmd   fugitive://*//[0-3]/*       exe fugitive#BufWriteCmd()
 273   autocmd FileReadCmd   fugitive://*//*             exe fugitive#FileReadCmd()
 274   autocmd FileWriteCmd  fugitive://*//[0-3]/*       exe fugitive#FileWriteCmd()
 275   if exists('##SourceCmd')
 276     autocmd SourceCmd     fugitive://*//*    nested exe fugitive#SourceCmd()
 277   endif
 278
 279   autocmd User Flags call Hoist('buffer', function('FugitiveStatusline'))
 280
 281   autocmd User ProjectionistDetect call s:ProjectionistDetect()
 282 augroup END