plugin/fugitive.vim

   1 " fugitive.vim - A Git wrapper so awesome, it should be illegal
   2 " Maintainer:   Tim Pope <http://tpo.pe/>
   3 " Version:      2.4
   4 " GetLatestVimScripts: 2975 1 :AutoInstall: fugitive.vim
   5
   6 if exists('g:loaded_fugitive')
   7   finish
   8 endif
   9 let g:loaded_fugitive = 1
  10
  11 function! s:shellslash(path) abort
  12   if &shell =~? 'cmd' || exists('+shellslash') && !&shellslash
  13     return tr(a:path, '\', '/')
  14   else
  15     return a:path
  16   endif
  17 endfunction
  18
  19 function! FugitiveGitDir(...) abort
  20   if !a:0 || a:1 ==# -1
  21     return get(b:, 'git_dir', '')
  22   elseif type(a:1) == type(0)
  23     return getbufvar(a:1, 'git_dir')
  24   elseif type(a:1) == type('')
  25     return substitute(s:shellslash(a:1), '/$', '', '')
  26   else
  27     return ''
  28   endif
  29 endfunction
  30
  31 function! FugitiveIsGitDir(path) abort
  32   let path = substitute(a:path, '[\/]$', '', '') . '/'
  33   return getfsize(path.'HEAD') > 10 && (
  34         \ isdirectory(path.'objects') && isdirectory(path.'refs') ||
  35         \ getftype(path.'commondir') ==# 'file')
  36 endfunction
  37
  38 let s:worktree_for_dir = {}
  39 let s:dir_for_worktree = {}
  40 function! FugitiveWorkTree(...) abort
  41   let dir = substitute(s:shellslash(a:0 ? a:1 : get(b:, 'git_dir', '')), '/$', '', '')
  42   if dir =~# '/\.git$'
  43     return len(dir) ==# 5 ? '/' : dir[0:-6]
  44   endif
  45   if !has_key(s:worktree_for_dir, dir)
  46     let s:worktree_for_dir[dir] = ''
  47     let config_file = dir . '/config'
  48     if filereadable(config_file)
  49       let config = readfile(config_file,'',10)
  50       call filter(config,'v:val =~# "^\\s*worktree *="')
  51       if len(config) == 1
  52         let worktree = matchstr(config[0], '= *\zs.*')
  53       endif
  54     elseif filereadable(dir . '/gitdir')
  55       let worktree = fnamemodify(readfile(dir . '/gitdir')[0], ':h')
  56       if worktree ==# '.'
  57         unlet! worktree
  58       endif
  59     endif
  60     if exists('worktree')
  61       let s:worktree_for_dir[dir] = worktree
  62       let s:dir_for_worktree[s:worktree_for_dir[dir]] = dir
  63     endif
  64   endif
  65   if s:worktree_for_dir[dir] =~# '^\.'
  66     return simplify(dir . '/' . s:worktree_for_dir[dir])
  67   else
  68     return s:worktree_for_dir[dir]
  69   endif
  70 endfunction
  71
  72 function! FugitiveReal(...) abort
  73   let file = a:0 ? a:1 : @%
  74   if file =~? '^fugitive:' || a:0 > 1
  75     return call('fugitive#Real', [file] + a:000[1:-1])
  76   elseif file =~# '^/\|^\a\+:\|^$'
  77     return file
  78   else
  79     return fnamemodify(file, ':p' . (file =~# '[\/]$' ? '' : ':s?[\/]$??'))
  80   endif
  81 endfunction
  82
  83 function! FugitivePath(...) abort
  84   if a:0 > 1
  85     return fugitive#Path(a:1, a:2, FugitiveGitDir(a:0 > 2 ? a:3 : -1))
  86   else
  87     return FugitiveReal(a:0 ? a:1 : @%)
  88   endif
  89 endfunction
  90
  91 function! FugitiveGenerate(...) abort
  92   if a:0 && s:shellslash(a:0) =~# '^\%(\a\a\+:\)\=\%(a:\)\=/\|^[~$]'
  93     return a:1
  94   endif
  95   return fugitive#repo(FugitiveGitDir(a:0 > 1 ? a:2 : -1)).translate(a:0 ? a:1 : '', 1)
  96 endfunction
  97
  98 function! FugitiveParse(...) abort
  99   let path = s:shellslash(a:0 ? a:1 : @%)
 100   let vals = matchlist(path, '\c^fugitive:\%(//\)\=\(.\{-\}\)\%(//\|::\)\(\x\{40\}\|[0-3]\)\(/.*\)\=$')
 101   if len(vals)
 102     return [(vals[2] =~# '^.$' ? ':' : '') . vals[2] . substitute(vals[3], '^/', ':', ''), vals[1]]
 103   endif
 104   let v:errmsg = 'fugitive: invalid Fugitive URL ' . path
 105   throw v:errmsg
 106 endfunction
 107
 108 function! FugitiveConfig(key, ...) abort
 109   return fugitive#Config(a:key, FugitiveGitDir(a:0 ? a:1 : -1))
 110 endfunction
 111
 112 function! FugitiveRemoteUrl(...) abort
 113   return fugitive#RemoteUrl(a:0 ? a:1 : '', FugitiveGitDir(a:0 > 1 ? a:2 : -1))
 114 endfunction
 115
 116 function! FugitiveHead(...) abort
 117   let dir = FugitiveGitDir(a:0 > 1 ? a:2 : -1)
 118   if empty(dir)
 119     return ''
 120   endif
 121   return fugitive#repo(dir).head(a:0 ? a:1 : 0)
 122 endfunction
 123
 124 function! FugitiveStatusline(...) abort
 125   if !exists('b:git_dir')
 126     return ''
 127   endif
 128   return fugitive#Statusline()
 129 endfunction
 130
 131 function! FugitiveTreeForGitDir(path) abort
 132   return FugitiveWorkTree(a:path)
 133 endfunction
 134
 135 function! FugitiveExtractGitDir(path) abort
 136   let path = s:shellslash(a:path)
 137   if path =~# '^fugitive:'
 138     return matchstr(path, '\C^fugitive:\%(//\)\=\zs.\{-\}\ze\%(//\|::\|$\)')
 139   elseif isdirectory(path)
 140     let path = fnamemodify(path, ':p:s?/$??')
 141   else
 142     let path = fnamemodify(path, ':p:h:s?/$??')
 143   endif
 144   let pre = substitute(matchstr(path, '^\a\a\+\ze:'), '^.', '\u&', '')
 145   if len(pre) && exists('*' . pre . 'Real')
 146     let path = s:shellslash({pre}Real(path))
 147   endif
 148   let root = resolve(path)
 149   if root !=# path
 150     silent! exe haslocaldir() ? 'lcd .' : 'cd .'
 151   endif
 152   let previous = ""
 153   while root !=# previous
 154     if root =~# '\v^//%([^/]+/?)?$'
 155       break
 156     endif
 157     if index(split($GIT_CEILING_DIRECTORIES, ':'), root) >= 0
 158       break
 159     endif
 160     if root ==# $GIT_WORK_TREE && FugitiveIsGitDir($GIT_DIR)
 161       return simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??'))
 162     endif
 163     if FugitiveIsGitDir($GIT_DIR)
 164       call FugitiveWorkTree(simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??')))
 165       if has_key(s:dir_for_worktree, root)
 166         return s:dir_for_worktree[root]
 167       endif
 168     endif
 169     let dir = substitute(root, '[\/]$', '', '') . '/.git'
 170     let type = getftype(dir)
 171     if type ==# 'dir' && FugitiveIsGitDir(dir)
 172       return dir
 173     elseif type ==# 'link' && FugitiveIsGitDir(dir)
 174       return resolve(dir)
 175     elseif type !=# '' && filereadable(dir)
 176       let line = get(readfile(dir, '', 1), 0, '')
 177       if line =~# '^gitdir: \.' && FugitiveIsGitDir(root.'/'.line[8:-1])
 178         return simplify(root.'/'.line[8:-1])
 179       elseif line =~# '^gitdir: ' && FugitiveIsGitDir(line[8:-1])
 180         return line[8:-1]
 181       endif
 182     elseif FugitiveIsGitDir(root)
 183       return root
 184     endif
 185     let previous = root
 186     let root = fnamemodify(root, ':h')
 187   endwhile
 188   return ''
 189 endfunction
 190
 191 function! FugitiveDetect(path) abort
 192   if exists('b:git_dir') && b:git_dir =~# '^$\|/$\|^fugitive:'
 193     unlet b:git_dir
 194   endif
 195   if !exists('b:git_dir')
 196     let dir = FugitiveExtractGitDir(a:path)
 197     if dir !=# ''
 198       let b:git_dir = dir
 199     endif
 200   endif
 201   if exists('b:git_dir')
 202     return fugitive#Init()
 203   endif
 204 endfunction
 205
 206 augroup fugitive
 207   autocmd!
 208
 209   autocmd BufNewFile,BufReadPost * call FugitiveDetect(expand('<amatch>:p'))
 210   autocmd FileType           netrw call FugitiveDetect(fnamemodify(get(b:, 'netrw_curdir', expand('<amatch>')), ':p'))
 211   autocmd User NERDTreeInit,NERDTreeNewRoot
 212         \ if exists('b:NERDTree.root.path.str') |
 213         \   call FugitiveDetect(b:NERDTree.root.path.str()) |
 214         \ endif
 215   autocmd VimEnter * if empty(expand('<amatch>'))|call FugitiveDetect(getcwd())|endif
 216   autocmd CmdWinEnter * call FugitiveDetect(expand('#:p'))
 217
 218   autocmd FileType git
 219         \ if exists('b:git_dir') |
 220         \   call fugitive#MapJumps() |
 221         \   call fugitive#MapCfile() |
 222         \ endif
 223   autocmd FileType gitcommit
 224         \ if exists('b:git_dir') |
 225         \   call fugitive#MapCfile('fugitive#StatusCfile()') |
 226         \ endif
 227   autocmd FileType gitrebase
 228         \ let &l:include = '^\%(pick\|squash\|edit\|reword\|fixup\|drop\|[pserfd]\)\>' |
 229         \ if exists('b:git_dir') |
 230         \   let &l:includeexpr = 'v:fname =~# ''^\x\{4,40\}$'' ? FugitiveGenerate(v:fname) : ' .
 231         \   (len(&l:includeexpr) ? &l:includeexpr : 'v:fname') |
 232         \ endif |
 233         \ let b:undo_ftplugin = get(b:, 'undo_ftplugin', 'exe') . '|setl inex= inc='
 234
 235   autocmd BufReadCmd index{,.lock}
 236         \ if FugitiveIsGitDir(expand('<amatch>:p:h')) |
 237         \   let b:git_dir = s:shellslash(expand('<amatch>:p:h')) |
 238         \   exe fugitive#BufReadStatus() |
 239         \ elseif filereadable(expand('<amatch>')) |
 240         \   read <amatch> |
 241         \   1delete_ |
 242         \ endif
 243   autocmd BufReadCmd    fugitive://*//*             exe fugitive#BufReadCmd()
 244   autocmd BufWriteCmd   fugitive://*//[0-3]/*       exe fugitive#BufWriteCmd()
 245   autocmd FileReadCmd   fugitive://*//*             exe fugitive#FileReadCmd()
 246   autocmd FileWriteCmd  fugitive://*//[0-3]/*       exe fugitive#FileWriteCmd()
 247   if exists('##SourceCmd')
 248     autocmd SourceCmd     fugitive://*//*    nested exe fugitive#SourceCmd()
 249   endif
 250
 251   autocmd User Flags call Hoist('buffer', function('FugitiveStatusline'))
 252 augroup END