plugin/fugitive.vim

   1 " fugitive.vim - A Git wrapper so awesome, it should be illegal
   2 " Maintainer:   Tim Pope <http://tpo.pe/>
   3 " Version:      2.4
   4 " GetLatestVimScripts: 2975 1 :AutoInstall: fugitive.vim
   5
   6 if exists('g:loaded_fugitive')
   7   finish
   8 endif
   9 let g:loaded_fugitive = 1
  10
  11 function! s:shellslash(path) abort
  12   if &shell =~? 'cmd' || exists('+shellslash') && !&shellslash
  13     return tr(a:path, '\', '/')
  14   else
  15     return a:path
  16   endif
  17 endfunction
  18
  19 function! FugitiveGitDir(...) abort
  20   if !a:0 || a:1 ==# -1
  21     return get(b:, 'git_dir', '')
  22   elseif type(a:1) == type(0)
  23     return getbufvar(a:1, 'git_dir')
  24   elseif type(a:1) == type('')
  25     return substitute(s:shellslash(a:1), '/$', '', '')
  26   else
  27     return ''
  28   endif
  29 endfunction
  30
  31 function! FugitiveIsGitDir(path) abort
  32   let path = substitute(a:path, '[\/]$', '', '') . '/'
  33   return getfsize(path.'HEAD') > 10 && (
  34         \ isdirectory(path.'objects') && isdirectory(path.'refs') ||
  35         \ getftype(path.'commondir') ==# 'file')
  36 endfunction
  37
  38 let s:worktree_for_dir = {}
  39 let s:dir_for_worktree = {}
  40 function! FugitiveWorkTree(...) abort
  41   let dir = substitute(s:shellslash(a:0 ? a:1 : get(b:, 'git_dir', '')), '/$', '', '')
  42   if dir =~# '/\.git$'
  43     return len(dir) ==# 5 ? '/' : dir[0:-6]
  44   endif
  45   if !has_key(s:worktree_for_dir, dir)
  46     let s:worktree_for_dir[dir] = ''
  47     let config_file = dir . '/config'
  48     if filereadable(config_file)
  49       let config = readfile(config_file,'',10)
  50       call filter(config,'v:val =~# "^\\s*worktree *="')
  51       if len(config) == 1
  52         let worktree = matchstr(config[0], '= *\zs.*')
  53       endif
  54     elseif filereadable(dir . '/gitdir')
  55       let worktree = fnamemodify(readfile(dir . '/gitdir')[0], ':h')
  56       if worktree ==# '.'
  57         unlet! worktree
  58       endif
  59     endif
  60     if exists('worktree')
  61       let s:worktree_for_dir[dir] = worktree
  62       let s:dir_for_worktree[s:worktree_for_dir[dir]] = dir
  63     endif
  64   endif
  65   if s:worktree_for_dir[dir] =~# '^\.'
  66     return simplify(dir . '/' . s:worktree_for_dir[dir])
  67   else
  68     return s:worktree_for_dir[dir]
  69   endif
  70 endfunction
  71
  72 function! FugitiveReal(...) abort
  73   let file = a:0 ? a:1 : @%
  74   if file =~? '^fugitive:' || a:0 > 1
  75     return call('fugitive#Real', [file] + a:000[1:-1])
  76   elseif file =~# '^/\|^\a\+:\|^$'
  77     return file
  78   else
  79     return fnamemodify(file, ':p' . (file =~# '[\/]$' ? '' : ':s?[\/]$??'))
  80   endif
  81 endfunction
  82
  83 function! FugitivePath(...) abort
  84   if a:0 > 1
  85     return fugitive#Path(a:1, a:2, FugitiveGitDir(a:0 > 2 ? a:3 : -1))
  86   else
  87     return FugitiveReal(a:0 ? a:1 : @%)
  88   endif
  89 endfunction
  90
  91 function! FugitiveGenerate(...) abort
  92   if a:0 && s:shellslash(a:0) =~# '^\%(\a\a\+:\)\=\%(a:\)\=/\|^[~$]'
  93     return a:1
  94   endif
  95   return fugitive#repo(FugitiveGitDir(a:0 > 1 ? a:2 : -1)).translate(a:0 ? a:1 : '', 1)
  96 endfunction
  97
  98 function! FugitiveRoute(...) abort
  99   return call('FugitiveGenerate', a:000)
 100 endfunction
 101
 102 function! FugitiveParse(...) abort
 103   let path = s:shellslash(a:0 ? a:1 : @%)
 104   let vals = matchlist(path, '\c^fugitive:\%(//\)\=\(.\{-\}\)\%(//\|::\)\(\x\{40\}\|[0-3]\)\(/.*\)\=$')
 105   if len(vals)
 106     return [(vals[2] =~# '^.$' ? ':' : '') . vals[2] . substitute(vals[3], '^/', ':', ''), vals[1]]
 107   endif
 108   let v:errmsg = 'fugitive: invalid Fugitive URL ' . path
 109   throw v:errmsg
 110 endfunction
 111
 112 function! FugitiveConfig(key, ...) abort
 113   return fugitive#Config(a:key, FugitiveGitDir(a:0 ? a:1 : -1))
 114 endfunction
 115
 116 function! FugitiveRemoteUrl(...) abort
 117   return fugitive#RemoteUrl(a:0 ? a:1 : '', FugitiveGitDir(a:0 > 1 ? a:2 : -1))
 118 endfunction
 119
 120 function! FugitiveHead(...) abort
 121   let dir = FugitiveGitDir(a:0 > 1 ? a:2 : -1)
 122   if empty(dir)
 123     return ''
 124   endif
 125   return fugitive#repo(dir).head(a:0 ? a:1 : 0)
 126 endfunction
 127
 128 function! FugitiveStatusline(...) abort
 129   if !exists('b:git_dir')
 130     return ''
 131   endif
 132   return fugitive#Statusline()
 133 endfunction
 134
 135 function! FugitiveTreeForGitDir(path) abort
 136   return FugitiveWorkTree(a:path)
 137 endfunction
 138
 139 function! FugitiveExtractGitDir(path) abort
 140   let path = s:shellslash(a:path)
 141   if path =~# '^fugitive:'
 142     return matchstr(path, '\C^fugitive:\%(//\)\=\zs.\{-\}\ze\%(//\|::\|$\)')
 143   elseif isdirectory(path)
 144     let path = fnamemodify(path, ':p:s?/$??')
 145   else
 146     let path = fnamemodify(path, ':p:h:s?/$??')
 147   endif
 148   let pre = substitute(matchstr(path, '^\a\a\+\ze:'), '^.', '\u&', '')
 149   if len(pre) && exists('*' . pre . 'Real')
 150     let path = s:shellslash({pre}Real(path))
 151   endif
 152   let root = resolve(path)
 153   if root !=# path
 154     silent! exe haslocaldir() ? 'lcd .' : 'cd .'
 155   endif
 156   let previous = ""
 157   while root !=# previous
 158     if root =~# '\v^//%([^/]+/?)?$'
 159       break
 160     endif
 161     if index(split($GIT_CEILING_DIRECTORIES, ':'), root) >= 0
 162       break
 163     endif
 164     if root ==# $GIT_WORK_TREE && FugitiveIsGitDir($GIT_DIR)
 165       return simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??'))
 166     endif
 167     if FugitiveIsGitDir($GIT_DIR)
 168       call FugitiveWorkTree(simplify(fnamemodify($GIT_DIR, ':p:s?[\/]$??')))
 169       if has_key(s:dir_for_worktree, root)
 170         return s:dir_for_worktree[root]
 171       endif
 172     endif
 173     let dir = substitute(root, '[\/]$', '', '') . '/.git'
 174     let type = getftype(dir)
 175     if type ==# 'dir' && FugitiveIsGitDir(dir)
 176       return dir
 177     elseif type ==# 'link' && FugitiveIsGitDir(dir)
 178       return resolve(dir)
 179     elseif type !=# '' && filereadable(dir)
 180       let line = get(readfile(dir, '', 1), 0, '')
 181       if line =~# '^gitdir: \.' && FugitiveIsGitDir(root.'/'.line[8:-1])
 182         return simplify(root.'/'.line[8:-1])
 183       elseif line =~# '^gitdir: ' && FugitiveIsGitDir(line[8:-1])
 184         return line[8:-1]
 185       endif
 186     elseif FugitiveIsGitDir(root)
 187       return root
 188     endif
 189     let previous = root
 190     let root = fnamemodify(root, ':h')
 191   endwhile
 192   return ''
 193 endfunction
 194
 195 function! FugitiveDetect(path) abort
 196   if exists('b:git_dir') && b:git_dir =~# '^$\|/$\|^fugitive:'
 197     unlet b:git_dir
 198   endif
 199   if !exists('b:git_dir')
 200     let dir = FugitiveExtractGitDir(a:path)
 201     if dir !=# ''
 202       let b:git_dir = dir
 203     endif
 204   endif
 205   if exists('b:git_dir')
 206     return fugitive#Init()
 207   endif
 208 endfunction
 209
 210 augroup fugitive
 211   autocmd!
 212
 213   autocmd BufNewFile,BufReadPost * call FugitiveDetect(expand('<amatch>:p'))
 214   autocmd FileType           netrw call FugitiveDetect(fnamemodify(get(b:, 'netrw_curdir', expand('<amatch>')), ':p'))
 215   autocmd User NERDTreeInit,NERDTreeNewRoot
 216         \ if exists('b:NERDTree.root.path.str') |
 217         \   call FugitiveDetect(b:NERDTree.root.path.str()) |
 218         \ endif
 219   autocmd VimEnter * if empty(expand('<amatch>'))|call FugitiveDetect(getcwd())|endif
 220   autocmd CmdWinEnter * call FugitiveDetect(expand('#:p'))
 221
 222   autocmd FileType git
 223         \ if exists('b:git_dir') |
 224         \   call fugitive#MapJumps() |
 225         \   call fugitive#MapCfile() |
 226         \ endif
 227   autocmd FileType gitcommit
 228         \ if exists('b:git_dir') |
 229         \   call fugitive#MapCfile('fugitive#StatusCfile()') |
 230         \ endif
 231   autocmd FileType gitrebase
 232         \ let &l:include = '^\%(pick\|squash\|edit\|reword\|fixup\|drop\|[pserfd]\)\>' |
 233         \ if exists('b:git_dir') |
 234         \   let &l:includeexpr = 'v:fname =~# ''^\x\{4,40\}$'' ? FugitiveGenerate(v:fname) : ' .
 235         \   (len(&l:includeexpr) ? &l:includeexpr : 'v:fname') |
 236         \ endif |
 237         \ let b:undo_ftplugin = get(b:, 'undo_ftplugin', 'exe') . '|setl inex= inc='
 238
 239   autocmd BufReadCmd index{,.lock}
 240         \ if FugitiveIsGitDir(expand('<amatch>:p:h')) |
 241         \   let b:git_dir = s:shellslash(expand('<amatch>:p:h')) |
 242         \   exe fugitive#BufReadStatus() |
 243         \ elseif filereadable(expand('<amatch>')) |
 244         \   read <amatch> |
 245         \   1delete_ |
 246         \ endif
 247   autocmd BufReadCmd    fugitive://*//*             exe fugitive#BufReadCmd()
 248   autocmd BufWriteCmd   fugitive://*//[0-3]/*       exe fugitive#BufWriteCmd()
 249   autocmd FileReadCmd   fugitive://*//*             exe fugitive#FileReadCmd()
 250   autocmd FileWriteCmd  fugitive://*//[0-3]/*       exe fugitive#FileWriteCmd()
 251   if exists('##SourceCmd')
 252     autocmd SourceCmd     fugitive://*//*    nested exe fugitive#SourceCmd()
 253   endif
 254
 255   autocmd User Flags call Hoist('buffer', function('FugitiveStatusline'))
 256 augroup END