configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([vkmodelviewer], 0.0.1)
   3
   4 AC_CONFIG_AUX_DIR([bin])
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_LIBOBJ_DIR([portable])
   7 AC_CONFIG_HEADERS(Core/config.h)
   8
   9 AC_ARG_VAR([HLSLC], [HLSL compiler])
  10
  11 dnl Check for progs
  12 AC_PROG_CXX
  13 AC_PROG_MKDIR_P
  14 AC_CHECK_PROG([HLSLC], [hlslc], [hlslc], [no])
  15 AS_IF([test "x$HLSLC" = "xno"], [AC_MSG_WARN([hlslc is required to compile shaders.])])
  16
  17 AM_INIT_AUTOMAKE([1.11 foreign silent-rules subdir-objects no-dist-gzip dist-xz -Wall -Werror])
  18 AM_MAINTAINER_MODE([enable])
  19 AM_SILENT_RULES([yes])
  20
  21 LT_PREREQ([2.4.2])
  22 LT_INIT
  23
  24 dnl Check compiler specific flags
  25 AC_SUBST([MODELVIEWER_CXXFLAGS], [""])
  26 AS_IF([test "x${GCC}" = "xyes"],
  27       [MODELVIEWER_CXXFLAGS="-Wall -pipe"
  28       MODELVIEWER_CHECK_CXXFLAGS([-std=gnu++11])
  29       MODELVIEWER_CHECK_CXXFLAGS([-fno-strict-aliasing])
  30       MODELVIEWER_CHECK_CXXFLAGS([-Wno-unused-but-set-variable])
  31       MODELVIEWER_CHECK_CXXFLAGS([-Wno-unknown-pragmas])])
  32
  33 dnl Check for libraries
  34 m4_ifdef([PKG_PROG_PKG_CONFIG], [PKG_PROG_PKG_CONFIG], [m4_fatal([pkg-config autoconf macros not found.])])
  35
  36 AC_SUBST([VULKAN_LIBS])
  37 AC_CHECK_LIB([vulkan], [vkGetInstanceProcAddr],
  38              [VULKAN_LIBS="-lvulkan"],
  39              [AC_MSG_ERROR([libvulkan not found.])])
  40
  41 PKG_CHECK_MODULES([VKD3D], [libvkd3d libvkd3d-utils])
  42 PKG_CHECK_MODULES([XCB], [xcb])
  43 PKG_CHECK_MODULES([ZLIB], [zlib])
  44
  45 AC_CONFIG_FILES([Makefile])
  46 AC_OUTPUT