other-licenses/ia2/AccessibleEditableText.idl

   1 /*************************************************************************
   2  *
   3  *  File Name (AccessibleEditableText.idl)
   4  *
   5  *  IAccessible2 IDL Specification
   6  *
   7  *  Copyright (c) IBM Corp. 2006
   8  *  Copyright (c) Sun Microsystems, Inc. 2000, 2006
   9  *
  10  *  This library is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU Lesser General Public
  12  *  License version 2.1, as published by the Free Software Foundation; either
  13  *  version 2.1 of the License, or (at your option) any later version.
  14  *
  15  *  This library is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18  *  Lesser General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU Lesser General Public
  21  *  License along with this library; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02110-1301  USA
  23  *
  24  ************************************************************************/
  25
  26 import "objidl.idl";
  27 import "oaidl.idl";
  28 import "oleacc.idl";
  29
  30 /** @brief This interface gives write access to a text representation.
  31
  32  This interface is typically used in conjunction with the IAccessibleText
  33   interface and complements that interface with the additional ability to
  34   modify text.
  35
  36  The substrings used with this interface are specified as follows:
  37   If startOffset is less than endOffset, the substring starts with the
  38   character at startOffset and ends with the character just before endOffset.
  39   If endOffset is lower than startOffset,  the result is the same as a call
  40   with the two arguments exchanged. The whole text can be defined by passing
  41   the indices zero and IAccessibleText::nCharacters. If both indices have the
  42   same value, an empty string is defined.
  43 */
  44 [object, uuid(A59AA09A-7011-4b65-939D-32B1FB5547E3)]
  45 interface IAccessibleEditableText : IUnknown
  46 {
  47
  48   /** @brief Copies the text range into the clipboard.
  49
  50    The specified text between the two given indices is copied into the
  51     system clipboard.
  52
  53    @param [in] startOffset
  54     Start index of the text to moved into the clipboard.
  55     The valid range is 0..length.
  56    @param [in] endOffset
  57     End index of the text to moved into the clipboard.
  58     The valid range is 0..length.
  59   */
  60   HRESULT copyText
  61     (
  62      [in] long startOffset,
  63      [in] long endOffset
  64     );
  65
  66   /** @brief Deletes a range of text.
  67
  68    The text between and including the two given indices is deleted
  69     from the text represented by this object.
  70
  71    @param [in] startOffset
  72     Start index of the text to be deleted.
  73     The valid range is 0..length.
  74    @param [in] endOffset
  75     End index of the text to be deleted.
  76     The valid range is 0..length.
  77   */
  78   HRESULT deleteText
  79     (
  80      [in] long startOffset,
  81      [in] long endOffset
  82     );
  83
  84   /** @brief Inserts text at the specified position.
  85
  86    The specified string is inserted at the given index into the text
  87     represented by this object.
  88
  89    @param [in] offset
  90     Index at which to insert the text.
  91     The valid range is 0..length.
  92    @param [in] text
  93     Text that is inserted.
  94   */
  95   HRESULT insertText
  96     (
  97      [in] long offset,
  98      [in] BSTR *text
  99     );
 100
 101   /** @brief Deletes a range of text and copies it to the clipboard.
 102
 103    The text between the two given indices is deleted from the text
 104     represented by this object and copied to the clipboard.
 105
 106    @param [in] startOffset
 107     Start index of the text to be deleted.
 108     The valid range is 0..length.
 109    @param [in] endOffset
 110     End index of the text to be deleted.
 111     The valid range is 0..length.
 112   */
 113   HRESULT cutText
 114     (
 115      [in] long startOffset,
 116      [in] long endOffset
 117     );
 118
 119   /** @brief Pastes text from the clipboard.
 120
 121    The text in the system clipboard is pasted into the text represented
 122     by this object at the given index.  This method is similar to the
 123         IAccessibleEditableText::insertText method. If the index is not valid
 124         the system clipboard text is not inserted.
 125
 126    @param [in] offset
 127     Index at which to insert the text from the system clipboard into
 128     the text represented by this object.
 129     The valid range is 0..length.
 130   */
 131   HRESULT pasteText
 132     (
 133      [in] long offset
 134     );
 135
 136   /** @brief Replaces text.
 137
 138    The text between the two given indices is replaced by the specified
 139     replacement string. This method is equivalent to calling first
 140     IAccessibleEditableText::deleteText with the two indices and then
 141     calling IAccessibleEditableText::insertText with the replacement text
 142         at the start index.
 143
 144    @param [in] startOffset
 145     Start index of the text to be replaced.
 146     The valid range is 0..length.
 147    @param [in] endOffset
 148     Start index of the text to be replaced.
 149     The valid range is 0..length.
 150    @param [in] text
 151     The Text that replaces the text between the given indices.
 152   */
 153   HRESULT replaceText
 154     (
 155      [in] long startOffset,
 156      [in] long endOffset,
 157      [in] BSTR *text
 158     );
 159
 160   /** @brief Replaces the attributes of a text range by the given set of attributes.
 161
 162    Sets the attributes for the text between the two given indices. The old
 163     attributes are replaced by the new list of attributes.
 164
 165    @param [in] startOffset
 166     Start index of the text whose attributes are modified.
 167     The valid range is 0..length.
 168    @param [in] endOffset
 169     Start index of the text whose attributes are modified.
 170     The valid range is 0..length.
 171    @param [in] attributes
 172     Set of attributes that replaces the old list of attributes of
 173     the specified text portion.
 174   */
 175   HRESULT setAttributes
 176     (
 177      [in] long startOffset,
 178      [in] long endOffset,
 179      [in] BSTR *attributes
 180     );
 181 }
 182