?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
wer: Add new stubbed wer.dll.
[wine/hramrach.git] / tools / wrc / parser.y
blob8c491140343629f38ad1086ca3b7c9949c6694e3
1 %{
2 /*
3 * Copyright 1994 Martin von Loewis
4 * Copyright 1998-2000 Bertho A. Stultiens (BS)
5 * 1999 Juergen Schmied (JS)
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
20 *
21 * History:
22 * 24-Jul-2000 BS - Made a fix for broken Berkeley yacc on
23 * non-terminals (see cjunk rule).
24 * 21-May-2000 BS - Partial implementation of font resources.
25 * - Corrected language propagation for binary
26 * resources such as bitmaps, icons, cursors,
27 * userres and rcdata. The language is now
28 * correct in .res files.
29 * - Fixed reading the resource name as ident,
30 * so that it may overlap keywords.
31 * 20-May-2000 BS - Implemented animated cursors and icons
32 * resource types.
33 * 30-Apr-2000 BS - Reintegration into the wine-tree
34 * 14-Jan-2000 BS - Redid the usertype resources so that they
35 * are compatible.
36 * 02-Jan-2000 BS - Removed the preprocessor from the grammar
37 * except for the # command (line numbers).
38 *
39 * 06-Nov-1999 JS - see CHANGES
40 *
41 * 29-Dec-1998 AdH - Grammar and function extensions.
42 * grammar: TOOLBAR resources, Named ICONs in
43 * DIALOGS
44 * functions: semantic actions for the grammar
45 * changes, resource files can now be anywhere
46 * on the include path instead of just in the
47 * current directory
48 *
49 * 20-Jun-1998 BS - Fixed a bug in load_file() where the name was not
50 * printed out correctly.
51 *
52 * 17-Jun-1998 BS - Fixed a bug in CLASS statement parsing which should
53 * also accept a tSTRING as argument.
54 *
55 * 25-May-1998 BS - Found out that I need to support language, version
56 * and characteristics in inline resources (bitmap,
57 * cursor, etc) but they can also be specified with
58 * a filename. This renders my filename-scanning scheme
59 * worthless. Need to build newline parsing to solve
60 * this one.
61 * It will come with version 1.1.0 (sigh).
62 *
63 * 19-May-1998 BS - Started to build a builtin preprocessor
64 *
65 * 30-Apr-1998 BS - Redid the stringtable parsing/handling. My previous
66 * ideas had some serious flaws.
67 *
68 * 27-Apr-1998 BS - Removed a lot of dead comments and put it in a doc
69 * file.
70 *
71 * 21-Apr-1998 BS - Added correct behavior for cursors and icons.
72 * - This file is growing too big. It is time to strip
73 * things and put it in a support file.
74 *
75 * 19-Apr-1998 BS - Tagged the stringtable resource so that only one
76 * resource will be created. This because the table
77 * has a different layout than other resources. The
78 * table has to be sorted, and divided into smaller
79 * resource entries (see comment in source).
80 *
81 * 17-Apr-1998 BS - Almost all strings, including identifiers, are parsed
82 * as string_t which include unicode strings upon
83 * input.
84 * - Parser now emits a warning when compiling win32
85 * extensions in win16 mode.
86 *
87 * 16-Apr-1998 BS - Raw data elements are now *optionally* separated
88 * by commas. Read the comments in file sq2dq.l.
89 * - FIXME: there are instances in the source that rely
90 * on the fact that int==32bit and pointers are int size.
91 * - Fixed the conflict in menuex by changing a rule
92 * back into right recursion. See note in source.
93 * - UserType resources cannot have an expression as its
94 * typeclass. See note in source.
95 *
96 * 15-Apr-1998 BS - Changed all right recursion into left recursion to
97 * get reduction of the parsestack.
98 * This also helps communication between bison and flex.
99 * Main advantage is that the Empty rule gets reduced
100 * first, which is used to allocate/link things.
101 * It also added a shift/reduce conflict in the menuex
102 * handling, due to expression/option possibility,
103 * although not serious.
104 *
105 * 14-Apr-1998 BS - Redone almost the entire parser. We're not talking
106 * about making it more efficient, but readable (for me)
107 * and slightly easier to expand/change.
108 * This is done primarily by using more reduce states
109 * with many (intuitive) types for the various resource
110 * statements.
111 * - Added expression handling for all resources where a
112 * number is accepted (not only for win32). Also added
113 * multiply and division (not MS compatible, but handy).
114 * Unary minus introduced a shift/reduce conflict, but
115 * it is not serious.
116 *
117 * 13-Apr-1998 BS - Reordered a lot of things
118 * - Made the source more readable
119 * - Added Win32 resource definitions
120 * - Corrected syntax problems with an old yacc (;)
121 * - Added extra comment about grammar
122 */
123 #include "config.h"
124 #include "wine/port.h"
125
126 #include <stdio.h>
127 #include <stdlib.h>
128 #include <stdarg.h>
129 #include <assert.h>
130 #include <ctype.h>
131 #include <string.h>
132
133 #include "wrc.h"
134 #include "utils.h"
135 #include "newstruc.h"
136 #include "dumpres.h"
137 #include "wine/wpp.h"
138 #include "wine/unicode.h"
139 #include "parser.h"
140 #include "windef.h"
141 #include "winbase.h"
142 #include "wingdi.h"
143 #include "winuser.h"
144
145 #if defined(YYBYACC)
146 /* Berkeley yacc (byacc) doesn't seem to know about these */
147 /* Some *BSD supplied versions do define these though */
148 # ifndef YYEMPTY
149 # define YYEMPTY (-1) /* Empty lookahead value of yychar */
150 # endif
151 # ifndef YYLEX
152 # define YYLEX yylex()
153 # endif
154
155 #elif defined(YYBISON)
156 /* Bison was used for original development */
157 /* #define YYEMPTY -2 */
158 /* #define YYLEX yylex() */
159
160 #else
161 /* No yacc we know yet */
162 # if !defined(YYEMPTY) || !defined(YYLEX)
163 # error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
164 # elif defined(__GNUC__) /* gcc defines the #warning directive */
165 # warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
166 /* #else we just take a chance that it works... */
167 # endif
168 #endif
169
170 int want_nl = 0; /* Signal flex that we need the next newline */
171 int want_id = 0; /* Signal flex that we need the next identifier */
172 static stringtable_t *tagstt; /* Stringtable tag.
173 * It is set while parsing a stringtable to one of
174 * the stringtables in the sttres list or a new one
175 * if the language was not parsed before.
176 */
177 static stringtable_t *sttres; /* Stringtable resources. This holds the list of
178 * stringtables with different lanuages
179 */
180 static int dont_want_id = 0; /* See language parsing for details */
181
182 /* Set to the current options of the currently scanning stringtable */
183 static int *tagstt_memopt;
184 static characts_t *tagstt_characts;
185 static version_t *tagstt_version;
186
187 static const char riff[4] = "RIFF"; /* RIFF file magic for animated cursor/icon */
188
189 /* Prototypes of here defined functions */
190 static event_t *get_event_head(event_t *p);
191 static control_t *get_control_head(control_t *p);
192 static ver_value_t *get_ver_value_head(ver_value_t *p);
193 static ver_block_t *get_ver_block_head(ver_block_t *p);
194 static resource_t *get_resource_head(resource_t *p);
195 static menu_item_t *get_item_head(menu_item_t *p);
196 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str);
197 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i);
198 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i);
199 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2);
200 static raw_data_t *str2raw_data(string_t *str);
201 static raw_data_t *int2raw_data(int i);
202 static raw_data_t *long2raw_data(int i);
203 static raw_data_t *load_file(string_t *name, language_t *lang);
204 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid);
205 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev);
206 static event_t *add_event(int key, int id, int flags, event_t *prev);
207 static name_id_t *convert_ctlclass(name_id_t *cls);
208 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev);
209 static dialog_t *dialog_version(version_t *v, dialog_t *dlg);
210 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg);
211 static dialog_t *dialog_language(language_t *l, dialog_t *dlg);
212 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg);
213 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg);
214 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg);
215 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg);
216 static dialog_t *dialog_exstyle(style_t * st, dialog_t *dlg);
217 static dialog_t *dialog_style(style_t * st, dialog_t *dlg);
218 static resource_t *build_stt_resources(stringtable_t *stthead);
219 static stringtable_t *find_stringtable(lvc_t *lvc);
220 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec);
221 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems);
222 static string_t *make_filename(string_t *s);
223 static resource_t *build_fontdirs(resource_t *tail);
224 static resource_t *build_fontdir(resource_t **fnt, int nfnt);
225 static int rsrcid_to_token(int lookahead);
226
227 %}
228 %union{
229 string_t *str;
230 int num;
231 int *iptr;
232 char *cptr;
233 resource_t *res;
234 accelerator_t *acc;
235 bitmap_t *bmp;
236 dialog_t *dlg;
237 font_t *fnt;
238 fontdir_t *fnd;
239 menu_t *men;
240 html_t *html;
241 rcdata_t *rdt;
242 stringtable_t *stt;
243 stt_entry_t *stte;
244 user_t *usr;
245 messagetable_t *msg;
246 versioninfo_t *veri;
247 control_t *ctl;
248 name_id_t *nid;
249 font_id_t *fntid;
250 language_t *lan;
251 version_t *ver;
252 characts_t *chars;
253 event_t *event;
254 menu_item_t *menitm;
255 itemex_opt_t *exopt;
256 raw_data_t *raw;
257 lvc_t *lvc;
258 ver_value_t *val;
259 ver_block_t *blk;
260 ver_words_t *verw;
261 toolbar_t *tlbar;
262 toolbar_item_t *tlbarItems;
263 dlginit_t *dginit;
264 style_pair_t *styles;
265 style_t *style;
266 ani_any_t *ani;
267 }
268
269 %token tNL
270 %token <num> tNUMBER tLNUMBER
271 %token <str> tSTRING tIDENT tFILENAME
272 %token <raw> tRAWDATA
273 %token tACCELERATORS tBITMAP tCURSOR tDIALOG tDIALOGEX tMENU tMENUEX tMESSAGETABLE
274 %token tRCDATA tVERSIONINFO tSTRINGTABLE tFONT tFONTDIR tICON tHTML
275 %token tAUTO3STATE tAUTOCHECKBOX tAUTORADIOBUTTON tCHECKBOX tDEFPUSHBUTTON
276 %token tPUSHBUTTON tRADIOBUTTON tSTATE3 /* PUSHBOX */
277 %token tGROUPBOX tCOMBOBOX tLISTBOX tSCROLLBAR
278 %token tCONTROL tEDITTEXT
279 %token tRTEXT tCTEXT tLTEXT
280 %token tBLOCK tVALUE
281 %token tSHIFT tALT tASCII tVIRTKEY tGRAYED tCHECKED tINACTIVE tNOINVERT
282 %token tPURE tIMPURE tDISCARDABLE tLOADONCALL tPRELOAD tFIXED tMOVEABLE
283 %token tCLASS tCAPTION tCHARACTERISTICS tEXSTYLE tSTYLE tVERSION tLANGUAGE
284 %token tFILEVERSION tPRODUCTVERSION tFILEFLAGSMASK tFILEOS tFILETYPE tFILEFLAGS tFILESUBTYPE
285 %token tMENUBARBREAK tMENUBREAK tMENUITEM tPOPUP tSEPARATOR
286 %token tHELP
287 %token tTOOLBAR tBUTTON
288 %token tBEGIN tEND
289 %token tDLGINIT
290 %left '|'
291 %left '^'
292 %left '&'
293 %left '+' '-'
294 %left '*' '/'
295 %right '~' tNOT
296 %left pUPM
297
298 %type <res> resource_file resource resources resource_definition
299 %type <stt> stringtable strings
300 %type <fnt> font
301 %type <fnd> fontdir
302 %type <acc> accelerators
303 %type <event> events
304 %type <bmp> bitmap
305 %type <ani> cursor icon
306 %type <dlg> dialog dlg_attributes dialogex dlgex_attribs
307 %type <ctl> ctrls gen_ctrl lab_ctrl ctrl_desc iconinfo
308 %type <iptr> helpid
309 %type <ctl> exctrls gen_exctrl lab_exctrl exctrl_desc
310 %type <html> html
311 %type <rdt> rcdata
312 %type <raw> raw_data raw_elements opt_data file_raw
313 %type <veri> versioninfo fix_version
314 %type <verw> ver_words
315 %type <blk> ver_blocks ver_block
316 %type <val> ver_values ver_value
317 %type <men> menu menuex
318 %type <menitm> item_definitions menu_body itemex_definitions menuex_body
319 %type <exopt> itemex_p_options itemex_options
320 %type <msg> messagetable
321 %type <usr> userres
322 %type <num> item_options
323 %type <nid> nameid nameid_s ctlclass usertype
324 %type <num> acc_opt acc accs
325 %type <iptr> loadmemopts lamo lama
326 %type <fntid> opt_font opt_exfont opt_expr
327 %type <lvc> opt_lvc
328 %type <lan> opt_language
329 %type <chars> opt_characts
330 %type <ver> opt_version
331 %type <num> expr xpr
332 %type <iptr> e_expr
333 %type <tlbar> toolbar
334 %type <tlbarItems> toolbar_items
335 %type <dginit> dlginit
336 %type <styles> optional_style_pair
337 %type <num> any_num
338 %type <style> style
339 %type <str> filename
340
341 %%
342
343 resource_file
344 : resources {
345 resource_t *rsc, *head;
346 /* First add stringtables to the resource-list */
347 rsc = build_stt_resources(sttres);
348 /* 'build_stt_resources' returns a head and $1 is a tail */
349 if($1)
350 {
351 $1->next = rsc;
352 if(rsc)
353 rsc->prev = $1;
354 }
355 else
356 $1 = rsc;
357 /* Find the tail again */
358 while($1 && $1->next)
359 $1 = $1->next;
360 /* Now add any fontdirecory */
361 rsc = build_fontdirs($1);
362 /* 'build_fontdir' returns a head and $1 is a tail */
363 if($1)
364 {
365 $1->next = rsc;
366 if(rsc)
367 rsc->prev = $1;
368 }
369 else
370 $1 = rsc;
371
372 /* Final statements before were done */
373 if ((head = get_resource_head($1)) != NULL)
374 {
375 if (resource_top) /* append to existing resources */
376 {
377 resource_t *tail = resource_top;
378 while (tail->next) tail = tail->next;
379 tail->next = head;
380 head->prev = tail;
381 }
382 else resource_top = head;
383 }
384 sttres = NULL;
385 }
386 ;
387
388 /* Resources are put into a linked list */
389 resources
390 : /* Empty */ { $$ = NULL; want_id = 1; }
391 | resources resource {
392 if($2)
393 {
394 resource_t *tail = $2;
395 resource_t *head = $2;
396 while(tail->next)
397 tail = tail->next;
398 while(head->prev)
399 head = head->prev;
400 head->prev = $1;
401 if($1)
402 $1->next = head;
403 $$ = tail;
404 /* Check for duplicate identifiers */
405 while($1 && head)
406 {
407 resource_t *rsc = $1;
408 while(rsc)
409 {
410 if(rsc->type == head->type
411 && rsc->lan->id == head->lan->id
412 && rsc->lan->sub == head->lan->sub
413 && !compare_name_id(rsc->name, head->name)
414 && (rsc->type != res_usr || !compare_name_id(rsc->res.usr->type,head->res.usr->type)))
415 {
416 yyerror("Duplicate resource name '%s'", get_nameid_str(rsc->name));
417 }
418 rsc = rsc->prev;
419 }
420 head = head->next;
421 }
422 }
423 else if($1)
424 {
425 resource_t *tail = $1;
426 while(tail->next)
427 tail = tail->next;
428 $$ = tail;
429 }
430 else
431 $$ = NULL;
432
433 if(!dont_want_id) /* See comments in language parsing below */
434 want_id = 1;
435 dont_want_id = 0;
436 }
437 /*
438 * The following newline rule will never get reduced because we never
439 * get the tNL token, unless we explicitly set the 'want_nl'
440 * flag, which we don't.
441 * The *ONLY* reason for this to be here is because Berkeley
442 * yacc (byacc), at least version 1.9, has a bug.
443 * (identified in the generated parser on the second
444 * line with:
445 * static char yysccsid[] = "@(#)yaccpar 1.9 (Berkeley) 02/21/93";
446 * )
447 * This extra rule fixes it.
448 * The problem is that the expression handling rule "expr: xpr"
449 * is not reduced on non-terminal tokens, defined above in the
450 * %token declarations. Token tNL is the only non-terminal that
451 * can occur. The error becomes visible in the language parsing
452 * rule below, which looks at the look-ahead token and tests it
453 * for tNL. However, byacc already generates an error upon reading
454 * the token instead of keeping it as a lookahead. The reason
455 * lies in the lack of a $default transition in the "expr : xpr . "
456 * state (currently state 25). It is probably omitted because tNL
457 * is a non-terminal and the state contains 2 s/r conflicts. The
458 * state enumerates all possible transitions instead of using a
459 * $default transition.
460 * All in all, it is a bug in byacc. (period)
461 */
462 | resources tNL
463 ;
464
465
466 /* Parse top level resource definitions etc. */
467 resource
468 : expr usrcvt resource_definition {
469 $$ = $3;
470 if($$)
471 {
472 if($1 > 65535 || $1 < -32768)
473 yyerror("Resource's ID out of range (%d)", $1);
474 $$->name = new_name_id();
475 $$->name->type = name_ord;
476 $$->name->name.i_name = $1;
477 chat("Got %s (%d)\n", get_typename($3), $$->name->name.i_name);
478 }
479 }
480 | tIDENT usrcvt resource_definition {
481 $$ = $3;
482 if($$)
483 {
484 $$->name = new_name_id();
485 $$->name->type = name_str;
486 $$->name->name.s_name = $1;
487 chat("Got %s (%s)\n", get_typename($3), $$->name->name.s_name->str.cstr);
488 }
489 }
490 | stringtable {
491 /* Don't do anything, stringtables are converted to
492 * resource_t structures when we are finished parsing and
493 * the final rule of the parser is reduced (see above)
494 */
495 $$ = NULL;
496 chat("Got STRINGTABLE\n");
497 }
498 | tLANGUAGE {want_nl = 1; } expr ',' expr {
499 /* We *NEED* the newline to delimit the expression.
500 * Otherwise, we would not be able to set the next
501 * want_id anymore because of the token-lookahead.
502 *
503 * However, we can test the lookahead-token for
504 * being "non-expression" type, in which case we
505 * continue. Fortunately, tNL is the only token that
506 * will break expression parsing and is implicitly
507 * void, so we just remove it. This scheme makes it
508 * possible to do some (not all) fancy preprocessor
509 * stuff.
510 * BTW, we also need to make sure that the next
511 * reduction of 'resources' above will *not* set
512 * want_id because we already have a lookahead that
513 * cannot be undone.
514 */
515 if(yychar != YYEMPTY && yychar != tNL)
516 dont_want_id = 1;
517
518 if(yychar == tNL)
519 yychar = YYEMPTY; /* Could use 'yyclearin', but we already need the*/
520 /* direct access to yychar in rule 'usrcvt' below. */
521 else if(yychar == tIDENT)
522 parser_warning("LANGUAGE statement not delimited with newline; next identifier might be wrong\n");
523
524 want_nl = 0; /* We don't want it anymore if we didn't get it */
525
526 if(!win32)
527 parser_warning("LANGUAGE not supported in 16-bit mode\n");
528 free(currentlanguage);
529 if (get_language_codepage($3, $5) == -1)
530 yyerror( "Language %04x is not supported", ($5<<10) + $3);
531 currentlanguage = new_language($3, $5);
532 $$ = NULL;
533 chat("Got LANGUAGE %d,%d (0x%04x)\n", $3, $5, ($5<<10) + $3);
534 }
535 ;
536
537 /*
538 * Remapping of numerical resource types
539 * (see also comment of called function below)
540 */
541 usrcvt : /* Empty */ { yychar = rsrcid_to_token(yychar); }
542 ;
543
544 /*
545 * Get a valid name/id
546 */
547 nameid : expr {
548 if($1 > 65535 || $1 < -32768)
549 yyerror("Resource's ID out of range (%d)", $1);
550 $$ = new_name_id();
551 $$->type = name_ord;
552 $$->name.i_name = $1;
553 }
554 | tIDENT {
555 $$ = new_name_id();
556 $$->type = name_str;
557 $$->name.s_name = $1;
558 }
559 ;
560
561 /*
562 * Extra string recognition for CLASS statement in dialogs
563 */
564 nameid_s: nameid { $$ = $1; }
565 | tSTRING {
566 $$ = new_name_id();
567 $$->type = name_str;
568 $$->name.s_name = $1;
569 }
570 ;
571
572 /* get the value for a single resource*/
573 resource_definition
574 : accelerators { $$ = new_resource(res_acc, $1, $1->memopt, $1->lvc.language); }
575 | bitmap { $$ = new_resource(res_bmp, $1, $1->memopt, $1->data->lvc.language); }
576 | cursor {
577 resource_t *rsc;
578 if($1->type == res_anicur)
579 {
580 $$ = rsc = new_resource(res_anicur, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
581 }
582 else if($1->type == res_curg)
583 {
584 cursor_t *cur;
585 $$ = rsc = new_resource(res_curg, $1->u.curg, $1->u.curg->memopt, $1->u.curg->lvc.language);
586 for(cur = $1->u.curg->cursorlist; cur; cur = cur->next)
587 {
588 rsc->prev = new_resource(res_cur, cur, $1->u.curg->memopt, $1->u.curg->lvc.language);
589 rsc->prev->next = rsc;
590 rsc = rsc->prev;
591 rsc->name = new_name_id();
592 rsc->name->type = name_ord;
593 rsc->name->name.i_name = cur->id;
594 }
595 }
596 else
597 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in cursor resource\n", $1->type);
598 free($1);
599 }
600 | dialog { $$ = new_resource(res_dlg, $1, $1->memopt, $1->lvc.language); }
601 | dialogex {
602 if(win32)
603 $$ = new_resource(res_dlg, $1, $1->memopt, $1->lvc.language);
604 else
605 $$ = NULL;
606 }
607 | dlginit { $$ = new_resource(res_dlginit, $1, $1->memopt, $1->data->lvc.language); }
608 | font { $$ = new_resource(res_fnt, $1, $1->memopt, $1->data->lvc.language); }
609 | fontdir { $$ = new_resource(res_fntdir, $1, $1->memopt, $1->data->lvc.language); }
610 | icon {
611 resource_t *rsc;
612 if($1->type == res_aniico)
613 {
614 $$ = rsc = new_resource(res_aniico, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
615 }
616 else if($1->type == res_icog)
617 {
618 icon_t *ico;
619 $$ = rsc = new_resource(res_icog, $1->u.icog, $1->u.icog->memopt, $1->u.icog->lvc.language);
620 for(ico = $1->u.icog->iconlist; ico; ico = ico->next)
621 {
622 rsc->prev = new_resource(res_ico, ico, $1->u.icog->memopt, $1->u.icog->lvc.language);
623 rsc->prev->next = rsc;
624 rsc = rsc->prev;
625 rsc->name = new_name_id();
626 rsc->name->type = name_ord;
627 rsc->name->name.i_name = ico->id;
628 }
629 }
630 else
631 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in icon resource\n", $1->type);
632 free($1);
633 }
634 | menu { $$ = new_resource(res_men, $1, $1->memopt, $1->lvc.language); }
635 | menuex {
636 if(win32)
637 $$ = new_resource(res_men, $1, $1->memopt, $1->lvc.language);
638 else
639 $$ = NULL;
640 }
641 | messagetable { $$ = new_resource(res_msg, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->data->lvc.language); }
642 | html { $$ = new_resource(res_html, $1, $1->memopt, $1->data->lvc.language); }
643 | rcdata { $$ = new_resource(res_rdt, $1, $1->memopt, $1->data->lvc.language); }
644 | toolbar { $$ = new_resource(res_toolbar, $1, $1->memopt, $1->lvc.language); }
645 | userres { $$ = new_resource(res_usr, $1, $1->memopt, $1->data->lvc.language); }
646 | versioninfo { $$ = new_resource(res_ver, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->lvc.language); }
647 ;
648
649
650 filename: tFILENAME { $$ = make_filename($1); }
651 | tIDENT { $$ = make_filename($1); }
652 | tSTRING { $$ = make_filename($1); }
653 ;
654
655 /* ------------------------------ Bitmap ------------------------------ */
656 bitmap : tBITMAP loadmemopts file_raw { $$ = new_bitmap($3, $2); }
657 ;
658
659 /* ------------------------------ Cursor ------------------------------ */
660 cursor : tCURSOR loadmemopts file_raw {
661 $$ = new_ani_any();
662 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
663 {
664 $$->type = res_anicur;
665 $$->u.ani = new_ani_curico(res_anicur, $3, $2);
666 }
667 else
668 {
669 $$->type = res_curg;
670 $$->u.curg = new_cursor_group($3, $2);
671 }
672 }
673 ;
674
675 /* ------------------------------ Icon ------------------------------ */
676 icon : tICON loadmemopts file_raw {
677 $$ = new_ani_any();
678 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
679 {
680 $$->type = res_aniico;
681 $$->u.ani = new_ani_curico(res_aniico, $3, $2);
682 }
683 else
684 {
685 $$->type = res_icog;
686 $$->u.icog = new_icon_group($3, $2);
687 }
688 }
689 ;
690
691 /* ------------------------------ Font ------------------------------ */
692 /*
693 * The reading of raw_data for fonts is a Borland BRC
694 * extension. MS generates an error. However, it is
695 * most logical to support this, considering how wine
696 * enters things in CVS (ascii).
697 */
698 font : tFONT loadmemopts file_raw { $$ = new_font($3, $2); }
699 ;
700
701 /*
702 * The fontdir is a Borland BRC extension which only
703 * reads the data as 'raw_data' from the file.
704 * I don't know whether it is interpreted.
705 * The fontdir is generated if it was not present and
706 * fonts are defined in the source.
707 */
708 fontdir : tFONTDIR loadmemopts file_raw { $$ = new_fontdir($3, $2); }
709 ;
710
711 /* ------------------------------ MessageTable ------------------------------ */
712 /* It might be interesting to implement the MS Message compiler here as well
713 * to get everything in one source. Might be a future project.
714 */
715 messagetable
716 : tMESSAGETABLE loadmemopts file_raw {
717 if(!win32)
718 parser_warning("MESSAGETABLE not supported in 16-bit mode\n");
719 $$ = new_messagetable($3, $2);
720 }
721 ;
722
723 /* ------------------------------ HTML ------------------------------ */
724 html : tHTML loadmemopts file_raw { $$ = new_html($3, $2); }
725 ;
726
727 /* ------------------------------ RCData ------------------------------ */
728 rcdata : tRCDATA loadmemopts file_raw { $$ = new_rcdata($3, $2); }
729 ;
730
731 /* ------------------------------ DLGINIT ------------------------------ */
732 dlginit : tDLGINIT loadmemopts file_raw { $$ = new_dlginit($3, $2); }
733 ;
734
735 /* ------------------------------ UserType ------------------------------ */
736 userres : usertype loadmemopts file_raw {
737 #ifdef WORDS_BIGENDIAN
738 if(pedantic && byteorder != WRC_BO_LITTLE)
739 #else
740 if(pedantic && byteorder == WRC_BO_BIG)
741 #endif
742 parser_warning("Byteordering is not little-endian and type cannot be interpreted\n");
743 $$ = new_user($1, $3, $2);
744 }
745 ;
746
747 usertype: tNUMBER {
748 $$ = new_name_id();
749 $$->type = name_ord;
750 $$->name.i_name = $1;
751 }
752 | tIDENT {
753 $$ = new_name_id();
754 $$->type = name_str;
755 $$->name.s_name = $1;
756 }
757 ;
758
759 /* ------------------------------ Accelerator ------------------------------ */
760 accelerators
761 : tACCELERATORS loadmemopts opt_lvc tBEGIN events tEND {
762 $$ = new_accelerator();
763 if($2)
764 {
765 $$->memopt = *($2);
766 free($2);
767 }
768 else
769 {
770 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
771 }
772 if(!$5)
773 yyerror("Accelerator table must have at least one entry");
774 $$->events = get_event_head($5);
775 if($3)
776 {
777 $$->lvc = *($3);
778 free($3);
779 }
780 if(!$$->lvc.language)
781 $$->lvc.language = dup_language(currentlanguage);
782 }
783 ;
784
785 events : /* Empty */ { $$=NULL; }
786 | events tSTRING ',' expr acc_opt { $$=add_string_event($2, $4, $5, $1); }
787 | events expr ',' expr acc_opt { $$=add_event($2, $4, $5, $1); }
788 ;
789
790 /*
791 * The empty rule generates a s/r conflict because of {bi,u}nary expr
792 * on - and +. It cannot be solved in any way because it is the same as
793 * the if/then/else problem (LALR(1) problem). The conflict is moved
794 * away by forcing it to be in the expression handling below.
795 */
796 acc_opt : /* Empty */ { $$ = 0; }
797 | ',' accs { $$ = $2; }
798 ;
799
800 accs : acc { $$ = $1; }
801 | accs ',' acc { $$ = $1 | $3; }
802 ;
803
804 acc : tNOINVERT { $$ = WRC_AF_NOINVERT; }
805 | tSHIFT { $$ = WRC_AF_SHIFT; }
806 | tCONTROL { $$ = WRC_AF_CONTROL; }
807 | tALT { $$ = WRC_AF_ALT; }
808 | tASCII { $$ = WRC_AF_ASCII; }
809 | tVIRTKEY { $$ = WRC_AF_VIRTKEY; }
810 ;
811
812 /* ------------------------------ Dialog ------------------------------ */
813 /* FIXME: Support EXSTYLE in the dialog line itself */
814 dialog : tDIALOG loadmemopts expr ',' expr ',' expr ',' expr dlg_attributes
815 tBEGIN ctrls tEND {
816 if($2)
817 {
818 $10->memopt = *($2);
819 free($2);
820 }
821 else
822 $10->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
823 $10->x = $3;
824 $10->y = $5;
825 $10->width = $7;
826 $10->height = $9;
827 $10->controls = get_control_head($12);
828 $$ = $10;
829 if(!$$->gotstyle)
830 {
831 $$->style = new_style(0,0);
832 $$->style->or_mask = WS_POPUP;
833 $$->gotstyle = TRUE;
834 }
835 if($$->title)
836 $$->style->or_mask |= WS_CAPTION;
837 if($$->font)
838 $$->style->or_mask |= DS_SETFONT;
839
840 $$->style->or_mask &= ~($$->style->and_mask);
841 $$->style->and_mask = 0;
842
843 if(!$$->lvc.language)
844 $$->lvc.language = dup_language(currentlanguage);
845 }
846 ;
847
848 dlg_attributes
849 : /* Empty */ { $$=new_dialog(); }
850 | dlg_attributes tSTYLE style { $$=dialog_style($3,$1); }
851 | dlg_attributes tEXSTYLE style { $$=dialog_exstyle($3,$1); }
852 | dlg_attributes tCAPTION tSTRING { $$=dialog_caption($3,$1); }
853 | dlg_attributes opt_font { $$=dialog_font($2,$1); }
854 | dlg_attributes tCLASS nameid_s { $$=dialog_class($3,$1); }
855 | dlg_attributes tMENU nameid { $$=dialog_menu($3,$1); }
856 | dlg_attributes opt_language { $$=dialog_language($2,$1); }
857 | dlg_attributes opt_characts { $$=dialog_characteristics($2,$1); }
858 | dlg_attributes opt_version { $$=dialog_version($2,$1); }
859 ;
860
861 ctrls : /* Empty */ { $$ = NULL; }
862 | ctrls tCONTROL gen_ctrl { $$=ins_ctrl(-1, 0, $3, $1); }
863 | ctrls tEDITTEXT ctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
864 | ctrls tLISTBOX ctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
865 | ctrls tCOMBOBOX ctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
866 | ctrls tSCROLLBAR ctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
867 | ctrls tCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
868 | ctrls tDEFPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
869 | ctrls tGROUPBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
870 | ctrls tPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
871 /* | ctrls tPUSHBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
872 | ctrls tRADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
873 | ctrls tAUTO3STATE lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
874 | ctrls tSTATE3 lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
875 | ctrls tAUTOCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
876 | ctrls tAUTORADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
877 | ctrls tLTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
878 | ctrls tCTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
879 | ctrls tRTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
880 /* special treatment for icons, as the extent is optional */
881 | ctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
882 $10->title = $3;
883 $10->id = $5;
884 $10->x = $7;
885 $10->y = $9;
886 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
887 }
888 ;
889
890 lab_ctrl
891 : nameid_s opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style_pair {
892 $$=new_control();
893 $$->title = $1;
894 $$->id = $3;
895 $$->x = $5;
896 $$->y = $7;
897 $$->width = $9;
898 $$->height = $11;
899 if($12)
900 {
901 $$->style = $12->style;
902 $$->gotstyle = TRUE;
903 if ($12->exstyle)
904 {
905 $$->exstyle = $12->exstyle;
906 $$->gotexstyle = TRUE;
907 }
908 free($12);
909 }
910 }
911 ;
912
913 ctrl_desc
914 : expr ',' expr ',' expr ',' expr ',' expr optional_style_pair {
915 $$ = new_control();
916 $$->id = $1;
917 $$->x = $3;
918 $$->y = $5;
919 $$->width = $7;
920 $$->height = $9;
921 if($10)
922 {
923 $$->style = $10->style;
924 $$->gotstyle = TRUE;
925 if ($10->exstyle)
926 {
927 $$->exstyle = $10->exstyle;
928 $$->gotexstyle = TRUE;
929 }
930 free($10);
931 }
932 }
933 ;
934
935 iconinfo: /* Empty */
936 { $$ = new_control(); }
937
938 | ',' expr ',' expr {
939 $$ = new_control();
940 $$->width = $2;
941 $$->height = $4;
942 }
943 | ',' expr ',' expr ',' style {
944 $$ = new_control();
945 $$->width = $2;
946 $$->height = $4;
947 $$->style = $6;
948 $$->gotstyle = TRUE;
949 }
950 | ',' expr ',' expr ',' style ',' style {
951 $$ = new_control();
952 $$->width = $2;
953 $$->height = $4;
954 $$->style = $6;
955 $$->gotstyle = TRUE;
956 $$->exstyle = $8;
957 $$->gotexstyle = TRUE;
958 }
959 ;
960
961 gen_ctrl: nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr ',' style {
962 $$=new_control();
963 $$->title = $1;
964 $$->id = $3;
965 $$->ctlclass = convert_ctlclass($5);
966 $$->style = $7;
967 $$->gotstyle = TRUE;
968 $$->x = $9;
969 $$->y = $11;
970 $$->width = $13;
971 $$->height = $15;
972 $$->exstyle = $17;
973 $$->gotexstyle = TRUE;
974 }
975 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr {
976 $$=new_control();
977 $$->title = $1;
978 $$->id = $3;
979 $$->ctlclass = convert_ctlclass($5);
980 $$->style = $7;
981 $$->gotstyle = TRUE;
982 $$->x = $9;
983 $$->y = $11;
984 $$->width = $13;
985 $$->height = $15;
986 }
987 ;
988
989 opt_font
990 : tFONT expr ',' tSTRING { $$ = new_font_id($2, $4, 0, 0); }
991 ;
992
993 /* ------------------------------ style flags ------------------------------ */
994 optional_style_pair
995 : /* Empty */ { $$ = NULL; }
996 | ',' style { $$ = new_style_pair($2, 0); }
997 | ',' style ',' style { $$ = new_style_pair($2, $4); }
998 ;
999
1000 style
1001 : style '|' style { $$ = new_style($1->or_mask | $3->or_mask, $1->and_mask | $3->and_mask); free($1); free($3);}
1002 | '(' style ')' { $$ = $2; }
1003 | any_num { $$ = new_style($1, 0); }
1004 | tNOT any_num { $$ = new_style(0, $2); }
1005 ;
1006
1007 ctlclass
1008 : expr {
1009 $$ = new_name_id();
1010 $$->type = name_ord;
1011 $$->name.i_name = $1;
1012 }
1013 | tSTRING {
1014 $$ = new_name_id();
1015 $$->type = name_str;
1016 $$->name.s_name = $1;
1017 }
1018 ;
1019
1020 /* ------------------------------ DialogEx ------------------------------ */
1021 dialogex: tDIALOGEX loadmemopts expr ',' expr ',' expr ',' expr helpid dlgex_attribs
1022 tBEGIN exctrls tEND {
1023 if(!win32)
1024 parser_warning("DIALOGEX not supported in 16-bit mode\n");
1025 if($2)
1026 {
1027 $11->memopt = *($2);
1028 free($2);
1029 }
1030 else
1031 $11->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1032 $11->x = $3;
1033 $11->y = $5;
1034 $11->width = $7;
1035 $11->height = $9;
1036 if($10)
1037 {
1038 $11->helpid = *($10);
1039 $11->gothelpid = TRUE;
1040 free($10);
1041 }
1042 $11->controls = get_control_head($13);
1043 $$ = $11;
1044
1045 assert($$->style != NULL);
1046 if(!$$->gotstyle)
1047 {
1048 $$->style->or_mask = WS_POPUP;
1049 $$->gotstyle = TRUE;
1050 }
1051 if($$->title)
1052 $$->style->or_mask |= WS_CAPTION;
1053 if($$->font)
1054 $$->style->or_mask |= DS_SETFONT;
1055
1056 $$->style->or_mask &= ~($$->style->and_mask);
1057 $$->style->and_mask = 0;
1058
1059 if(!$$->lvc.language)
1060 $$->lvc.language = dup_language(currentlanguage);
1061 }
1062 ;
1063
1064 dlgex_attribs
1065 : /* Empty */ { $$=new_dialog(); $$->is_ex = TRUE; }
1066 | dlgex_attribs tSTYLE style { $$=dialog_style($3,$1); }
1067 | dlgex_attribs tEXSTYLE style { $$=dialog_exstyle($3,$1); }
1068 | dlgex_attribs tCAPTION tSTRING { $$=dialog_caption($3,$1); }
1069 | dlgex_attribs opt_font { $$=dialog_font($2,$1); }
1070 | dlgex_attribs opt_exfont { $$=dialog_font($2,$1); }
1071 | dlgex_attribs tCLASS nameid_s { $$=dialog_class($3,$1); }
1072 | dlgex_attribs tMENU nameid { $$=dialog_menu($3,$1); }
1073 | dlgex_attribs opt_language { $$=dialog_language($2,$1); }
1074 | dlgex_attribs opt_characts { $$=dialog_characteristics($2,$1); }
1075 | dlgex_attribs opt_version { $$=dialog_version($2,$1); }
1076 ;
1077
1078 exctrls : /* Empty */ { $$ = NULL; }
1079 | exctrls tCONTROL gen_exctrl { $$=ins_ctrl(-1, 0, $3, $1); }
1080 | exctrls tEDITTEXT exctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
1081 | exctrls tLISTBOX exctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
1082 | exctrls tCOMBOBOX exctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
1083 | exctrls tSCROLLBAR exctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
1084 | exctrls tCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
1085 | exctrls tDEFPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
1086 | exctrls tGROUPBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
1087 | exctrls tPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
1088 /* | exctrls tPUSHBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
1089 | exctrls tRADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
1090 | exctrls tAUTO3STATE lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
1091 | exctrls tSTATE3 lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
1092 | exctrls tAUTOCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
1093 | exctrls tAUTORADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
1094 | exctrls tLTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
1095 | exctrls tCTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
1096 | exctrls tRTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
1097 /* special treatment for icons, as the extent is optional */
1098 | exctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
1099 $10->title = $3;
1100 $10->id = $5;
1101 $10->x = $7;
1102 $10->y = $9;
1103 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
1104 }
1105 ;
1106
1107 gen_exctrl
1108 : nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ','
1109 expr ',' style helpid opt_data {
1110 $$=new_control();
1111 $$->title = $1;
1112 $$->id = $3;
1113 $$->ctlclass = convert_ctlclass($5);
1114 $$->style = $7;
1115 $$->gotstyle = TRUE;
1116 $$->x = $9;
1117 $$->y = $11;
1118 $$->width = $13;
1119 $$->height = $15;
1120 if($17)
1121 {
1122 $$->exstyle = $17;
1123 $$->gotexstyle = TRUE;
1124 }
1125 if($18)
1126 {
1127 $$->helpid = *($18);
1128 $$->gothelpid = TRUE;
1129 free($18);
1130 }
1131 $$->extra = $19;
1132 }
1133 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr opt_data {
1134 $$=new_control();
1135 $$->title = $1;
1136 $$->id = $3;
1137 $$->style = $7;
1138 $$->gotstyle = TRUE;
1139 $$->ctlclass = convert_ctlclass($5);
1140 $$->x = $9;
1141 $$->y = $11;
1142 $$->width = $13;
1143 $$->height = $15;
1144 $$->extra = $16;
1145 }
1146 ;
1147
1148 lab_exctrl
1149 : nameid_s opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1150 $$=new_control();
1151 $$->title = $1;
1152 $$->id = $3;
1153 $$->x = $5;
1154 $$->y = $7;
1155 $$->width = $9;
1156 $$->height = $11;
1157 if($12)
1158 {
1159 $$->style = $12->style;
1160 $$->gotstyle = TRUE;
1161
1162 if ($12->exstyle)
1163 {
1164 $$->exstyle = $12->exstyle;
1165 $$->gotexstyle = TRUE;
1166 }
1167 free($12);
1168 }
1169
1170 $$->extra = $14;
1171 }
1172 ;
1173
1174 exctrl_desc
1175 : expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1176 $$ = new_control();
1177 $$->id = $1;
1178 $$->x = $3;
1179 $$->y = $5;
1180 $$->width = $7;
1181 $$->height = $9;
1182 if($10)
1183 {
1184 $$->style = $10->style;
1185 $$->gotstyle = TRUE;
1186
1187 if ($10->exstyle)
1188 {
1189 $$->exstyle = $10->exstyle;
1190 $$->gotexstyle = TRUE;
1191 }
1192 free($10);
1193 }
1194 $$->extra = $12;
1195 }
1196 ;
1197
1198 opt_data: /* Empty */ { $$ = NULL; }
1199 | raw_data { $$ = $1; }
1200 ;
1201
1202 helpid : /* Empty */ { $$ = NULL; }
1203 | ',' expr { $$ = new_int($2); }
1204 ;
1205
1206 opt_exfont
1207 : tFONT expr ',' tSTRING ',' expr ',' expr opt_expr { $$ = new_font_id($2, $4, $6, $8); }
1208 ;
1209
1210 /*
1211 * FIXME: This odd expression is here to nullify an extra token found
1212 * in some appstudio produced resources which appear to do nothing.
1213 */
1214 opt_expr: /* Empty */ { $$ = NULL; }
1215 | ',' expr { $$ = NULL; }
1216 ;
1217
1218 /* ------------------------------ Menu ------------------------------ */
1219 menu : tMENU loadmemopts opt_lvc menu_body {
1220 if(!$4)
1221 yyerror("Menu must contain items");
1222 $$ = new_menu();
1223 if($2)
1224 {
1225 $$->memopt = *($2);
1226 free($2);
1227 }
1228 else
1229 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1230 $$->items = get_item_head($4);
1231 if($3)
1232 {
1233 $$->lvc = *($3);
1234 free($3);
1235 }
1236 if(!$$->lvc.language)
1237 $$->lvc.language = dup_language(currentlanguage);
1238 }
1239 ;
1240
1241 menu_body
1242 : tBEGIN item_definitions tEND { $$ = $2; }
1243 ;
1244
1245 item_definitions
1246 : /* Empty */ {$$ = NULL;}
1247 | item_definitions tMENUITEM tSTRING opt_comma expr item_options {
1248 $$=new_menu_item();
1249 $$->prev = $1;
1250 if($1)
1251 $1->next = $$;
1252 $$->id = $5;
1253 $$->state = $6;
1254 $$->name = $3;
1255 }
1256 | item_definitions tMENUITEM tSEPARATOR {
1257 $$=new_menu_item();
1258 $$->prev = $1;
1259 if($1)
1260 $1->next = $$;
1261 }
1262 | item_definitions tPOPUP tSTRING item_options menu_body {
1263 $$ = new_menu_item();
1264 $$->prev = $1;
1265 if($1)
1266 $1->next = $$;
1267 $$->popup = get_item_head($5);
1268 $$->name = $3;
1269 }
1270 ;
1271
1272 /* NOTE: item_options is right recursive because it would introduce
1273 * a shift/reduce conflict on ',' in itemex_options due to the
1274 * empty rule here. The parser is now forced to look beyond the ','
1275 * before reducing (force shift).
1276 * Right recursion here is not a problem because we cannot expect
1277 * more than 7 parserstack places to be occupied while parsing this
1278 * (who would want to specify a MF_x flag twice?).
1279 */
1280 item_options
1281 : /* Empty */ { $$ = 0; }
1282 | opt_comma tCHECKED item_options { $$ = $3 | MF_CHECKED; }
1283 | opt_comma tGRAYED item_options { $$ = $3 | MF_GRAYED; }
1284 | opt_comma tHELP item_options { $$ = $3 | MF_HELP; }
1285 | opt_comma tINACTIVE item_options { $$ = $3 | MF_DISABLED; }
1286 | opt_comma tMENUBARBREAK item_options { $$ = $3 | MF_MENUBARBREAK; }
1287 | opt_comma tMENUBREAK item_options { $$ = $3 | MF_MENUBREAK; }
1288 ;
1289
1290 /* ------------------------------ MenuEx ------------------------------ */
1291 menuex : tMENUEX loadmemopts opt_lvc menuex_body {
1292 if(!win32)
1293 parser_warning("MENUEX not supported in 16-bit mode\n");
1294 if(!$4)
1295 yyerror("MenuEx must contain items");
1296 $$ = new_menu();
1297 $$->is_ex = TRUE;
1298 if($2)
1299 {
1300 $$->memopt = *($2);
1301 free($2);
1302 }
1303 else
1304 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1305 $$->items = get_item_head($4);
1306 if($3)
1307 {
1308 $$->lvc = *($3);
1309 free($3);
1310 }
1311 if(!$$->lvc.language)
1312 $$->lvc.language = dup_language(currentlanguage);
1313 }
1314 ;
1315
1316 menuex_body
1317 : tBEGIN itemex_definitions tEND { $$ = $2; }
1318 ;
1319
1320 itemex_definitions
1321 : /* Empty */ {$$ = NULL; }
1322 | itemex_definitions tMENUITEM tSTRING itemex_options {
1323 $$ = new_menu_item();
1324 $$->prev = $1;
1325 if($1)
1326 $1->next = $$;
1327 $$->name = $3;
1328 $$->id = $4->id;
1329 $$->type = $4->type;
1330 $$->state = $4->state;
1331 $$->helpid = $4->helpid;
1332 $$->gotid = $4->gotid;
1333 $$->gottype = $4->gottype;
1334 $$->gotstate = $4->gotstate;
1335 $$->gothelpid = $4->gothelpid;
1336 free($4);
1337 }
1338 | itemex_definitions tMENUITEM tSEPARATOR {
1339 $$ = new_menu_item();
1340 $$->prev = $1;
1341 if($1)
1342 $1->next = $$;
1343 }
1344 | itemex_definitions tPOPUP tSTRING itemex_p_options menuex_body {
1345 $$ = new_menu_item();
1346 $$->prev = $1;
1347 if($1)
1348 $1->next = $$;
1349 $$->popup = get_item_head($5);
1350 $$->name = $3;
1351 $$->id = $4->id;
1352 $$->type = $4->type;
1353 $$->state = $4->state;
1354 $$->helpid = $4->helpid;
1355 $$->gotid = $4->gotid;
1356 $$->gottype = $4->gottype;
1357 $$->gotstate = $4->gotstate;
1358 $$->gothelpid = $4->gothelpid;
1359 free($4);
1360 }
1361 ;
1362
1363 itemex_options
1364 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1365 | ',' expr {
1366 $$ = new_itemex_opt($2, 0, 0, 0);
1367 $$->gotid = TRUE;
1368 }
1369 | ',' e_expr ',' e_expr item_options {
1370 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $5, 0);
1371 $$->gotid = TRUE;
1372 $$->gottype = TRUE;
1373 $$->gotstate = TRUE;
1374 free($2);
1375 free($4);
1376 }
1377 | ',' e_expr ',' e_expr ',' expr {
1378 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1379 $$->gotid = TRUE;
1380 $$->gottype = TRUE;
1381 $$->gotstate = TRUE;
1382 free($2);
1383 free($4);
1384 }
1385 ;
1386
1387 itemex_p_options
1388 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1389 | ',' expr {
1390 $$ = new_itemex_opt($2, 0, 0, 0);
1391 $$->gotid = TRUE;
1392 }
1393 | ',' e_expr ',' expr {
1394 $$ = new_itemex_opt($2 ? *($2) : 0, $4, 0, 0);
1395 free($2);
1396 $$->gotid = TRUE;
1397 $$->gottype = TRUE;
1398 }
1399 | ',' e_expr ',' e_expr ',' expr {
1400 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1401 free($2);
1402 free($4);
1403 $$->gotid = TRUE;
1404 $$->gottype = TRUE;
1405 $$->gotstate = TRUE;
1406 }
1407 | ',' e_expr ',' e_expr ',' e_expr ',' expr {
1408 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6 ? *($6) : 0, $8);
1409 free($2);
1410 free($4);
1411 free($6);
1412 $$->gotid = TRUE;
1413 $$->gottype = TRUE;
1414 $$->gotstate = TRUE;
1415 $$->gothelpid = TRUE;
1416 }
1417 ;
1418
1419 /* ------------------------------ StringTable ------------------------------ */
1420 /* Stringtables are parsed differently than other resources because their
1421 * layout is substantially different from other resources.
1422 * The table is parsed through a _global_ variable 'tagstt' which holds the
1423 * current stringtable descriptor (stringtable_t *) and 'sttres' that holds a
1424 * list of stringtables of different languages.
1425 */
1426 stringtable
1427 : stt_head tBEGIN strings tEND {
1428 if(!$3)
1429 {
1430 yyerror("Stringtable must have at least one entry");
1431 }
1432 else
1433 {
1434 stringtable_t *stt;
1435 /* Check if we added to a language table or created
1436 * a new one.
1437 */
1438 for(stt = sttres; stt; stt = stt->next)
1439 {
1440 if(stt == tagstt)
1441 break;
1442 }
1443 if(!stt)
1444 {
1445 /* It is a new one */
1446 if(sttres)
1447 {
1448 sttres->prev = tagstt;
1449 tagstt->next = sttres;
1450 sttres = tagstt;
1451 }
1452 else
1453 sttres = tagstt;
1454 }
1455 /* Else were done */
1456 }
1457 free(tagstt_memopt);
1458 tagstt_memopt = NULL;
1459
1460 $$ = tagstt;
1461 }
1462 ;
1463
1464 /* This is to get the language of the currently parsed stringtable */
1465 stt_head: tSTRINGTABLE loadmemopts opt_lvc {
1466 if((tagstt = find_stringtable($3)) == NULL)
1467 tagstt = new_stringtable($3);
1468 tagstt_memopt = $2;
1469 tagstt_version = $3->version;
1470 tagstt_characts = $3->characts;
1471 free($3);
1472 }
1473 ;
1474
1475 strings : /* Empty */ { $$ = NULL; }
1476 | strings expr opt_comma tSTRING {
1477 int i;
1478 assert(tagstt != NULL);
1479 if($2 > 65535 || $2 < -32768)
1480 yyerror("Stringtable entry's ID out of range (%d)", $2);
1481 /* Search for the ID */
1482 for(i = 0; i < tagstt->nentries; i++)
1483 {
1484 if(tagstt->entries[i].id == $2)
1485 yyerror("Stringtable ID %d already in use", $2);
1486 }
1487 /* If we get here, then we have a new unique entry */
1488 tagstt->nentries++;
1489 tagstt->entries = xrealloc(tagstt->entries, sizeof(tagstt->entries[0]) * tagstt->nentries);
1490 tagstt->entries[tagstt->nentries-1].id = $2;
1491 tagstt->entries[tagstt->nentries-1].str = $4;
1492 if(tagstt_memopt)
1493 tagstt->entries[tagstt->nentries-1].memopt = *tagstt_memopt;
1494 else
1495 tagstt->entries[tagstt->nentries-1].memopt = WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1496 tagstt->entries[tagstt->nentries-1].version = tagstt_version;
1497 tagstt->entries[tagstt->nentries-1].characts = tagstt_characts;
1498
1499 if(pedantic && !$4->size)
1500 parser_warning("Zero length strings make no sense\n");
1501 if(!win32 && $4->size > 254)
1502 yyerror("Stringtable entry more than 254 characters");
1503 if(win32 && $4->size > 65534) /* Hmm..., does this happen? */
1504 yyerror("Stringtable entry more than 65534 characters (probably something else that went wrong)");
1505 $$ = tagstt;
1506 }
1507 ;
1508
1509 opt_comma /* There seem to be two ways to specify a stringtable... */
1510 : /* Empty */
1511 | ','
1512 ;
1513
1514 /* ------------------------------ VersionInfo ------------------------------ */
1515 versioninfo
1516 : tVERSIONINFO loadmemopts fix_version tBEGIN ver_blocks tEND {
1517 $$ = $3;
1518 if($2)
1519 {
1520 $$->memopt = *($2);
1521 free($2);
1522 }
1523 else
1524 $$->memopt = WRC_MO_MOVEABLE | (win32 ? WRC_MO_PURE : 0);
1525 $$->blocks = get_ver_block_head($5);
1526 /* Set language; there is no version or characteristics */
1527 $$->lvc.language = dup_language(currentlanguage);
1528 }
1529 ;
1530
1531 fix_version
1532 : /* Empty */ { $$ = new_versioninfo(); }
1533 | fix_version tFILEVERSION expr ',' expr ',' expr ',' expr {
1534 if($1->gotit.fv)
1535 yyerror("FILEVERSION already defined");
1536 $$ = $1;
1537 $$->filever_maj1 = $3;
1538 $$->filever_maj2 = $5;
1539 $$->filever_min1 = $7;
1540 $$->filever_min2 = $9;
1541 $$->gotit.fv = 1;
1542 }
1543 | fix_version tPRODUCTVERSION expr ',' expr ',' expr ',' expr {
1544 if($1->gotit.pv)
1545 yyerror("PRODUCTVERSION already defined");
1546 $$ = $1;
1547 $$->prodver_maj1 = $3;
1548 $$->prodver_maj2 = $5;
1549 $$->prodver_min1 = $7;
1550 $$->prodver_min2 = $9;
1551 $$->gotit.pv = 1;
1552 }
1553 | fix_version tFILEFLAGS expr {
1554 if($1->gotit.ff)
1555 yyerror("FILEFLAGS already defined");
1556 $$ = $1;
1557 $$->fileflags = $3;
1558 $$->gotit.ff = 1;
1559 }
1560 | fix_version tFILEFLAGSMASK expr {
1561 if($1->gotit.ffm)
1562 yyerror("FILEFLAGSMASK already defined");
1563 $$ = $1;
1564 $$->fileflagsmask = $3;
1565 $$->gotit.ffm = 1;
1566 }
1567 | fix_version tFILEOS expr {
1568 if($1->gotit.fo)
1569 yyerror("FILEOS already defined");
1570 $$ = $1;
1571 $$->fileos = $3;
1572 $$->gotit.fo = 1;
1573 }
1574 | fix_version tFILETYPE expr {
1575 if($1->gotit.ft)
1576 yyerror("FILETYPE already defined");
1577 $$ = $1;
1578 $$->filetype = $3;
1579 $$->gotit.ft = 1;
1580 }
1581 | fix_version tFILESUBTYPE expr {
1582 if($1->gotit.fst)
1583 yyerror("FILESUBTYPE already defined");
1584 $$ = $1;
1585 $$->filesubtype = $3;
1586 $$->gotit.fst = 1;
1587 }
1588 ;
1589
1590 ver_blocks
1591 : /* Empty */ { $$ = NULL; }
1592 | ver_blocks ver_block {
1593 $$ = $2;
1594 $$->prev = $1;
1595 if($1)
1596 $1->next = $$;
1597 }
1598 ;
1599
1600 ver_block
1601 : tBLOCK tSTRING tBEGIN ver_values tEND {
1602 $$ = new_ver_block();
1603 $$->name = $2;
1604 $$->values = get_ver_value_head($4);
1605 }
1606 ;
1607
1608 ver_values
1609 : /* Empty */ { $$ = NULL; }
1610 | ver_values ver_value {
1611 $$ = $2;
1612 $$->prev = $1;
1613 if($1)
1614 $1->next = $$;
1615 }
1616 ;
1617
1618 ver_value
1619 : ver_block {
1620 $$ = new_ver_value();
1621 $$->type = val_block;
1622 $$->value.block = $1;
1623 }
1624 | tVALUE tSTRING ',' tSTRING {
1625 $$ = new_ver_value();
1626 $$->type = val_str;
1627 $$->key = $2;
1628 $$->value.str = $4;
1629 }
1630 | tVALUE tSTRING ',' ver_words {
1631 $$ = new_ver_value();
1632 $$->type = val_words;
1633 $$->key = $2;
1634 $$->value.words = $4;
1635 }
1636 ;
1637
1638 ver_words
1639 : expr { $$ = new_ver_words($1); }
1640 | ver_words ',' expr { $$ = add_ver_words($1, $3); }
1641 ;
1642
1643 /* ------------------------------ Toolbar ------------------------------ */
1644 toolbar: tTOOLBAR loadmemopts expr ',' expr opt_lvc tBEGIN toolbar_items tEND {
1645 int nitems;
1646 toolbar_item_t *items = get_tlbr_buttons_head($8, &nitems);
1647 $$ = new_toolbar($3, $5, items, nitems);
1648 if($2)
1649 {
1650 $$->memopt = *($2);
1651 free($2);
1652 }
1653 else
1654 {
1655 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
1656 }
1657 if($6)
1658 {
1659 $$->lvc = *($6);
1660 free($6);
1661 }
1662 if(!$$->lvc.language)
1663 {
1664 $$->lvc.language = dup_language(currentlanguage);
1665 }
1666 }
1667 ;
1668
1669 toolbar_items
1670 : /* Empty */ { $$ = NULL; }
1671 | toolbar_items tBUTTON expr {
1672 toolbar_item_t *idrec = new_toolbar_item();
1673 idrec->id = $3;
1674 $$ = ins_tlbr_button($1, idrec);
1675 }
1676 | toolbar_items tSEPARATOR {
1677 toolbar_item_t *idrec = new_toolbar_item();
1678 idrec->id = 0;
1679 $$ = ins_tlbr_button($1, idrec);
1680 }
1681 ;
1682
1683 /* ------------------------------ Memory options ------------------------------ */
1684 loadmemopts
1685 : /* Empty */ { $$ = NULL; }
1686 | loadmemopts lamo {
1687 if($1)
1688 {
1689 *($1) |= *($2);
1690 $$ = $1;
1691 free($2);
1692 }
1693 else
1694 $$ = $2;
1695 }
1696 | loadmemopts lama {
1697 if($1)
1698 {
1699 *($1) &= *($2);
1700 $$ = $1;
1701 free($2);
1702 }
1703 else
1704 {
1705 *$2 &= WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1706 $$ = $2;
1707 }
1708 }
1709 ;
1710
1711 lamo : tPRELOAD { $$ = new_int(WRC_MO_PRELOAD);
1712 if (win32 && pedantic) parser_warning("PRELOAD is ignored in 32-bit mode\n"); }
1713 | tMOVEABLE { $$ = new_int(WRC_MO_MOVEABLE);
1714 if (win32 && pedantic) parser_warning("MOVEABLE is ignored in 32-bit mode\n"); }
1715 | tDISCARDABLE { $$ = new_int(WRC_MO_DISCARDABLE);
1716 if (win32 && pedantic) parser_warning("DISCARDABLE is ignored in 32-bit mode\n"); }
1717 | tPURE { $$ = new_int(WRC_MO_PURE);
1718 if (win32 && pedantic) parser_warning("PURE is ignored in 32-bit mode\n"); }
1719 ;
1720
1721 lama : tLOADONCALL { $$ = new_int(~WRC_MO_PRELOAD);
1722 if (win32 && pedantic) parser_warning("LOADONCALL is ignored in 32-bit mode\n"); }
1723 | tFIXED { $$ = new_int(~WRC_MO_MOVEABLE);
1724 if (win32 && pedantic) parser_warning("FIXED is ignored in 32-bit mode\n"); }
1725 | tIMPURE { $$ = new_int(~WRC_MO_PURE);
1726 if (win32 && pedantic) parser_warning("IMPURE is ignored in 32-bit mode\n"); }
1727 ;
1728
1729 /* ------------------------------ Win32 options ------------------------------ */
1730 opt_lvc : /* Empty */ { $$ = new_lvc(); }
1731 | opt_lvc opt_language {
1732 if(!win32)
1733 parser_warning("LANGUAGE not supported in 16-bit mode\n");
1734 if($1->language)
1735 yyerror("Language already defined");
1736 $$ = $1;
1737 $1->language = $2;
1738 }
1739 | opt_lvc opt_characts {
1740 if(!win32)
1741 parser_warning("CHARACTERISTICS not supported in 16-bit mode\n");
1742 if($1->characts)
1743 yyerror("Characteristics already defined");
1744 $$ = $1;
1745 $1->characts = $2;
1746 }
1747 | opt_lvc opt_version {
1748 if(!win32)
1749 parser_warning("VERSION not supported in 16-bit mode\n");
1750 if($1->version)
1751 yyerror("Version already defined");
1752 $$ = $1;
1753 $1->version = $2;
1754 }
1755 ;
1756
1757 /*
1758 * This here is another s/r conflict on {bi,u}nary + and -.
1759 * It is due to the look-ahead which must determine when the
1760 * rule opt_language ends. It could be solved with adding a
1761 * tNL at the end, but that seems unreasonable to do.
1762 * The conflict is now moved to the expression handling below.
1763 */
1764 opt_language
1765 : tLANGUAGE expr ',' expr { $$ = new_language($2, $4);
1766 if (get_language_codepage($2, $4) == -1)
1767 yyerror( "Language %04x is not supported", ($4<<10) + $2);
1768 }
1769 ;
1770
1771 opt_characts
1772 : tCHARACTERISTICS expr { $$ = new_characts($2); }
1773 ;
1774
1775 opt_version
1776 : tVERSION expr { $$ = new_version($2); }
1777 ;
1778
1779 /* ------------------------------ Raw data handling ------------------------------ */
1780 raw_data: opt_lvc tBEGIN raw_elements tEND {
1781 if($1)
1782 {
1783 $3->lvc = *($1);
1784 free($1);
1785 }
1786
1787 if(!$3->lvc.language)
1788 $3->lvc.language = dup_language(currentlanguage);
1789
1790 $$ = $3;
1791 }
1792 ;
1793
1794 raw_elements
1795 : tRAWDATA { $$ = $1; }
1796 | tNUMBER { $$ = int2raw_data($1); }
1797 | '-' tNUMBER { $$ = int2raw_data(-($2)); }
1798 | tLNUMBER { $$ = long2raw_data($1); }
1799 | '-' tLNUMBER { $$ = long2raw_data(-($2)); }
1800 | tSTRING { $$ = str2raw_data($1); }
1801 | raw_elements opt_comma tRAWDATA { $$ = merge_raw_data($1, $3); free($3->data); free($3); }
1802 | raw_elements opt_comma tNUMBER { $$ = merge_raw_data_int($1, $3); }
1803 | raw_elements opt_comma '-' tNUMBER { $$ = merge_raw_data_int($1, -($4)); }
1804 | raw_elements opt_comma tLNUMBER { $$ = merge_raw_data_long($1, $3); }
1805 | raw_elements opt_comma '-' tLNUMBER { $$ = merge_raw_data_long($1, -($4)); }
1806 | raw_elements opt_comma tSTRING { $$ = merge_raw_data_str($1, $3); }
1807 ;
1808
1809 /* File data or raw data */
1810 file_raw: filename { $$ = load_file($1,dup_language(currentlanguage)); }
1811 | raw_data { $$ = $1; }
1812 ;
1813
1814 /* ------------------------------ Win32 expressions ------------------------------ */
1815 /* All win16 numbers are also handled here. This is inconsistent with MS'
1816 * resource compiler, but what the heck, its just handy to have.
1817 */
1818 e_expr : /* Empty */ { $$ = 0; }
1819 | expr { $$ = new_int($1); }
1820 ;
1821
1822 /* This rule moves ALL s/r conflicts on {bi,u}nary - and + to here */
1823 expr : xpr { $$ = ($1); }
1824 ;
1825
1826 xpr : xpr '+' xpr { $$ = ($1) + ($3); }
1827 | xpr '-' xpr { $$ = ($1) - ($3); }
1828 | xpr '|' xpr { $$ = ($1) | ($3); }
1829 | xpr '&' xpr { $$ = ($1) & ($3); }
1830 | xpr '*' xpr { $$ = ($1) * ($3); }
1831 | xpr '/' xpr { $$ = ($1) / ($3); }
1832 | xpr '^' xpr { $$ = ($1) ^ ($3); }
1833 | '~' xpr { $$ = ~($2); }
1834 | '-' xpr %prec pUPM { $$ = -($2); }
1835 | '+' xpr %prec pUPM { $$ = $2; }
1836 | '(' xpr ')' { $$ = $2; }
1837 | any_num { $$ = $1; }
1838 | tNOT any_num { $$ = ~($2); }
1839 ;
1840
1841 any_num : tNUMBER { $$ = $1; }
1842 | tLNUMBER { $$ = $1; }
1843 ;
1844
1845 %%
1846 /* Dialog specific functions */
1847 static dialog_t *dialog_style(style_t * st, dialog_t *dlg)
1848 {
1849 assert(dlg != NULL);
1850 if(dlg->style == NULL)
1851 {
1852 dlg->style = new_style(0,0);
1853 }
1854
1855 if(dlg->gotstyle)
1856 {
1857 parser_warning("Style already defined, or-ing together\n");
1858 }
1859 else
1860 {
1861 dlg->style->or_mask = 0;
1862 dlg->style->and_mask = 0;
1863 }
1864 dlg->style->or_mask |= st->or_mask;
1865 dlg->style->and_mask |= st->and_mask;
1866 dlg->gotstyle = TRUE;
1867 free(st);
1868 return dlg;
1869 }
1870
1871 static dialog_t *dialog_exstyle(style_t *st, dialog_t *dlg)
1872 {
1873 assert(dlg != NULL);
1874 if(dlg->exstyle == NULL)
1875 {
1876 dlg->exstyle = new_style(0,0);
1877 }
1878
1879 if(dlg->gotexstyle)
1880 {
1881 parser_warning("ExStyle already defined, or-ing together\n");
1882 }
1883 else
1884 {
1885 dlg->exstyle->or_mask = 0;
1886 dlg->exstyle->and_mask = 0;
1887 }
1888 dlg->exstyle->or_mask |= st->or_mask;
1889 dlg->exstyle->and_mask |= st->and_mask;
1890 dlg->gotexstyle = TRUE;
1891 free(st);
1892 return dlg;
1893 }
1894
1895 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg)
1896 {
1897 assert(dlg != NULL);
1898 if(dlg->title)
1899 yyerror("Caption already defined");
1900 dlg->title = s;
1901 return dlg;
1902 }
1903
1904 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg)
1905 {
1906 assert(dlg != NULL);
1907 if(dlg->font)
1908 yyerror("Font already defined");
1909 dlg->font = f;
1910 return dlg;
1911 }
1912
1913 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg)
1914 {
1915 assert(dlg != NULL);
1916 if(dlg->dlgclass)
1917 yyerror("Class already defined");
1918 dlg->dlgclass = n;
1919 return dlg;
1920 }
1921
1922 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg)
1923 {
1924 assert(dlg != NULL);
1925 if(dlg->menu)
1926 yyerror("Menu already defined");
1927 dlg->menu = m;
1928 return dlg;
1929 }
1930
1931 static dialog_t *dialog_language(language_t *l, dialog_t *dlg)
1932 {
1933 assert(dlg != NULL);
1934 if(dlg->lvc.language)
1935 yyerror("Language already defined");
1936 dlg->lvc.language = l;
1937 return dlg;
1938 }
1939
1940 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg)
1941 {
1942 assert(dlg != NULL);
1943 if(dlg->lvc.characts)
1944 yyerror("Characteristics already defined");
1945 dlg->lvc.characts = c;
1946 return dlg;
1947 }
1948
1949 static dialog_t *dialog_version(version_t *v, dialog_t *dlg)
1950 {
1951 assert(dlg != NULL);
1952 if(dlg->lvc.version)
1953 yyerror("Version already defined");
1954 dlg->lvc.version = v;
1955 return dlg;
1956 }
1957
1958 /* Controls specific functions */
1959 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev)
1960 {
1961 /* Hm... this seems to be jammed in at all time... */
1962 int defaultstyle = WS_CHILD | WS_VISIBLE;
1963
1964 assert(ctrl != NULL);
1965 ctrl->prev = prev;
1966
1967 if(prev)
1968 prev->next = ctrl;
1969
1970 /* Check for duplicate identifiers */
1971 while (prev)
1972 {
1973 if (ctrl->id != -1 && ctrl->id == prev->id)
1974 parser_warning("Duplicate dialog control id %d\n", ctrl->id);
1975 prev = prev->prev;
1976 }
1977
1978 if(type != -1)
1979 {
1980 ctrl->ctlclass = new_name_id();
1981 ctrl->ctlclass->type = name_ord;
1982 ctrl->ctlclass->name.i_name = type;
1983 }
1984
1985 switch(type)
1986 {
1987 case CT_BUTTON:
1988 if(special_style != BS_GROUPBOX && special_style != BS_RADIOBUTTON)
1989 defaultstyle |= WS_TABSTOP;
1990 break;
1991 case CT_EDIT:
1992 defaultstyle |= WS_TABSTOP | WS_BORDER;
1993 break;
1994 case CT_LISTBOX:
1995 defaultstyle |= LBS_NOTIFY | WS_BORDER;
1996 break;
1997 case CT_COMBOBOX:
1998 if (!(ctrl->style->or_mask & (CBS_SIMPLE | CBS_DROPDOWN | CBS_DROPDOWNLIST)))
1999 defaultstyle |= CBS_SIMPLE;
2000 break;
2001 case CT_STATIC:
2002 if(special_style == SS_CENTER || special_style == SS_LEFT || special_style == SS_RIGHT)
2003 defaultstyle |= WS_GROUP;
2004 break;
2005 }
2006
2007 if(!ctrl->gotstyle) /* Handle default style setting */
2008 {
2009 switch(type)
2010 {
2011 case CT_EDIT:
2012 defaultstyle |= ES_LEFT;
2013 break;
2014 case CT_LISTBOX:
2015 defaultstyle |= LBS_NOTIFY;
2016 break;
2017 case CT_COMBOBOX:
2018 defaultstyle |= CBS_SIMPLE | WS_TABSTOP;
2019 break;
2020 case CT_SCROLLBAR:
2021 defaultstyle |= SBS_HORZ;
2022 break;
2023 case CT_BUTTON:
2024 switch(special_style)
2025 {
2026 case BS_CHECKBOX:
2027 case BS_DEFPUSHBUTTON:
2028 case BS_PUSHBUTTON:
2029 /* case BS_PUSHBOX: */
2030 case BS_AUTORADIOBUTTON:
2031 case BS_AUTO3STATE:
2032 case BS_3STATE:
2033 case BS_AUTOCHECKBOX:
2034 defaultstyle |= WS_TABSTOP;
2035 break;
2036 default:
2037 parser_warning("Unknown default button control-style 0x%08x\n", special_style);
2038 case BS_GROUPBOX:
2039 case BS_RADIOBUTTON:
2040 break;
2041 }
2042 break;
2043
2044 case CT_STATIC:
2045 switch(special_style)
2046 {
2047 case SS_LEFT:
2048 case SS_RIGHT:
2049 case SS_CENTER:
2050 defaultstyle |= WS_GROUP;
2051 break;
2052 case SS_ICON: /* Special case */
2053 break;
2054 default:
2055 parser_warning("Unknown default static control-style 0x%08x\n", special_style);
2056 break;
2057 }
2058 break;
2059 case -1: /* Generic control */
2060 goto byebye;
2061
2062 default:
2063 yyerror("Internal error (report this): Got weird control type 0x%08x", type);
2064 }
2065 }
2066
2067 /* The SS_ICON flag is always forced in for icon controls */
2068 if(type == CT_STATIC && special_style == SS_ICON)
2069 defaultstyle |= SS_ICON;
2070
2071 if (!ctrl->gotstyle)
2072 ctrl->style = new_style(0,0);
2073
2074 /* combine all styles */
2075 ctrl->style->or_mask = ctrl->style->or_mask | defaultstyle | special_style;
2076 ctrl->gotstyle = TRUE;
2077 byebye:
2078 /* combine with NOT mask */
2079 if (ctrl->gotstyle)
2080 {
2081 ctrl->style->or_mask &= ~(ctrl->style->and_mask);
2082 ctrl->style->and_mask = 0;
2083 }
2084 if (ctrl->gotexstyle)
2085 {
2086 ctrl->exstyle->or_mask &= ~(ctrl->exstyle->and_mask);
2087 ctrl->exstyle->and_mask = 0;
2088 }
2089 return ctrl;
2090 }
2091
2092 static int get_class_idW(const WCHAR *cc)
2093 {
2094 static const WCHAR szBUTTON[] = {'B','U','T','T','O','N',0};
2095 static const WCHAR szCOMBOBOX[] = {'C','O','M','B','O','B','O','X',0};
2096 static const WCHAR szLISTBOX[] = {'L','I','S','T','B','O','X',0};
2097 static const WCHAR szEDIT[] = {'E','D','I','T',0};
2098 static const WCHAR szSTATIC[] = {'S','T','A','T','I','C',0};
2099 static const WCHAR szSCROLLBAR[] = {'S','C','R','O','L','L','B','A','R',0};
2100
2101 if(!strcmpiW(szBUTTON, cc))
2102 return CT_BUTTON;
2103 if(!strcmpiW(szCOMBOBOX, cc))
2104 return CT_COMBOBOX;
2105 if(!strcmpiW(szLISTBOX, cc))
2106 return CT_LISTBOX;
2107 if(!strcmpiW(szEDIT, cc))
2108 return CT_EDIT;
2109 if(!strcmpiW(szSTATIC, cc))
2110 return CT_STATIC;
2111 if(!strcmpiW(szSCROLLBAR, cc))
2112 return CT_SCROLLBAR;
2113
2114 return -1;
2115 }
2116
2117 static int get_class_idA(const char *cc)
2118 {
2119 if(!strcasecmp("BUTTON", cc))
2120 return CT_BUTTON;
2121 if(!strcasecmp("COMBOBOX", cc))
2122 return CT_COMBOBOX;
2123 if(!strcasecmp("LISTBOX", cc))
2124 return CT_LISTBOX;
2125 if(!strcasecmp("EDIT", cc))
2126 return CT_EDIT;
2127 if(!strcasecmp("STATIC", cc))
2128 return CT_STATIC;
2129 if(!strcasecmp("SCROLLBAR", cc))
2130 return CT_SCROLLBAR;
2131
2132 return -1;
2133 }
2134
2135
2136 static name_id_t *convert_ctlclass(name_id_t *cls)
2137 {
2138 int iclass;
2139
2140 if(cls->type == name_ord)
2141 return cls;
2142 assert(cls->type == name_str);
2143 if(cls->name.s_name->type == str_unicode)
2144 iclass = get_class_idW(cls->name.s_name->str.wstr);
2145 else
2146 iclass = get_class_idA(cls->name.s_name->str.cstr);
2147
2148 if (iclass == -1)
2149 return cls; /* No default, return user controlclass */
2150
2151 free(cls->name.s_name->str.cstr);
2152 free(cls->name.s_name);
2153 cls->type = name_ord;
2154 cls->name.i_name = iclass;
2155 return cls;
2156 }
2157
2158 /* Accelerator specific functions */
2159 static event_t *add_event(int key, int id, int flags, event_t *prev)
2160 {
2161 event_t *ev = new_event();
2162
2163 if((flags & (WRC_AF_VIRTKEY | WRC_AF_ASCII)) == (WRC_AF_VIRTKEY | WRC_AF_ASCII))
2164 yyerror("Cannot use both ASCII and VIRTKEY");
2165
2166 ev->key = key;
2167 ev->id = id;
2168 ev->flags = flags & ~WRC_AF_ASCII;
2169 ev->prev = prev;
2170 if(prev)
2171 prev->next = ev;
2172 return ev;
2173 }
2174
2175 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev)
2176 {
2177 int keycode = 0;
2178 event_t *ev = new_event();
2179
2180 if(key->type == str_char)
2181 {
2182 if((flags & WRC_AF_VIRTKEY) &&
2183 !((key->str.cstr[0] >= 'A' && key->str.cstr[0] <= 'Z') ||
2184 (key->str.cstr[0] >= '0' && key->str.cstr[0] <= '9')))
2185 yyerror("VIRTKEY code is not equal to ascii value");
2186
2187 if(key->str.cstr[0] == '^' && (flags & WRC_AF_CONTROL) != 0)
2188 {
2189 yyerror("Cannot use both '^' and CONTROL modifier");
2190 }
2191 else if(key->str.cstr[0] == '^')
2192 {
2193 keycode = toupper((unsigned char)key->str.cstr[1]) - '@';
2194 if(keycode >= ' ')
2195 yyerror("Control-code out of range");
2196 }
2197 else
2198 keycode = key->str.cstr[0];
2199 }
2200 else
2201 {
2202 if((flags & WRC_AF_VIRTKEY) &&
2203 !((key->str.wstr[0] >= 'A' && key->str.wstr[0] <= 'Z') ||
2204 (key->str.wstr[0] >= '0' && key->str.wstr[0] <= '9')))
2205 yyerror("VIRTKEY code is not equal to ascii value");
2206
2207 if(key->str.wstr[0] == '^' && (flags & WRC_AF_CONTROL) != 0)
2208 {
2209 yyerror("Cannot use both '^' and CONTROL modifier");
2210 }
2211 else if(key->str.wstr[0] == '^')
2212 {
2213 keycode = toupperW(key->str.wstr[1]) - '@';
2214 if(keycode >= ' ')
2215 yyerror("Control-code out of range");
2216 }
2217 else
2218 keycode = key->str.wstr[0];
2219 }
2220
2221 ev->key = keycode;
2222 ev->id = id;
2223 ev->flags = flags & ~WRC_AF_ASCII;
2224 ev->prev = prev;
2225 if(prev)
2226 prev->next = ev;
2227 return ev;
2228 }
2229
2230 /* MenuEx specific functions */
2231 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid)
2232 {
2233 itemex_opt_t *opt = xmalloc(sizeof(itemex_opt_t));
2234 memset( opt, 0, sizeof(*opt) );
2235 opt->id = id;
2236 opt->type = type;
2237 opt->state = state;
2238 opt->helpid = helpid;
2239 return opt;
2240 }
2241
2242 /* Raw data functions */
2243 static raw_data_t *load_file(string_t *filename, language_t *lang)
2244 {
2245 FILE *fp = NULL;
2246 char *path;
2247 raw_data_t *rd;
2248 string_t *name;
2249 int codepage = get_language_codepage(lang->id, lang->sub);
2250
2251 /* FIXME: we may want to use utf-8 here */
2252 if (codepage <= 0 && filename->type != str_char)
2253 yyerror("Cannot convert filename to ASCII string");
2254 name = convert_string( filename, str_char, codepage );
2255 if (!(path = wpp_find_include(name->str.cstr, input_name)))
2256 yyerror("Cannot open file %s", name->str.cstr);
2257 if (!(fp = fopen( path, "rb" )))
2258 yyerror("Cannot open file %s", name->str.cstr);
2259 free( path );
2260 rd = new_raw_data();
2261 fseek(fp, 0, SEEK_END);
2262 rd->size = ftell(fp);
2263 fseek(fp, 0, SEEK_SET);
2264 if (rd->size)
2265 {
2266 rd->data = xmalloc(rd->size);
2267 fread(rd->data, rd->size, 1, fp);
2268 }
2269 else rd->data = NULL;
2270 fclose(fp);
2271 rd->lvc.language = lang;
2272 free_string(name);
2273 return rd;
2274 }
2275
2276 static raw_data_t *int2raw_data(int i)
2277 {
2278 raw_data_t *rd;
2279
2280 if( ( i >= 0 && (int)((unsigned short)i) != i) ||
2281 ( i < 0 && (int)((short)i) != i) )
2282 parser_warning("Integer constant out of 16bit range (%d), truncated to %d\n", i, (short)i);
2283
2284 rd = new_raw_data();
2285 rd->size = sizeof(short);
2286 rd->data = xmalloc(rd->size);
2287 switch(byteorder)
2288 {
2289 #ifdef WORDS_BIGENDIAN
2290 default:
2291 #endif
2292 case WRC_BO_BIG:
2293 rd->data[0] = HIBYTE(i);
2294 rd->data[1] = LOBYTE(i);
2295 break;
2296
2297 #ifndef WORDS_BIGENDIAN
2298 default:
2299 #endif
2300 case WRC_BO_LITTLE:
2301 rd->data[1] = HIBYTE(i);
2302 rd->data[0] = LOBYTE(i);
2303 break;
2304 }
2305 return rd;
2306 }
2307
2308 static raw_data_t *long2raw_data(int i)
2309 {
2310 raw_data_t *rd;
2311 rd = new_raw_data();
2312 rd->size = sizeof(int);
2313 rd->data = xmalloc(rd->size);
2314 switch(byteorder)
2315 {
2316 #ifdef WORDS_BIGENDIAN
2317 default:
2318 #endif
2319 case WRC_BO_BIG:
2320 rd->data[0] = HIBYTE(HIWORD(i));
2321 rd->data[1] = LOBYTE(HIWORD(i));
2322 rd->data[2] = HIBYTE(LOWORD(i));
2323 rd->data[3] = LOBYTE(LOWORD(i));
2324 break;
2325
2326 #ifndef WORDS_BIGENDIAN
2327 default:
2328 #endif
2329 case WRC_BO_LITTLE:
2330 rd->data[3] = HIBYTE(HIWORD(i));
2331 rd->data[2] = LOBYTE(HIWORD(i));
2332 rd->data[1] = HIBYTE(LOWORD(i));
2333 rd->data[0] = LOBYTE(LOWORD(i));
2334 break;
2335 }
2336 return rd;
2337 }
2338
2339 static raw_data_t *str2raw_data(string_t *str)
2340 {
2341 raw_data_t *rd;
2342 rd = new_raw_data();
2343 rd->size = str->size * (str->type == str_char ? 1 : 2);
2344 rd->data = xmalloc(rd->size);
2345 if(str->type == str_char)
2346 memcpy(rd->data, str->str.cstr, rd->size);
2347 else if(str->type == str_unicode)
2348 {
2349 int i;
2350 switch(byteorder)
2351 {
2352 #ifdef WORDS_BIGENDIAN
2353 default:
2354 #endif
2355 case WRC_BO_BIG:
2356 for(i = 0; i < str->size; i++)
2357 {
2358 rd->data[2*i + 0] = HIBYTE((WORD)str->str.wstr[i]);
2359 rd->data[2*i + 1] = LOBYTE((WORD)str->str.wstr[i]);
2360 }
2361 break;
2362 #ifndef WORDS_BIGENDIAN
2363 default:
2364 #endif
2365 case WRC_BO_LITTLE:
2366 for(i = 0; i < str->size; i++)
2367 {
2368 rd->data[2*i + 1] = HIBYTE((WORD)str->str.wstr[i]);
2369 rd->data[2*i + 0] = LOBYTE((WORD)str->str.wstr[i]);
2370 }
2371 break;
2372 }
2373 }
2374 else
2375 internal_error(__FILE__, __LINE__, "Invalid stringtype\n");
2376 return rd;
2377 }
2378
2379 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2)
2380 {
2381 r1->data = xrealloc(r1->data, r1->size + r2->size);
2382 memcpy(r1->data + r1->size, r2->data, r2->size);
2383 r1->size += r2->size;
2384 return r1;
2385 }
2386
2387 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i)
2388 {
2389 raw_data_t *t = int2raw_data(i);
2390 merge_raw_data(r1, t);
2391 free(t->data);
2392 free(t);
2393 return r1;
2394 }
2395
2396 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i)
2397 {
2398 raw_data_t *t = long2raw_data(i);
2399 merge_raw_data(r1, t);
2400 free(t->data);
2401 free(t);
2402 return r1;
2403 }
2404
2405 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str)
2406 {
2407 raw_data_t *t = str2raw_data(str);
2408 merge_raw_data(r1, t);
2409 free(t->data);
2410 free(t);
2411 return r1;
2412 }
2413
2414 /* Function the go back in a list to get the head */
2415 static menu_item_t *get_item_head(menu_item_t *p)
2416 {
2417 if(!p)
2418 return NULL;
2419 while(p->prev)
2420 p = p->prev;
2421 return p;
2422 }
2423
2424 static resource_t *get_resource_head(resource_t *p)
2425 {
2426 if(!p)
2427 return NULL;
2428 while(p->prev)
2429 p = p->prev;
2430 return p;
2431 }
2432
2433 static ver_block_t *get_ver_block_head(ver_block_t *p)
2434 {
2435 if(!p)
2436 return NULL;
2437 while(p->prev)
2438 p = p->prev;
2439 return p;
2440 }
2441
2442 static ver_value_t *get_ver_value_head(ver_value_t *p)
2443 {
2444 if(!p)
2445 return NULL;
2446 while(p->prev)
2447 p = p->prev;
2448 return p;
2449 }
2450
2451 static control_t *get_control_head(control_t *p)
2452 {
2453 if(!p)
2454 return NULL;
2455 while(p->prev)
2456 p = p->prev;
2457 return p;
2458 }
2459
2460 static event_t *get_event_head(event_t *p)
2461 {
2462 if(!p)
2463 return NULL;
2464 while(p->prev)
2465 p = p->prev;
2466 return p;
2467 }
2468
2469 /* Find a stringtable with given language */
2470 static stringtable_t *find_stringtable(lvc_t *lvc)
2471 {
2472 stringtable_t *stt;
2473
2474 assert(lvc != NULL);
2475
2476 if(!lvc->language)
2477 lvc->language = dup_language(currentlanguage);
2478
2479 for(stt = sttres; stt; stt = stt->next)
2480 {
2481 if(stt->lvc.language->id == lvc->language->id
2482 && stt->lvc.language->sub == lvc->language->sub)
2483 {
2484 /* Found a table with the same language */
2485 /* The version and characteristics are now handled
2486 * in the generation of the individual stringtables.
2487 * This enables localized analysis.
2488 if((stt->lvc.version && lvc->version && *(stt->lvc.version) != *(lvc->version))
2489 || (!stt->lvc.version && lvc->version)
2490 || (stt->lvc.version && !lvc->version))
2491 parser_warning("Stringtable's versions are not the same, using first definition\n");
2492
2493 if((stt->lvc.characts && lvc->characts && *(stt->lvc.characts) != *(lvc->characts))
2494 || (!stt->lvc.characts && lvc->characts)
2495 || (stt->lvc.characts && !lvc->characts))
2496 parser_warning("Stringtable's characteristics are not the same, using first definition\n");
2497 */
2498 return stt;
2499 }
2500 }
2501 return NULL;
2502 }
2503
2504 /* qsort sorting function for string table entries */
2505 #define STE(p) ((const stt_entry_t *)(p))
2506 static int sort_stt_entry(const void *e1, const void *e2)
2507 {
2508 return STE(e1)->id - STE(e2)->id;
2509 }
2510 #undef STE
2511
2512 static resource_t *build_stt_resources(stringtable_t *stthead)
2513 {
2514 stringtable_t *stt;
2515 stringtable_t *newstt;
2516 resource_t *rsc;
2517 resource_t *rsclist = NULL;
2518 resource_t *rsctail = NULL;
2519 int i;
2520 int j;
2521 DWORD andsum;
2522 DWORD orsum;
2523 characts_t *characts;
2524 version_t *version;
2525
2526 if(!stthead)
2527 return NULL;
2528
2529 /* For all languages defined */
2530 for(stt = stthead; stt; stt = stt->next)
2531 {
2532 assert(stt->nentries > 0);
2533
2534 /* Sort the entries */
2535 if(stt->nentries > 1)
2536 qsort(stt->entries, stt->nentries, sizeof(stt->entries[0]), sort_stt_entry);
2537
2538 for(i = 0; i < stt->nentries; )
2539 {
2540 newstt = new_stringtable(&stt->lvc);
2541 newstt->entries = xmalloc(16 * sizeof(stt_entry_t));
2542 memset( newstt->entries, 0, 16 * sizeof(stt_entry_t) );
2543 newstt->nentries = 16;
2544 newstt->idbase = stt->entries[i].id & ~0xf;
2545 for(j = 0; j < 16 && i < stt->nentries; j++)
2546 {
2547 if(stt->entries[i].id - newstt->idbase == j)
2548 {
2549 newstt->entries[j] = stt->entries[i];
2550 i++;
2551 }
2552 }
2553 andsum = ~0;
2554 orsum = 0;
2555 characts = NULL;
2556 version = NULL;
2557 /* Check individual memory options and get
2558 * the first characteristics/version
2559 */
2560 for(j = 0; j < 16; j++)
2561 {
2562 if(!newstt->entries[j].str)
2563 continue;
2564 andsum &= newstt->entries[j].memopt;
2565 orsum |= newstt->entries[j].memopt;
2566 if(!characts)
2567 characts = newstt->entries[j].characts;
2568 if(!version)
2569 version = newstt->entries[j].version;
2570 }
2571 if(andsum != orsum)
2572 {
2573 warning("Stringtable's memory options are not equal (idbase: %d)\n", newstt->idbase);
2574 }
2575 /* Check version and characteristics */
2576 for(j = 0; j < 16; j++)
2577 {
2578 if(characts
2579 && newstt->entries[j].characts
2580 && *newstt->entries[j].characts != *characts)
2581 warning("Stringtable's characteristics are not the same (idbase: %d)\n", newstt->idbase);
2582 if(version
2583 && newstt->entries[j].version
2584 && *newstt->entries[j].version != *version)
2585 warning("Stringtable's versions are not the same (idbase: %d)\n", newstt->idbase);
2586 }
2587 rsc = new_resource(res_stt, newstt, newstt->memopt, newstt->lvc.language);
2588 rsc->name = new_name_id();
2589 rsc->name->type = name_ord;
2590 rsc->name->name.i_name = (newstt->idbase >> 4) + 1;
2591 rsc->memopt = andsum; /* Set to least common denominator */
2592 newstt->memopt = andsum;
2593 newstt->lvc.characts = characts;
2594 newstt->lvc.version = version;
2595 if(!rsclist)
2596 {
2597 rsclist = rsc;
2598 rsctail = rsc;
2599 }
2600 else
2601 {
2602 rsctail->next = rsc;
2603 rsc->prev = rsctail;
2604 rsctail = rsc;
2605 }
2606 }
2607 }
2608 return rsclist;
2609 }
2610
2611
2612 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec)
2613 {
2614 idrec->prev = prev;
2615 if(prev)
2616 prev->next = idrec;
2617
2618 return idrec;
2619 }
2620
2621 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems)
2622 {
2623 if(!p)
2624 {
2625 *nitems = 0;
2626 return NULL;
2627 }
2628
2629 *nitems = 1;
2630
2631 while(p->prev)
2632 {
2633 (*nitems)++;
2634 p = p->prev;
2635 }
2636
2637 return p;
2638 }
2639
2640 static string_t *make_filename(string_t *str)
2641 {
2642 if(str->type == str_char)
2643 {
2644 char *cptr;
2645
2646 /* Remove escaped backslash and convert to forward */
2647 for(cptr = str->str.cstr; (cptr = strchr(cptr, '\\')) != NULL; cptr++)
2648 {
2649 if(cptr[1] == '\\')
2650 {
2651 memmove(cptr, cptr+1, strlen(cptr));
2652 str->size--;
2653 }
2654 *cptr = '/';
2655 }
2656 }
2657 else
2658 {
2659 WCHAR *wptr;
2660
2661 /* Remove escaped backslash and convert to forward */
2662 for(wptr = str->str.wstr; (wptr = strchrW(wptr, '\\')) != NULL; wptr++)
2663 {
2664 if(wptr[1] == '\\')
2665 {
2666 memmove(wptr, wptr+1, strlenW(wptr));
2667 str->size--;
2668 }
2669 *wptr = '/';
2670 }
2671 }
2672 return str;
2673 }
2674
2675 /*
2676 * Process all resources to extract fonts and build
2677 * a fontdir resource.
2678 *
2679 * Note: MS' resource compiler (build 1472) does not
2680 * handle font resources with different languages.
2681 * The fontdir is generated in the last active language
2682 * and font identifiers must be unique across the entire
2683 * source.
2684 * This is not logical considering the localization
2685 * constraints of all other resource types. MS has,
2686 * most probably, never testet localized fonts. However,
2687 * using fontresources is rare, so it might not occur
2688 * in normal applications.
2689 * Wine does require better localization because a lot
2690 * of languages are coded into the same executable.
2691 * Therefore, I will generate fontdirs for *each*
2692 * localized set of fonts.
2693 */
2694 static resource_t *build_fontdir(resource_t **fnt, int nfnt)
2695 {
2696 static int once = 0;
2697 if(!once)
2698 {
2699 warning("Need to parse fonts, not yet implemented (fnt: %p, nfnt: %d)\n", fnt, nfnt);
2700 once++;
2701 }
2702 return NULL;
2703 }
2704
2705 static resource_t *build_fontdirs(resource_t *tail)
2706 {
2707 resource_t *rsc;
2708 resource_t *lst = NULL;
2709 resource_t **fnt = NULL; /* List of all fonts */
2710 int nfnt = 0;
2711 resource_t **fnd = NULL; /* List of all fontdirs */
2712 int nfnd = 0;
2713 resource_t **lanfnt = NULL;
2714 int nlanfnt = 0;
2715 int i;
2716 name_id_t nid;
2717 string_t str;
2718 int fntleft;
2719
2720 nid.type = name_str;
2721 nid.name.s_name = &str;
2722 str.type = str_char;
2723 str.str.cstr = xstrdup("FONTDIR");
2724 str.size = 7;
2725
2726 /* Extract all fonts and fontdirs */
2727 for(rsc = tail; rsc; rsc = rsc->prev)
2728 {
2729 if(rsc->type == res_fnt)
2730 {
2731 nfnt++;
2732 fnt = xrealloc(fnt, nfnt * sizeof(*fnt));
2733 fnt[nfnt-1] = rsc;
2734 }
2735 else if(rsc->type == res_fntdir)
2736 {
2737 nfnd++;
2738 fnd = xrealloc(fnd, nfnd * sizeof(*fnd));
2739 fnd[nfnd-1] = rsc;
2740 }
2741 }
2742
2743 /* Verify the name of the present fontdirs */
2744 for(i = 0; i < nfnd; i++)
2745 {
2746 if(compare_name_id(&nid, fnd[i]->name))
2747 {
2748 warning("User supplied FONTDIR entry has an invalid name '%s', ignored\n",
2749 get_nameid_str(fnd[i]->name));
2750 fnd[i] = NULL;
2751 }
2752 }
2753
2754 /* Sanity check */
2755 if(nfnt == 0)
2756 {
2757 if(nfnd != 0)
2758 warning("Found %d FONTDIR entries without any fonts present\n", nfnd);
2759 goto clean;
2760 }
2761
2762 /* Copy space */
2763 lanfnt = xmalloc(nfnt * sizeof(*lanfnt));
2764 memset( lanfnt, 0, nfnt * sizeof(*lanfnt));
2765
2766 /* Get all fonts covered by fontdirs */
2767 for(i = 0; i < nfnd; i++)
2768 {
2769 int j;
2770 WORD cnt;
2771 int isswapped = 0;
2772
2773 if(!fnd[i])
2774 continue;
2775 for(j = 0; j < nfnt; j++)
2776 {
2777 if(!fnt[j])
2778 continue;
2779 if(fnt[j]->lan->id == fnd[i]->lan->id && fnt[j]->lan->sub == fnd[i]->lan->sub)
2780 {
2781 lanfnt[nlanfnt] = fnt[j];
2782 nlanfnt++;
2783 fnt[j] = NULL;
2784 }
2785 }
2786
2787 cnt = *(WORD *)fnd[i]->res.fnd->data->data;
2788 if(nlanfnt == cnt)
2789 isswapped = 0;
2790 else if(nlanfnt == BYTESWAP_WORD(cnt))
2791 isswapped = 1;
2792 else
2793 error("FONTDIR for language %d,%d has wrong count (%d, expected %d)\n",
2794 fnd[i]->lan->id, fnd[i]->lan->sub, cnt, nlanfnt);
2795 #ifdef WORDS_BIGENDIAN
2796 if((byteorder == WRC_BO_LITTLE && !isswapped) || (byteorder != WRC_BO_LITTLE && isswapped))
2797 #else
2798 if((byteorder == WRC_BO_BIG && !isswapped) || (byteorder != WRC_BO_BIG && isswapped))
2799 #endif
2800 {
2801 internal_error(__FILE__, __LINE__, "User supplied FONTDIR needs byteswapping\n");
2802 }
2803 }
2804
2805 /* We now have fonts left where we need to make a fontdir resource */
2806 for(i = fntleft = 0; i < nfnt; i++)
2807 {
2808 if(fnt[i])
2809 fntleft++;
2810 }
2811 while(fntleft)
2812 {
2813 /* Get fonts of same language in lanfnt[] */
2814 for(i = nlanfnt = 0; i < nfnt; i++)
2815 {
2816 if(fnt[i])
2817 {
2818 if(!nlanfnt)
2819 {
2820 addlanfnt:
2821 lanfnt[nlanfnt] = fnt[i];
2822 nlanfnt++;
2823 fnt[i] = NULL;
2824 fntleft--;
2825 }
2826 else if(fnt[i]->lan->id == lanfnt[0]->lan->id && fnt[i]->lan->sub == lanfnt[0]->lan->sub)
2827 goto addlanfnt;
2828 }
2829 }
2830 /* and build a fontdir */
2831 rsc = build_fontdir(lanfnt, nlanfnt);
2832 if(rsc)
2833 {
2834 if(lst)
2835 {
2836 lst->next = rsc;
2837 rsc->prev = lst;
2838 }
2839 lst = rsc;
2840 }
2841 }
2842
2843 free(lanfnt);
2844 clean:
2845 free(fnt);
2846 free(fnd);
2847 free(str.str.cstr);
2848 return lst;
2849 }
2850
2851 /*
2852 * This gets invoked to determine whether the next resource
2853 * is to be of a standard-type (e.g. bitmaps etc.), or should
2854 * be a user-type resource. This function is required because
2855 * there is the _possibility_ of a lookahead token in the
2856 * parser, which is generated from the "expr" state in the
2857 * "nameid" parsing.
2858 *
2859 * The general resource format is:
2860 * <identifier> <type> <flags> <resourcebody>
2861 *
2862 * The <identifier> can either be tIDENT or "expr". The latter
2863 * will always generate a lookahead, which is the <type> of the
2864 * resource to parse. Otherwise, we need to get a new token from
2865 * the scanner to determine the next step.
2866 *
2867 * The problem arrises when <type> is numerical. This case should
2868 * map onto default resource-types and be parsed as such instead
2869 * of being mapped onto user-type resources.
2870 *
2871 * The trick lies in the fact that yacc (bison) doesn't care about
2872 * intermediate changes of the lookahead while reducing a rule. We
2873 * simply replace the lookahead with a token that will result in
2874 * a shift to the appropriate rule for the specific resource-type.
2875 */
2876 static int rsrcid_to_token(int lookahead)
2877 {
2878 int token;
2879
2880 /* Get a token if we don't have one yet */
2881 if(lookahead == YYEMPTY)
2882 lookahead = YYLEX;
2883
2884 /* Only numbers are possibly interesting */
2885 switch(lookahead)
2886 {
2887 case tNUMBER:
2888 case tLNUMBER:
2889 break;
2890 default:
2891 return lookahead;
2892 }
2893
2894 token = lookahead;
2895
2896 switch(yylval.num)
2897 {
2898 case WRC_RT_CURSOR:
2899 token = tCURSOR;
2900 break;
2901 case WRC_RT_ICON:
2902 token = tICON;
2903 break;
2904 case WRC_RT_BITMAP:
2905 token = tBITMAP;
2906 break;
2907 case WRC_RT_FONT:
2908 token = tFONT;
2909 break;
2910 case WRC_RT_FONTDIR:
2911 token = tFONTDIR;
2912 break;
2913 case WRC_RT_RCDATA:
2914 token = tRCDATA;
2915 break;
2916 case WRC_RT_MESSAGETABLE:
2917 token = tMESSAGETABLE;
2918 break;
2919 case WRC_RT_DLGINIT:
2920 token = tDLGINIT;
2921 break;
2922 case WRC_RT_ACCELERATOR:
2923 token = tACCELERATORS;
2924 break;
2925 case WRC_RT_MENU:
2926 token = tMENU;
2927 break;
2928 case WRC_RT_DIALOG:
2929 token = tDIALOG;
2930 break;
2931 case WRC_RT_VERSION:
2932 token = tVERSIONINFO;
2933 break;
2934 case WRC_RT_TOOLBAR:
2935 token = tTOOLBAR;
2936 break;
2937 case WRC_RT_HTML:
2938 token = tHTML;
2939 break;
2940
2941 case WRC_RT_STRING:
2942 break;
2943
2944 case WRC_RT_ANICURSOR:
2945 case WRC_RT_ANIICON:
2946 case WRC_RT_GROUP_CURSOR:
2947 case WRC_RT_GROUP_ICON:
2948 parser_warning("Usertype uses reserved type ID %d, which is auto-generated\n", yylval.num);
2949 return lookahead;
2950
2951 case WRC_RT_DLGINCLUDE:
2952 case WRC_RT_PLUGPLAY:
2953 case WRC_RT_VXD:
2954 parser_warning("Usertype uses reserved type ID %d, which is not supported by wrc yet\n", yylval.num);
2955 default:
2956 return lookahead;
2957 }
2958
2959 return token;
2960 }
an attempt at megring old patches into wine