configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 AC_ARG_ENABLE(debug,
  35 [  --disable-debug         compile out all debugging messages],
  36 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  37
  38 AC_ARG_ENABLE(trace,
  39 [  --disable-trace         compile out TRACE messages],
  40 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  41
  42 AC_ARG_WITH(reentrant-x,
  43 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  44
  45 AC_SUBST(MAIN_TARGET)
  46 AC_SUBST(LIB_TARGET)
  47 AC_SUBST(ALT_LINK)
  48 AC_SUBST(OPTIONS)
  49
  50 if test "$DEBUG_MSGS" = "no"
  51 then
  52     AC_DEFINE(NO_DEBUG_MSGS)
  53     AC_DEFINE(NO_TRACE_MSGS)
  54 else
  55     if test "$TRACE_MSGS" = "no"
  56     then
  57         AC_DEFINE(NO_TRACE_MSGS)
  58     fi
  59 fi
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CPP
  66 AC_PATH_XTRA
  67 AC_PROG_YACC
  68 AC_PROG_LEX
  69 AC_PROG_RANLIB
  70 AC_PROG_INSTALL
  71 AC_PROG_LN_S
  72 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  73 AC_PATH_PROG(LDCONFIG, ldconfig, false, /sbin:/usr/sbin:$PATH)
  74
  75 dnl **** Check for some libraries ****
  76
  77 dnl Check for -lm for BeOS
  78 AC_CHECK_LIB(m,sqrt)
  79 dnl Check for -li386 for NetBSD and OpenBSD
  80 AC_CHECK_LIB(i386,i386_set_ldt)
  81 dnl Check for -lossaudio for NetBSD
  82 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  83 dnl Check for -lw for Solaris
  84 AC_CHECK_LIB(w,iswalnum)
  85 dnl Check for -lnsl for Solaris
  86 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
  87 dnl Check for -lsocket for Solaris
  88 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
  89 dnl Check for -lxpg4 for FreeBSD
  90 AC_CHECK_LIB(xpg4,setrunelocale)
  91 dnl Check for -lmmap for OS/2
  92 AC_CHECK_LIB(mmap,mmap)
  93
  94 AC_CHECK_HEADERS(dlfcn.h,
  95         AC_CHECK_FUNCS(dlopen,
  96                 AC_DEFINE(HAVE_DL_API),
  97                 AC_CHECK_LIB(dl,dlopen,
  98                         AC_DEFINE(HAVE_DL_API)
  99                         LIBS="$LIBS -ldl"
 100                 )
 101         )
 102 )
 103 AC_SUBST(XLIB)
 104 if test "$have_x" = "yes"
 105 then
 106     XLIB="-lXext -lX11"
 107     ac_save_CPPFLAGS="$CPPFLAGS"
 108     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 109
 110     dnl Check for -lXpm
 111     AC_CHECK_HEADERS(X11/xpm.h)
 112     if test "$ac_cv_header_X11_xpm_h" = "yes"
 113     then
 114         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 115     fi
 116
 117     dnl Check for X Shm extension
 118     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 119     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 120     then
 121         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 122     fi
 123     dnl Check for XFree86 DGA extension
 124     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 125     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 126     then
 127          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 128     fi
 129
 130     dnl Check for XFree86 VMODE extension
 131     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 132     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 133     then
 134         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 135     fi
 136
 137     dnl Check for the presence of Mesa
 138     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 139     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 140     then
 141         dnl Check for some problems due to old Mesa versions
 142         AC_CACHE_CHECK("for up-to-date Mesa version", wine_cv_mesa_version_OK,
 143           AC_TRY_COMPILE(
 144             [#include <GL/gl.h>],
 145             [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 146             [wine_cv_mesa_version_OK="yes"],
 147             [wine_cv_mesa_version_OK="no"]
 148           )
 149         )
 150
 151         if test "$wine_cv_mesa_version_OK" = "yes"
 152         then
 153             dnl Check for the presense of the library
 154             AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 155         fi
 156     fi
 157
 158     CPPFLAGS="$ac_save_CPPFLAGS"
 159 else
 160     XLIB=""
 161     X_CFLAGS=""
 162     X_LIBS=""
 163 fi
 164
 165 dnl **** Check which curses lib to use ***
 166 AC_CHECK_HEADERS(ncurses.h)
 167 if test "$ac_cv_header_ncurses_h" = "yes"
 168 then
 169     AC_CHECK_LIB(ncurses,waddch)
 170 fi
 171 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 172 then
 173     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 174     AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 175 else
 176     AC_CHECK_HEADERS(curses.h)
 177     if test "$ac_cv_header_curses_h" = "yes"
 178     then
 179        AC_CHECK_LIB(curses,waddch)
 180        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 181        AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 182     fi
 183 fi
 184
 185 dnl **** Check for IPX (currently Linux only) ****
 186 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 187  AC_TRY_COMPILE(
 188    [#include <sys/socket.h>
 189     #include <netipx/ipx.h>],
 190    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 191    [AC_DEFINE(HAVE_IPX_GNU)
 192     ac_cv_c_ipx_gnu="yes"],
 193    [ac_cv_c_ipx_gnu="no"])
 194  )
 195
 196 if test "$ac_cv_c_ipx_gnu" = "no"
 197 then
 198  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 199   AC_TRY_COMPILE(
 200     [#include <sys/socket.h>
 201      #include <asm/types.h>
 202      #include <linux/ipx.h>],
 203     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 204     [AC_DEFINE(HAVE_IPX_LINUX)
 205      ac_cv_c_ipx_linux="yes"],
 206     [ac_cv_c_ipx_linux="no"])
 207   )
 208 fi
 209
 210 dnl **** Check for Open Sound System ****
 211 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 212
 213 AC_CACHE_CHECK("for Open Sound System",
 214         ac_cv_c_opensoundsystem,
 215         AC_TRY_COMPILE([
 216         #if defined(HAVE_SYS_SOUNDCARD_H)
 217                 #include <sys/soundcard.h>
 218         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 219                 #include <machine/soundcard.h>
 220         #elif defined(HAVE_SOUNDCARD_H)
 221                 #include <soundcard.h>
 222         #endif
 223         ],[
 224
 225 /* check for one of the Open Sound System specific SNDCTL_ defines */
 226 #if !defined(SNDCTL_DSP_STEREO)
 227 #error No open sound system
 228 #endif
 229 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 230
 231 if test "$ac_cv_c_opensoundsystem" = "yes"
 232 then
 233     AC_DEFINE(HAVE_OSS)
 234 fi
 235
 236 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 237         ac_cv_c_opensoundsystem_midi,
 238         AC_TRY_COMPILE([
 239         #if defined(HAVE_SYS_SOUNDCARD_H)
 240                 #include <sys/soundcard.h>
 241         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 242                 #include <machine/soundcard.h>
 243         #elif defined(HAVE_SOUNDCARD_H)
 244                 #include <soundcard.h>
 245         #endif
 246         ],[
 247
 248 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 249 #if !defined(SNDCTL_SEQ_SYNC)
 250 #error No open sound system MIDI interface
 251 #endif
 252 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 253
 254 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 255 then
 256     AC_DEFINE(HAVE_OSS_MIDI)
 257 fi
 258
 259 dnl **** If ln -s doesn't work, use cp instead ****
 260 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 261
 262 dnl **** Check for gcc strength-reduce bug ****
 263
 264 if test "x${GCC}" = "xyes"
 265 then
 266   CFLAGS="$CFLAGS -Wall"
 267   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 268                   AC_TRY_RUN([
 269 int main(void) {
 270   static int Array[[3]];
 271   unsigned int B = 3;
 272   int i;
 273   for(i=0; i<B; i++) Array[[i]] = i - 3;
 274   exit( Array[[1]] != -2 );
 275 }],
 276     ac_cv_c_gcc_strength_bug="no",
 277     ac_cv_c_gcc_strength_bug="yes",
 278     ac_cv_c_gcc_strength_bug="yes") )
 279   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 280   then
 281     CFLAGS="$CFLAGS -fno-strength-reduce"
 282   fi
 283 fi
 284
 285 dnl **** Check for underscore on external symbols ****
 286
 287 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 288                ac_cv_c_extern_prefix,
 289 [saved_libs=$LIBS
 290 LIBS="conftest_asm.s $LIBS"
 291 cat > conftest_asm.s <<EOF
 292         .globl _ac_test
 293 _ac_test:
 294         .long 0
 295 EOF
 296 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 297             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 298 LIBS=$saved_libs])
 299 if test "$ac_cv_c_extern_prefix" = "yes"
 300 then
 301   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 302 fi
 303
 304 dnl **** Check for .string in assembler ****
 305
 306 AC_CACHE_CHECK("whether assembler accepts .string",
 307                ac_cv_c_asm_string,
 308 [saved_libs=$LIBS
 309 LIBS="conftest_asm.s $LIBS"
 310 cat > conftest_asm.s <<EOF
 311         .string "test"
 312 EOF
 313 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 314 LIBS=$saved_libs])
 315 if test "$ac_cv_c_asm_string" = "yes"
 316 then
 317   AC_DEFINE(HAVE_ASM_STRING)
 318 fi
 319
 320 dnl **** Check for working dll ****
 321
 322 DLLFLAGS=""
 323 LDSHARED=""
 324 if test "$LIB_TARGET" = "libwine.so.1.0"
 325 then
 326   AC_CACHE_CHECK("whether we can build a Linux dll",
 327                  ac_cv_c_dll_linux,
 328   [saved_cflags=$CFLAGS
 329   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 330   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 331   CFLAGS=$saved_cflags
 332   ])
 333   if test "$ac_cv_c_dll_linux" = "yes"
 334   then
 335     DLLFLAGS="-fPIC"
 336     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 337   else
 338     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 339                    ac_cv_c_dll_netbsd,
 340     [saved_cflags=$CFLAGS
 341     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 342     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 343     CFLAGS=$saved_cflags
 344     ])
 345     if test "$ac_cv_c_dll_netbsd" = "yes"
 346     then
 347       DLLFLAGS="-fPIC"
 348       LDSHARED="ld -Bshareable -Bforcearchive"
 349     fi
 350   fi
 351   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 352   then
 353     LIB_TARGET="libwine.a"
 354   fi
 355 fi
 356 AC_SUBST(DLLFLAGS)
 357 AC_SUBST(LDSHARED)
 358
 359 dnl **** Check for reentrant libc ****
 360 dnl
 361 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 362 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 363
 364 wine_cv_libc_reentrant=no
 365 dnl
 366 dnl Linux style errno location
 367 dnl
 368 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 369   [AC_TRY_RUN([int myerrno = 0;
 370 char buf[256];
 371 int *__errno_location(){return &myerrno;}
 372 main(){connect(0,buf,255); exit(!myerrno);}],
 373   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 374   wine_cv_libc_r__errno_location=yes )
 375 ])
 376 if test "$wine_cv_libc_r__errno_location" = "yes"
 377 then
 378     AC_DEFINE(HAVE__ERRNO_LOCATION)
 379     wine_cv_libc_reentrant=__errno_location
 380 fi
 381 dnl
 382 dnl FreeBSD style errno location
 383 dnl
 384 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 385   [AC_TRY_RUN([int myerrno = 0;
 386 char buf[256];
 387 int *__error(){return &myerrno;}
 388 main(){connect(0,buf,255); exit(!myerrno);}],
 389     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 390     wine_cv_libc_r__error=yes )
 391 ])
 392 if test "$wine_cv_libc_r__error" = "yes"
 393 then
 394     AC_DEFINE(HAVE__ERROR)
 395     wine_cv_libc_reentrant=__error
 396 fi
 397 dnl
 398 dnl Solaris style errno location
 399 dnl
 400 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 401   [AC_TRY_RUN([int myerrno = 0;
 402 char buf[256];
 403 int *___errno(){return &myerrno;}
 404 main(){connect(0,buf,255); exit(!myerrno);}],
 405     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 406     wine_cv_libc_r___errno=yes )
 407 ])
 408 if test "$wine_cv_libc_r___errno" = "yes"
 409 then
 410     AC_DEFINE(HAVE___ERRNO)
 411     wine_cv_libc_reentrant=___errno
 412 fi
 413 if test "$wine_cv_libc_reentrant" = "no"
 414 then
 415   AC_DEFINE(NO_REENTRANT_LIBC)
 416 fi
 417
 418 dnl **** Check for reentrant X libraries ****
 419 dnl
 420 dnl This may fail to determine whether X libraries are reentrant if
 421 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 422 dnl is possible with the --without-reentrant-x option.
 423
 424 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 425 then
 426 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 427   [ if test "x$with_reentrant_x" = "xno"
 428     then
 429         wine_cv_x_reentrant=no
 430     else
 431         libX11_check=none
 432         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 433             if test -r $dir/libX11.so; then
 434                 libX11_check="-D $dir/libX11.so"
 435                 break 1
 436             fi
 437             if test -r $dir/libX11.a; then
 438                 libX11_check="$dir/libX11.a"
 439                 break 1
 440             fi
 441         done
 442         if test "$libX11_check" != "none"; then
 443             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 444             then
 445                 wine_cv_x_reentrant=yes
 446             else
 447                 wine_cv_x_reentrant=no
 448             fi
 449         else
 450             wine_cv_x_reentrant=unknown
 451         fi
 452     fi ] )
 453 else
 454     wine_cv_x_reentrant=no
 455 fi
 456 if test "$wine_cv_x_reentrant" = "no"
 457 then
 458   AC_DEFINE(NO_REENTRANT_X11)
 459 fi
 460
 461 dnl **** Check for functions ****
 462
 463 AC_FUNC_ALLOCA()
 464 AC_CHECK_FUNCS(\
 465         _lwp_create \
 466         clone \
 467         getpagesize \
 468         memmove \
 469         rfork \
 470         sendmsg \
 471         sigaltstack \
 472         strerror \
 473         stricmp \
 474         tcgetattr \
 475         timegm \
 476         usleep \
 477         vfscanf \
 478         wait4 \
 479         waitpid \
 480 )
 481
 482 dnl **** Check for header files ****
 483
 484 AC_CHECK_HEADERS(\
 485         arpa/nameser.h \
 486         curses.h \
 487         elf.h \
 488         float.h \
 489         libio.h \
 490         linux/cdrom.h \
 491         linux/ucdrom.h \
 492         ncurses.h \
 493         net/if.h \
 494         netinet/in.h \
 495         resolv.h \
 496         strings.h \
 497         sys/cdio.h \
 498         sys/errno.h \
 499         sys/file.h \
 500         sys/filio.h \
 501         sys/lwp.h \
 502         sys/mman.h \
 503         sys/modem.h \
 504         sys/mount.h \
 505         sys/param.h \
 506         sys/signal.h \
 507         sys/sockio.h \
 508         sys/statfs.h \
 509         sys/strtio.h \
 510         sys/syscall.h \
 511         sys/vfs.h \
 512         syscall.h \
 513         ucontext.h \
 514         unistd.h \
 515         wctype.h \
 516 )
 517 AC_HEADER_STAT()
 518
 519 dnl **** Check for types ****
 520
 521 AC_C_CONST()
 522 AC_C_INLINE()
 523 AC_TYPE_SIZE_T()
 524 AC_CHECK_SIZEOF(long long,0)
 525
 526 dnl **** statfs checks ****
 527
 528 if test "$ac_cv_header_sys_vfs_h" = "yes"
 529 then
 530     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 531                     wine_cv_sys_vfs_has_statfs,
 532         AC_TRY_COMPILE([
 533         #include <sys/types.h>
 534         #ifdef HAVE_SYS_PARAM_H
 535         # include <sys/param.h>
 536         #endif
 537         #include <sys/vfs.h>
 538         ],[
 539                 struct statfs stfs;
 540
 541                 memset(&stfs,0,sizeof(stfs));
 542         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 543         )
 544     )
 545     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 546     then
 547       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 548     fi
 549 fi
 550
 551 if test "$ac_cv_header_sys_statfs_h" = "yes"
 552 then
 553     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 554                     wine_cv_sys_statfs_has_statfs,
 555         AC_TRY_COMPILE([
 556         #include <sys/types.h>
 557         #ifdef HAVE_SYS_PARAM_H
 558         # include <sys/param.h>
 559         #endif
 560         #include <sys/statfs.h>
 561         ],[
 562                 struct statfs stfs;
 563         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 564         )
 565     )
 566     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 567     then
 568       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 569     fi
 570 fi
 571
 572 if test "$ac_cv_header_sys_mount_h" = "yes"
 573 then
 574     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 575                     wine_cv_sys_mount_has_statfs,
 576         AC_TRY_COMPILE([
 577         #include <sys/types.h>
 578         #ifdef HAVE_SYS_PARAM_H
 579         # include <sys/param.h>
 580         #endif
 581         #include <sys/mount.h>
 582         ],[
 583                 struct statfs stfs;
 584         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 585         )
 586     )
 587     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 588     then
 589       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 590     fi
 591 fi
 592
 593 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 594
 595 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 596   [ if test "x$statfs_bfree" = "xno"
 597     then
 598         wine_cv_statfs_bfree=no
 599     else
 600         AC_TRY_COMPILE([
 601         #include <sys/types.h>
 602         #ifdef HAVE_SYS_PARAM_H
 603         # include <sys/param.h>
 604         #endif
 605         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 606         # include <sys/mount.h>
 607         #else
 608         # ifdef STATFS_DEFINED_BY_SYS_VFS
 609         #  include <sys/vfs.h>
 610         # else
 611         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 612         #   include <sys/statfs.h>
 613         #  endif
 614         # endif
 615         #endif
 616         ],[
 617                 struct statfs stfs;
 618
 619                 stfs.f_bfree++;
 620         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 621         )
 622     fi ] )
 623 if test "$wine_cv_statfs_bfree" = "yes"
 624 then
 625   AC_DEFINE(STATFS_HAS_BFREE)
 626 fi
 627
 628 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 629   [ if test "x$statfs_bavail" = "xno"
 630     then
 631         wine_cv_statfs_bavail=no
 632     else
 633         AC_TRY_COMPILE([
 634         #include <sys/types.h>
 635         #ifdef HAVE_SYS_PARAM_H
 636         # include <sys/param.h>
 637         #endif
 638         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 639         # include <sys/mount.h>
 640         #else
 641         # ifdef STATFS_DEFINED_BY_SYS_VFS
 642         #  include <sys/vfs.h>
 643         # else
 644         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 645         #   include <sys/statfs.h>
 646         #  endif
 647         # endif
 648         #endif
 649         ],[
 650                 struct statfs stfs;
 651
 652                 stfs.f_bavail++;
 653         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 654         )
 655     fi ] )
 656 if test "$wine_cv_statfs_bavail" = "yes"
 657 then
 658   AC_DEFINE(STATFS_HAS_BAVAIL)
 659 fi
 660
 661 dnl *** check for working sigaltstack
 662 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 663
 664 AC_CACHE_CHECK("for working sigaltstack",
 665         ac_cv_c_working_sigaltstack,
 666         AC_TRY_RUN([
 667         #include <stdio.h>
 668         #include <time.h> /* <sys/time.h> ? bad magic without end */
 669         #include <sys/types.h>
 670         #include <sys/signal.h>
 671         #ifdef HAVE_SYS_PARAM_H
 672         # include <sys/param.h>
 673         #endif
 674         #ifdef HAVE_SYSCALL_H
 675         # include <syscall.h>
 676         #else
 677         # ifdef HAVE_SYS_SYSCALL_H
 678         #  include <sys/syscall.h>
 679         # endif
 680         #endif
 681
 682         unsigned char *xaltstack;
 683
 684         int
 685         main(int argc,char **argv) {
 686             struct sigaltstack  ss;
 687
 688             xaltstack = malloc(16384);
 689             ss.ss_sp    = xaltstack;
 690             ss.ss_size  = 16384;
 691             ss.ss_flags = 0;
 692             if (sigaltstack(&ss, NULL) < 0) {
 693                 /* this catches the glibc case */
 694                 perror("sigaltstack");
 695                 return (1); /* aka exit(1) aka fail */
 696             }
 697             /* assume it works. */
 698             return 0; /* OK */
 699         }
 700         ],
 701         ac_cv_c_working_sigaltstack="yes",
 702         ac_cv_c_working_sigaltstack="no",
 703         ac_cv_c_working_sigaltstack="no"
 704 ))
 705
 706 if test "$ac_cv_c_working_sigaltstack" = "yes"
 707 then
 708     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 709 fi
 710
 711
 712 dnl *** check for file descriptor passing with msg_accrights
 713
 714 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 715  AC_TRY_COMPILE([#include <sys/types.h>
 716 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 717                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 718 if test "$ac_cv_c_msg_accrights" = "yes"
 719 then
 720     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 721 fi
 722
 723 dnl *** check for the need to define __i386__
 724
 725 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
 726  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
 727 yes
 728 #endif],
 729  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
 730 if test "$ac_cv_cpp_def_i386" = "yes"
 731 then
 732     CFLAGS="$CFLAGS -D__i386__"
 733 fi
 734
 735 dnl $GCC is set by autoconf
 736 GCC_NO_BUILTIN=""
 737 if test "$GCC" = "yes"
 738 then
 739     GCC_NO_BUILTIN="-fno-builtin"
 740 fi
 741 AC_SUBST(GCC_NO_BUILTIN)
 742
 743 dnl **** Generate output files ****
 744
 745 MAKE_RULES=Make.rules
 746 AC_SUBST_FILE(MAKE_RULES)
 747
 748 AC_OUTPUT([
 749 Make.rules
 750 Makefile
 751 console/Makefile
 752 controls/Makefile
 753 debugger/Makefile
 754 dlls/Makefile
 755 dlls/advapi32/Makefile
 756 dlls/avifil32/Makefile
 757 dlls/comctl32/Makefile
 758 dlls/commdlg/Makefile
 759 dlls/imagehlp/Makefile
 760 dlls/msacm/Makefile
 761 dlls/msacm32/Makefile
 762 dlls/ntdll/Makefile
 763 dlls/psapi/Makefile
 764 dlls/rasapi32/Makefile
 765 dlls/shell32/Makefile
 766 dlls/tapi32/Makefile
 767 dlls/ver/Makefile
 768 dlls/version/Makefile
 769 dlls/winaspi/Makefile
 770 dlls/winspool/Makefile
 771 dlls/wnaspi32/Makefile
 772 documentation/Makefile
 773 documentation/wine.man
 774 files/Makefile
 775 graphics/Makefile
 776 graphics/enhmetafiledrv/Makefile
 777 graphics/metafiledrv/Makefile
 778 graphics/psdrv/Makefile
 779 graphics/ttydrv/Makefile
 780 graphics/win16drv/Makefile
 781 graphics/x11drv/Makefile
 782 if1632/Makefile
 783 include/Makefile
 784 library/Makefile
 785 libtest/Makefile
 786 loader/Makefile
 787 loader/ne/Makefile
 788 loader/dos/Makefile
 789 memory/Makefile
 790 misc/Makefile
 791 miscemu/Makefile
 792 msdos/Makefile
 793 multimedia/Makefile
 794 objects/Makefile
 795 ole/Makefile
 796 programs/Makefile
 797 programs/clock/Makefile
 798 programs/cmdlgtst/Makefile
 799 programs/control/Makefile
 800 programs/avitools/Makefile
 801 programs/notepad/Makefile
 802 programs/progman/Makefile
 803 programs/regtest/Makefile
 804 programs/regapi/Makefile
 805 programs/view/Makefile
 806 programs/wcmd/Makefile
 807 programs/winhelp/Makefile
 808 programs/winver/Makefile
 809 rc/Makefile
 810 relay32/Makefile
 811 resources/Makefile
 812 scheduler/Makefile
 813 server/Makefile
 814 tools/Makefile
 815 tools/wrc/Makefile
 816 tsx11/Makefile
 817 win32/Makefile
 818 windows/Makefile
 819 windows/ttydrv/Makefile
 820 windows/x11drv/Makefile ])
 821
 822 if test "$have_x" = "no"
 823 then
 824   echo
 825   echo "*** Warning: X development files not found. Wine will be built without"
 826   echo "*** X support, which currently does not work, and would probably not be"
 827   echo "*** what you want anyway. You will need to install devel packages of"
 828   echo "*** Xlib/Xfree86 and Xpm at the very least."
 829 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 830 then
 831   echo
 832   echo "*** Warning: Xpm development files not found. Wine will be built without"
 833   echo "*** Xpm support, which currently does not work. You will need to install"
 834   echo "*** devel packages of Xpm."
 835 fi
 836
 837 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 838 then
 839   echo
 840   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 841   echo "*** terminal resize support. Consider upgrading ncurses."
 842 fi
 843
 844 if test "$wine_cv_libc_reentrant" = "no"
 845 then
 846   echo
 847   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 848   echo "*** thread support. Consider upgrading libc to a more recent"
 849   echo "*** reentrant version of libc."
 850 fi
 851
 852 if test "$wine_cv_mesa_version_OK" = "no"
 853 then
 854   echo
 855   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
 856   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)"
 857 fi
 858
 859 echo
 860 echo "Configure finished.  Do 'make depend && make' to compile Wine."
 861 echo
 862
 863 dnl Local Variables:
 864 dnl comment-start: "dnl "
 865 dnl comment-end: ""
 866 dnl comment-start-skip: "\\bdnl\\b\\s *"
 867 dnl compile-command: "autoconf"
 868 dnl End: