| blob | 5cc6309d46b693cbf5886e55355bf3acc6687eca |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
138 dnl **** Check for some libraries ****
140 dnl Check for -li386 for NetBSD and OpenBSD
141 AC_CHECK_LIB(i386,i386_set_ldt)
142 dnl Check for -lossaudio for NetBSD
143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
144 dnl Check for -lw for Solaris
145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
146 dnl Check for -lnsl for Solaris
147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
148 dnl Check for -lsocket for Solaris
149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
150 dnl Check for -lresolv for Solaris
151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
152 dnl Check for -lxpg4 for FreeBSD
153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
154 dnl Check for -lpoll for Mac OS X/Darwin
155 AC_CHECK_LIB(poll,poll)
156 dnl Check for -lresolv for Mac OS X/Darwin
157 AC_CHECK_LIB(resolv,res_9_init)
158 dnl Check for -lpthread
159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
171 dnl **** Check for header files ****
173 AC_CHECK_HEADERS(\
174 IOKit/IOKitLib.h \
175 arpa/inet.h \
176 arpa/nameser.h \
177 asm/types.h \
178 cups/cups.h \
179 direct.h \
180 elf.h \
181 float.h \
182 fontconfig/fontconfig.h \
183 getopt.h \
184 gif_lib.h \
185 ieeefp.h \
186 io.h \
187 jack/jack.h \
188 jpeglib.h \
189 lber.h \
190 lcms/lcms.h \
191 lcms.h \
192 ldap.h \
193 link.h \
194 linux/cdrom.h \
195 linux/compiler.h \
196 linux/hdreg.h \
197 linux/input.h \
198 linux/ioctl.h \
199 linux/joystick.h \
200 linux/major.h \
201 linux/param.h \
202 linux/serial.h \
203 linux/ucdrom.h \
204 mach/machine.h \
205 machine/cpu.h \
206 machine/limits.h \
207 mntent.h \
208 netdb.h \
209 netinet/in.h \
210 netinet/in_systm.h \
211 netinet/tcp.h \
212 netinet/tcp_fsm.h \
213 openssl/ssl.h \
214 poll.h \
215 process.h \
216 pthread.h \
217 pwd.h \
218 regex.h \
219 sched.h \
220 scsi/sg.h \
221 scsi/scsi.h \
222 scsi/scsi_ioctl.h \
223 stdint.h \
224 strings.h \
225 sys/cdio.h \
226 sys/elf32.h \
227 sys/errno.h \
228 sys/epoll.h \
229 sys/exec_elf.h \
230 sys/filio.h \
231 sys/ioctl.h \
232 sys/ipc.h \
233 sys/link.h \
234 sys/lwp.h \
235 sys/mman.h \
236 sys/modem.h \
237 sys/msg.h \
238 sys/param.h \
239 sys/poll.h \
240 sys/ptrace.h \
241 sys/reg.h \
242 sys/scsiio.h \
243 sys/shm.h \
244 sys/signal.h \
245 sys/socket.h \
246 sys/sockio.h \
247 sys/statfs.h \
248 sys/statvfs.h \
249 sys/strtio.h \
250 sys/syscall.h \
251 sys/sysctl.h \
252 sys/time.h \
253 sys/times.h \
254 sys/uio.h \
255 sys/un.h \
256 sys/vfs.h \
257 sys/vm86.h \
258 sys/wait.h \
259 syscall.h \
260 termios.h \
261 unistd.h \
262 utime.h \
263 valgrind/memcheck.h
264 )
265 AC_HEADER_STAT()
267 dnl **** Check for X11 ****
269 if test "$have_x" = "yes"
270 then
271 XLIB="-lXext -lX11"
272 ac_save_CPPFLAGS="$CPPFLAGS"
273 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
275 dnl *** All of the following tests require X11/Xlib.h
276 AC_CHECK_HEADERS(X11/Xlib.h,
277 [
278 AC_CHECK_HEADERS([X11/XKBlib.h \
279 X11/Xutil.h \
280 X11/extensions/shape.h \
281 X11/extensions/XInput.h \
282 X11/extensions/XShm.h \
283 X11/extensions/Xrandr.h \
284 X11/extensions/Xrender.h \
285 X11/extensions/xf86dga.h \
286 X11/extensions/xf86vmode.h],,,
287 [#include <X11/Xlib.h>
288 #ifdef HAVE_X11_XUTIL_H
289 # include <X11/Xutil.h>
290 #endif])
292 dnl *** Check for X keyboard extension
293 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
294 then
295 AC_CHECK_LIB(X11, XkbQueryExtension,
296 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
297 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
298 fi
300 dnl *** Check for X Shm extension
301 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
302 then
303 AC_CHECK_LIB(Xext, XShmQueryExtension,
304 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
305 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
306 fi
308 dnl *** Check for X shape extension
309 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
310 then
311 AC_CHECK_LIB(Xext,XShapeQueryExtension,
312 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
313 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
314 fi
316 dnl *** Check for XFree86 DGA / DGA 2.0 extension
317 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
318 then
319 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
320 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
321 [Define if you have the Xxf86dga library version 2])
322 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
323 ],,
324 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
325 fi
327 dnl *** Check for XFree86 VMODE extension
328 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
329 then
330 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
331 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
332 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
333 ],,
334 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
335 fi
337 dnl *** Check for X RandR extension
338 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
339 then
340 AC_TRY_COMPILE([#include <X11/Xlib.h>
341 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
342 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
343 fi
345 dnl *** Check for Transform functions in Xrender
346 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
347 then
348 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
349 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
350 [Define if Xrender has the XRenderSetPictureTransform function])],,
351 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
352 fi
353 ]
354 ) dnl *** End of X11/Xlib.h check
356 dnl Check for the presence of OpenGL
357 if test "x$with_opengl" != "xno"
358 then
359 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
360 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
361 then
362 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
363 dnl Check for some problems due to old Mesa versions
364 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
365 AC_TRY_COMPILE(
366 [#include <GL/gl.h>],
367 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
368 [wine_cv_opengl_version_OK="yes"],
369 [wine_cv_opengl_version_OK="no"]
370 )
371 )
373 if test "$wine_cv_opengl_version_OK" = "yes"
374 then
375 dnl Check for the presence of the library
376 AC_CHECK_LIB(GL,glXCreateContext,
377 OPENGL_LIBS="-lGL"
378 ,,
379 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
381 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
382 then
383 OPENGLFILES='$(OPENGLFILES)'
384 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
385 else
386 if test -f /usr/X11R6/lib/libGL.a
387 then
388 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
389 This prevents linking to OpenGL. Delete the file and restart configure.])
390 fi
391 fi
393 dnl Check for GLU32 library.
394 AC_CHECK_LIB(GLU,gluLookAt,
395 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
396 GLU32FILES='$(GLU32FILES)']
397 ,,
398 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
399 )
400 fi
402 dnl Check for glut32 library.
403 AC_CHECK_LIB(glut,glutMainLoop,
404 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
405 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
406 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
407 fi
408 fi
410 dnl **** Check for NAS ****
411 AC_SUBST(NASLIBS,"")
412 AC_CHECK_HEADERS(audio/audiolib.h,
413 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
414 AC_CHECK_LIB(audio,AuCreateFlow,
415 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
416 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
417 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
419 CPPFLAGS="$ac_save_CPPFLAGS"
420 XFILES='$(XFILES)'
421 else
422 XLIB=""
423 X_CFLAGS=""
424 X_LIBS=""
425 fi
427 dnl **** Check for libxml2 ****
429 AC_SUBST(XML2LIBS,"")
430 AC_SUBST(XML2INCL,"")
431 ac_save_CPPFLAGS="$CPPFLAGS"
432 CPPFLAGS="$CPPFLAGS -I/usr/include/libxml2"
433 AC_CHECK_HEADERS(libxml/parser.h,
434 [AC_CHECK_LIB(xml2, xmlReadIO,
435 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
436 XML2LIBS="-lxml2"
437 XML2INCL="-I/usr/include/libxml2"])])
438 CPPFLAGS="$ac_save_CPPFLAGS"
440 dnl **** Check which curses lib to use ***
441 CURSESLIBS=""
442 if test "x$with_curses" != "xno"
443 then
444 AC_CHECK_HEADERS(ncurses.h,
445 [AC_CHECK_LIB(ncurses,waddch,
446 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
447 CURSESLIBS="-lncurses"],
448 [AC_CHECK_HEADERS(curses.h,
449 [AC_CHECK_LIB(curses,waddch,
450 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
451 CURSESLIBS="-lcurses"])])])])
452 fi
453 AC_SUBST(CURSESLIBS)
455 dnl **** Check for SANE ****
456 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
457 if test "$sane_devel" = "no"
458 then
459 SANELIBS=""
460 SANEINCL=""
461 else
462 SANELIBS="`$sane_devel --libs`"
463 SANEINCL="`$sane_devel --cflags`"
464 ac_save_CPPFLAGS="$CPPFLAGS"
465 ac_save_LIBS="$LIBS"
466 CPPFLAGS="$CPPFLAGS $SANEINCL"
467 LIBS="$LIBS $SANELIBS"
468 AC_CHECK_HEADER(sane/sane.h,
469 [AC_CHECK_LIB(sane,sane_open,
470 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
471 [SANELIBS=""
472 SANEINCL=""])],
473 [SANELIBS=""
474 SANEINCL=""])
475 LIBS="$ac_save_LIBS"
476 CPPFLAGS="$ac_save_CPPFLAGS"
477 fi
478 AC_SUBST(SANELIBS)
479 AC_SUBST(SANEINCL)
481 dnl **** Check for the ICU library ****
482 AC_CHECK_HEADERS(unicode/ubidi.h)
483 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
484 then
485 saved_libs="$LIBS"
486 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
487 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
488 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
489 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
490 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
491 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
492 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
493 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
494 AC_MSG_RESULT(yes)],
495 [AC_MSG_RESULT(no)])
496 LIBS="$saved_libs"
497 fi
499 dnl **** Check for LittleCMS ***
500 AC_SUBST(LCMSLIBS,"")
501 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
502 then
503 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
504 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
505 LCMSLIBS="-llcms"])
506 fi
508 dnl **** Check for OpenLDAP ***
509 AC_SUBST(LDAPLIBS,"")
510 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
511 then
512 AC_CHECK_LIB(ldap, ldap_init,
513 [AC_CHECK_LIB(lber, ber_init,
514 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
515 LDAPLIBS="-lldap -llber"])])
516 fi
518 dnl **** Check for FreeType 2 ****
519 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
520 if test "$ft_lib" = "no"
521 then
522 FREETYPELIBS=""
523 FREETYPEINCL=""
524 wine_cv_msg_freetype=no
525 else
526 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
527 if test "$ft_devel" = "no"
528 then
529 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
530 if test "$ft_devel2" = "freetype2-config"
531 then
532 ft_devel=$ft_devel2
533 fi
534 fi
535 if test "$ft_devel" = "no"
536 then
537 FREETYPELIBS=""
538 FREETYPEINCL=""
539 wine_cv_msg_freetype=yes
540 else
541 FREETYPELIBS=`$ft_devel --libs`
542 FREETYPEINCL=`$ft_devel --cflags`
543 ac_save_CPPFLAGS="$CPPFLAGS"
544 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
545 AC_CHECK_HEADERS(ft2build.h \
546 freetype/freetype.h \
547 freetype/ftglyph.h \
548 freetype/tttables.h \
549 freetype/ftnames.h \
550 freetype/ftsnames.h \
551 freetype/ttnameid.h \
552 freetype/ftoutln.h \
553 freetype/ftwinfnt.h \
554 freetype/internal/sfnt.h,,,
555 [#if HAVE_FT2BUILD_H
556 #include <ft2build.h>
557 #endif])
558 AC_TRY_CPP([#include <ft2build.h>
559 #include <freetype/fttrigon.h>],
560 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
561 [Define if you have the <freetype/fttrigon.h> header file.])
562 wine_cv_fttrigon=yes],
563 wine_cv_fttrigon=no)
564 CPPFLAGS="$ac_save_CPPFLAGS"
565 dnl Check that we have at least freetype/freetype.h
566 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
567 then
568 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
569 wine_cv_msg_freetype=no
570 else
571 FREETYPELIBS=""
572 FREETYPEINCL=""
573 wine_cv_msg_freetype=yes
574 fi
575 fi
576 fi
577 AC_SUBST(FREETYPELIBS)
578 AC_SUBST(FREETYPEINCL)
580 dnl Only build the fonts dir if we have both freetype and fontforge
581 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
582 then
583 AC_SUBST(FONTSSUBDIRS,"fonts")
584 fi
586 dnl **** Check for parport (currently Linux only) ****
587 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
588 AC_TRY_COMPILE(
589 [#include <linux/ppdev.h>],
590 [ioctl (1,PPCLAIM,0)],
591 [ac_cv_c_ppdev="yes"],
592 [ac_cv_c_ppdev="no"])
593 )
594 if test "$ac_cv_c_ppdev" = "yes"
595 then
596 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
597 fi
599 dnl **** Check for va_copy ****
600 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
601 AC_TRY_LINK(
602 [#include <stdarg.h>],
603 [va_list ap1, ap2;
604 va_copy(ap1,ap2);
605 ],
606 [ac_cv_c_va_copy="yes"],
607 [ac_cv_c_va_copy="no"])
608 )
609 if test "$ac_cv_c_va_copy" = "yes"
610 then
611 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
612 fi
613 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
614 AC_TRY_LINK(
615 [#include <stdarg.h>],
616 [va_list ap1, ap2;
617 __va_copy(ap1,ap2);
618 ],
619 [ac_cv_c___va_copy="yes"],
620 [ac_cv_c___va_copy="no"])
621 )
622 if test "$ac_cv_c___va_copy" = "yes"
623 then
624 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
625 fi
627 dnl **** Check for sigsetjmp ****
628 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
629 AC_TRY_LINK(
630 [#include <setjmp.h>],
631 [sigjmp_buf buf;
632 sigsetjmp( buf, 1 );
633 siglongjmp( buf, 1 );],
634 [ac_cv_c_sigsetjmp="yes"],
635 [ac_cv_c_sigsetjmp="no"])
636 )
637 if test "$ac_cv_c_sigsetjmp" = "yes"
638 then
639 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
640 fi
642 dnl **** Check for pthread_rwlock_t ****
643 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
644 #include <pthread.h>])
646 dnl **** Check for pthread functions ****
647 ac_save_LIBS="$LIBS"
648 LIBS="$LIBS $LIBPTHREAD"
649 AC_CHECK_FUNCS(\
650 pthread_getattr_np \
651 pthread_get_stackaddr_np \
652 pthread_get_stacksize_np \
653 )
654 LIBS="$ac_save_LIBS"
656 dnl **** Check for Open Sound System ****
657 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
659 AC_CACHE_CHECK([for Open Sound System],
660 ac_cv_c_opensoundsystem,
661 AC_TRY_COMPILE([
662 #if defined(HAVE_SYS_SOUNDCARD_H)
663 #include <sys/soundcard.h>
664 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
665 #include <machine/soundcard.h>
666 #elif defined(HAVE_SOUNDCARD_H)
667 #include <soundcard.h>
668 #endif
669 ],[
671 /* check for one of the Open Sound System specific SNDCTL_ defines */
672 #if !defined(SNDCTL_DSP_STEREO)
673 #error No open sound system
674 #endif
675 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
677 if test "$ac_cv_c_opensoundsystem" = "yes"
678 then
679 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
680 fi
682 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
683 ac_cv_c_opensoundsystem_midi,
684 AC_TRY_COMPILE([
685 #if defined(HAVE_SYS_SOUNDCARD_H)
686 #include <sys/soundcard.h>
687 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
688 #include <machine/soundcard.h>
689 #elif defined(HAVE_SOUNDCARD_H)
690 #include <soundcard.h>
691 #endif
692 ],[
694 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
695 #if !defined(SNDCTL_SEQ_SYNC)
696 #error No open sound system MIDI interface
697 #endif
698 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
700 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
701 then
702 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
703 fi
705 dnl **** Check for aRts Sound Server ****
706 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
707 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
708 then
709 ARTSC_CFLAGS=""
710 for i in `$ARTSCCONFIG --cflags`
711 do
712 case "$i" in
713 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
714 esac
715 done
716 ARTSC_LIBS=`$ARTSCCONFIG --libs`
717 save_CFLAGS="$CFLAGS"
718 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
719 AC_CHECK_LIB(artsc,arts_init,
720 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
721 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
722 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
723 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
724 $ARTSC_LIBS)
725 CFLAGS="$save_CFLAGS"
726 fi
728 dnl **** Check for ALSA 1.x ****
729 AC_SUBST(ALSALIBS,"")
730 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
731 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
732 then
733 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
734 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
735 #include <alsa/asoundlib.h>
736 #elif defined(HAVE_SYS_ASOUNDLIB_H)
737 #include <sys/asoundlib.h>
738 #endif],
739 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
740 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
741 ALSALIBS="-lasound"])])
742 fi
744 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
746 AC_SUBST(AUDIOIOLIBS,"")
747 AC_CHECK_HEADERS(libaudioio.h,
748 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
749 [AUDIOIOLIBS="-laudioio"
750 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
752 dnl **** Check for capi4linux ****
754 AC_CHECK_HEADERS(capi20.h,[
755 AC_CHECK_HEADERS(linux/capi.h,[
756 AC_CHECK_LIB(capi20,capi20_register,[
757 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
758 ])
759 ])
760 ])
762 dnl **** Check for broken glibc mmap64 ****
764 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
765 AC_TRY_RUN([
766 #define _FILE_OFFSET_BITS 64
767 #include <stdio.h>
768 #include <unistd.h>
769 #include <fcntl.h>
770 #include <sys/mman.h>
771 #include <errno.h>
773 int main(int argc,char **argv) {
774 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
775 if (fd == -1) exit(1);
777 unlink("conftest.map");
779 write(fd,"test",4);
781 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
782 (errno == EINVAL)
783 ) {
784 exit(1);
785 }
786 close(fd);
787 fprintf(stderr,"success!\n");
788 exit(0);
789 }
791 ],
792 ac_cv_mmap64_works="yes",
793 ac_cv_mmap64_works="no",
794 ac_cv_mmap64_works="no") )
796 if test "$ac_cv_mmap64_works" = "yes"
797 then
798 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
799 fi
801 dnl **** Check for gcc specific options ****
803 AC_SUBST(EXTRACFLAGS,"")
804 if test "x${GCC}" = "xyes"
805 then
806 EXTRACFLAGS="-Wall -pipe"
808 dnl Check for strength-reduce bug
809 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
810 AC_TRY_RUN([
811 int L[[4]] = {0,1,2,3};
812 int main(void) {
813 static int Array[[3]];
814 unsigned int B = 3;
815 int i;
816 for(i=0; i<B; i++) Array[[i]] = i - 3;
817 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
818 L[[i]] = 4;
820 exit( Array[[1]] != -2 || L[[2]] != 3);
821 }],
822 ac_cv_c_gcc_strength_bug="no",
823 ac_cv_c_gcc_strength_bug="yes",
824 ac_cv_c_gcc_strength_bug="yes") )
825 if test "$ac_cv_c_gcc_strength_bug" = "yes"
826 then
827 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
828 fi
830 dnl Check for -fshort-wchar
831 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
832 [WINE_TRY_CFLAGS([-fshort-wchar],
833 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
834 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
835 then
836 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
837 fi
839 dnl Check for -mpreferred-stack-boundary
840 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
841 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
842 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
843 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
844 then
845 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
846 fi
848 dnl Check for -fno-strict-aliasing
849 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
850 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
851 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
852 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
853 then
854 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
855 fi
857 dnl Check for -gstabs+ option
858 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
859 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
860 if test "$ac_cv_c_gcc_gstabs" = "yes"
861 then
862 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
863 fi
865 dnl Check for noisy string.h
866 saved_CFLAGS="$CFLAGS"
867 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
868 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
869 AC_TRY_COMPILE([#include <string.h>],[],
870 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
871 CFLAGS="$saved_CFLAGS"
872 if test "$ac_cv_c_string_h_warnings" = "no"
873 then
874 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
875 fi
876 fi
878 dnl **** Check how to define a function in assembly code ****
880 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
881 WINE_TRY_ASM_LINK(
882 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
883 ac_cv_asm_func_def=".def",
884 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
885 ac_cv_asm_func_def=".type @function",
886 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
887 ac_cv_asm_func_def=".type 2",
888 ac_cv_asm_func_def="unknown")])]))
890 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
891 case "$ac_cv_asm_func_def" in
892 ".def")
893 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
894 ".type @function")
895 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
896 ".type 2")
897 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
898 *)
899 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
900 esac
902 dnl **** Check for underscore on external symbols ****
904 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
905 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
906 [extern int ac_test;],
907 [if (ac_test) return 1],
908 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
910 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
911 if test "$ac_cv_c_extern_prefix" = "yes"
912 then
913 AC_DEFINE([__ASM_NAME(name)], ["_" name])
914 else
915 AC_DEFINE([__ASM_NAME(name)], [name])
916 fi
918 dnl **** Check for working dll ****
920 AC_SUBST(DLLEXT,"")
921 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
922 AC_SUBST(DLLIBS,"")
923 AC_SUBST(LDSHARED,"")
924 AC_SUBST(LDDLLFLAGS,"")
925 AC_SUBST(LIBEXT,"so")
926 AC_SUBST(IMPLIBEXT,"def")
928 case $host_os in
929 cygwin*|mingw32*)
930 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
931 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
932 if test "$DLLWRAP" = "false"; then
933 LIBEXT="a"
934 else
935 dnl FIXME - check whether dllwrap works correctly...
936 LIBEXT="dll"
937 fi
938 IMPLIBEXT="a"
939 dnl We can't build 16-bit NE dlls
940 WIN16_FILES=""
941 WIN16_INSTALL=""
942 ;;
943 *)
944 AC_CHECK_HEADERS(dlfcn.h,
945 [AC_CHECK_FUNCS(dlopen,,
946 [AC_CHECK_LIB(dl,dlopen,
947 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
948 DLLIBS="-ldl"],
949 [LIBEXT="a"])])],
950 [LIBEXT="a"])
952 if test "$LIBEXT" = "so"
953 then
954 DLLFLAGS="$DLLFLAGS -fPIC"
955 DLLEXT=".so"
956 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
957 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
958 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
959 if test "$ac_cv_c_dll_gnuelf" = "yes"
960 then
961 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
962 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
963 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
964 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
965 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
966 if test "$ac_cv_c_dll_zdefs" = "yes"
967 then
968 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
969 fi
971 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
972 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
973 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
974 if test "$ac_cv_c_dll_init_fini" = "yes"
975 then
976 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
977 fi
979 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
980 [echo '{ global: *; };' >conftest.map
981 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
982 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
983 rm -f conftest.map])
984 if test "$ac_cv_c_ld_version_scripts" = "yes"
985 then
986 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
987 fi
989 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
990 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
991 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
992 if test "$ac_cv_c_export_dynamic" = "yes"
993 then
994 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
995 fi
997 case $host_cpu in
998 *i[[3456789]]86*)
999 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1000 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1001 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1002 if test "$ac_cv_ld_reloc_exec" = "yes"
1003 then
1004 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1005 fi
1006 ;;
1007 esac
1009 else
1010 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1011 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1012 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1013 if test "$ac_cv_c_dll_unixware" = "yes"
1014 then
1015 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1016 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1018 else
1019 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1020 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1021 if test "$ac_cv_c_dll_macho" = "yes"
1022 then
1023 LIBEXT="dylib"
1024 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1025 LDSHARED="\$(CC) -dynamiclib"
1026 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1027 STRIP="$STRIP -u -r"
1028 dnl Relocate wine executable
1029 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1030 dnl Relocate libwine.dyld too
1031 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1032 dnl declare needed frameworks
1033 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1034 AC_SUBST(IOKITLIB,"-framework IOKit")
1035 dnl using IOKit imply we use CoreFoundation too
1036 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1037 else
1038 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1039 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1040 if test "$ac_cv_c_dll_hpux" = "yes"
1041 then
1042 LIBEXT="sl"
1043 DLLEXT=".sl"
1044 LDDLLFLAGS="-shared -fPIC"
1045 LDSHARED="\$(CC) -shared"
1046 fi
1047 fi
1048 fi
1049 fi
1050 fi
1052 dnl Check for cross compiler to build test programs
1053 AC_SUBST(CROSSTEST,"")
1054 if test "$cross_compiling" = "no"
1055 then
1056 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1057 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1058 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1059 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1060 fi
1061 ;;
1062 esac
1064 if test "$LIBEXT" = "a"; then
1065 AC_MSG_ERROR(
1066 [could not find a way to build shared libraries.
1067 It is currently not possible to build Wine without shared library
1068 (.so) support to allow transparent switch between .so and .dll files.
1069 If you are using Linux, you will need a newer binutils.]
1070 )
1071 fi
1073 case $build_os in
1074 cygwin*|mingw32*)
1075 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1076 darwin*|macosx*)
1077 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1078 *)
1079 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1080 esac
1082 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1083 case $host_os in
1084 mingw32*)
1085 AC_SUBST(CRTLIBS,"-lmsvcrt")
1086 AC_SUBST(SOCKETLIBS,"-lws2_32")
1087 ;;
1088 esac
1090 case $host_os in
1091 linux*)
1092 case $host_cpu in
1093 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1094 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1095 esac
1096 AC_SUBST(MAIN_BINARY,"wine-glibc")
1097 ;;
1098 darwin*)
1099 AC_SUBST(WINE_BINARIES,"wine-pthread")
1100 AC_SUBST(MAIN_BINARY,"wine-pthread")
1101 ;;
1102 *)
1103 AC_SUBST(WINE_BINARIES,"wine-kthread")
1104 AC_SUBST(MAIN_BINARY,"wine-kthread")
1105 ;;
1106 esac
1108 dnl **** Get the soname for libraries that we load dynamically ****
1110 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1111 then
1112 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1113 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1114 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1115 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1116 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1117 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1118 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1119 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1120 WINE_GET_SONAME(cups,cupsGetDefault)
1121 WINE_GET_SONAME(jack,jack_client_new)
1122 WINE_GET_SONAME(fontconfig,FcInit)
1123 WINE_GET_SONAME(ssl,SSL_library_init)
1124 WINE_GET_SONAME(crypto,BIO_new_socket)
1125 WINE_GET_SONAME(ncurses,waddch)
1126 WINE_GET_SONAME(curses,waddch)
1127 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1128 WINE_GET_SONAME(ungif,DGifOpen)
1129 WINE_GET_SONAME(gif,DGifOpen)
1130 WINE_GET_SONAME(capi20,capi20_isinstalled)
1131 fi
1134 dnl **** Check for functions ****
1136 AC_FUNC_ALLOCA()
1137 AC_CHECK_FUNCS(\
1138 _lwp_create \
1139 _lwp_self \
1140 _pclose \
1141 _popen \
1142 _snprintf \
1143 _spawnvp \
1144 _stricmp \
1145 _strnicmp \
1146 _vsnprintf \
1147 chsize \
1148 clone \
1149 epoll_create \
1150 ffs \
1151 finite \
1152 fork \
1153 fpclass \
1154 fstatfs \
1155 fstatvfs \
1156 ftruncate \
1157 futimes \
1158 futimesat \
1159 getnetbyname \
1160 getopt_long \
1161 getpagesize \
1162 getprotobyname \
1163 getprotobynumber \
1164 getpwuid \
1165 getservbyport \
1166 gettid \
1167 gettimeofday \
1168 getuid \
1169 inet_network \
1170 lstat \
1171 memmove \
1172 mmap \
1173 pclose \
1174 popen \
1175 pread \
1176 pwrite \
1177 readlink \
1178 rfork \
1179 sched_yield \
1180 select \
1181 sendmsg \
1182 settimeofday \
1183 sigaltstack \
1184 sigprocmask \
1185 snprintf \
1186 spawnvp \
1187 statfs \
1188 statvfs \
1189 strcasecmp \
1190 strerror \
1191 strncasecmp \
1192 tcgetattr \
1193 timegm \
1194 usleep \
1195 vsnprintf \
1196 wait4 \
1197 waitpid \
1198 )
1200 dnl **** Checks for headers that depend on other ones ****
1202 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1203 [#include <sys/types.h>
1204 #if HAVE_SYS_PARAM_H
1205 # include <sys/param.h>
1206 #endif])
1208 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1209 [#include <sys/types.h>
1210 #if HAVE_SYS_SOCKET_H
1211 # include <sys/socket.h>
1212 #endif])
1214 AC_CHECK_HEADERS([resolv.h],,,
1215 [#include <sys/types.h>
1216 #if HAVE_SYS_SOCKET_H
1217 # include <sys/socket.h>
1218 #endif
1219 #if HAVE_NETINET_IN_H
1220 # include <netinet/in.h>
1221 #endif
1222 #if HAVE_ARPA_NAMESER_H
1223 # include <arpa/nameser.h>
1224 #endif])
1226 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1228 dnl **** Check for v4l(2) headers ****
1230 AC_CHECK_HEADERS(linux/videodev.h,,,
1231 [#ifdef HAVE_SYS_TIME_H
1232 #include <sys/time.h>
1233 #endif
1234 #include <sys/types.h>
1235 #ifdef HAVE_ASM_TYPES_H
1236 #include <asm/types.h>
1237 #endif])
1239 dnl **** Check for IPX headers (currently Linux only) ****
1241 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1242 AC_TRY_COMPILE(
1243 [#include <sys/types.h>
1244 #ifdef HAVE_SYS_SOCKET_H
1245 # include <sys/socket.h>
1246 #endif
1247 #include <netipx/ipx.h>],
1248 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1249 [ac_cv_c_ipx_gnu="yes"],
1250 [ac_cv_c_ipx_gnu="no"])
1251 )
1252 if test "$ac_cv_c_ipx_gnu" = "yes"
1253 then
1254 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1255 fi
1257 if test "$ac_cv_c_ipx_gnu" = "no"
1258 then
1259 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1260 AC_TRY_COMPILE(
1261 [#include <sys/types.h>
1262 #ifdef HAVE_SYS_SOCKET_H
1263 # include <sys/socket.h>
1264 #endif
1265 #include <asm/types.h>
1266 #include <linux/ipx.h>],
1267 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1268 [ac_cv_c_ipx_linux="yes"],
1269 [ac_cv_c_ipx_linux="no"])
1270 )
1271 if test "$ac_cv_c_ipx_linux" = "yes"
1272 then
1273 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1274 fi
1275 fi
1277 dnl **** Check for types ****
1279 AC_C_CONST
1280 AC_C_INLINE
1281 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1282 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1283 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1285 AC_CACHE_CHECK([whether linux/input.h is for real],
1286 wine_cv_linux_input_h,
1287 AC_TRY_COMPILE([
1288 #include <linux/input.h>
1289 ] , [
1290 int foo = EVIOCGBIT(EV_ABS,42);
1291 int bar = BTN_PINKIE;
1292 int fortytwo = 42;
1293 ],
1294 wine_cv_linux_input_h=yes,
1295 wine_cv_linux_input_h=no,
1296 no
1297 )
1298 )
1299 if test "$wine_cv_linux_input_h" = "yes"
1300 then
1301 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1302 [Define if we have linux/input.h AND it contains the INPUT event API])
1303 fi
1305 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1306 [#ifdef HAVE_LINUX_INPUT_H
1307 #include <linux/input.h>
1308 #endif])
1310 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1311 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1312 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1313 if test "$wine_cv_have_sigaddset" = "yes"
1314 then
1315 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1316 fi
1319 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1320 wine_cv_linux_gethostbyname_r_6,
1321 AC_TRY_LINK([
1322 #include <netdb.h>
1323 ], [
1324 char *name=NULL;
1325 struct hostent he;
1326 struct hostent *result;
1327 char *buf=NULL;
1328 int bufsize=0;
1329 int res,errnr;
1330 char *addr=NULL;
1331 int addrlen=0;
1332 int addrtype=0;
1333 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1334 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1335 ],
1336 wine_cv_linux_gethostbyname_r_6=yes,
1337 wine_cv_linux_gethostbyname_r_6=no
1338 )
1339 )
1340 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1341 then
1342 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1343 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1344 fi
1346 if test "$ac_cv_header_linux_joystick_h" = "yes"
1347 then
1348 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1349 wine_cv_linux_joystick_22_api,
1350 AC_TRY_COMPILE([
1351 #include <sys/ioctl.h>
1352 #include <linux/joystick.h>
1354 struct js_event blub;
1355 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1356 #error "no 2.2 header"
1357 #endif
1358 ],/*empty*/,
1359 wine_cv_linux_joystick_22_api=yes,
1360 wine_cv_linux_joystick_22_api=no,
1361 wine_cv_linux_joystick_22_api=no
1362 )
1363 )
1364 if test "$wine_cv_linux_joystick_22_api" = "yes"
1365 then
1366 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1367 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1368 fi
1369 fi
1371 dnl **** statfs checks ****
1373 if test "$ac_cv_header_sys_vfs_h" = "yes"
1374 then
1375 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1376 wine_cv_sys_vfs_has_statfs,
1377 AC_TRY_COMPILE([
1378 #include <sys/types.h>
1379 #ifdef HAVE_SYS_PARAM_H
1380 # include <sys/param.h>
1381 #endif
1382 #include <sys/vfs.h>
1383 ],[
1384 struct statfs stfs;
1386 memset(&stfs,0,sizeof(stfs));
1387 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1388 )
1389 )
1390 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1391 then
1392 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1393 [Define if the struct statfs is defined by <sys/vfs.h>])
1394 fi
1395 fi
1397 if test "$ac_cv_header_sys_statfs_h" = "yes"
1398 then
1399 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1400 wine_cv_sys_statfs_has_statfs,
1401 AC_TRY_COMPILE([
1402 #include <sys/types.h>
1403 #ifdef HAVE_SYS_PARAM_H
1404 # include <sys/param.h>
1405 #endif
1406 #include <sys/statfs.h>
1407 ],[
1408 struct statfs stfs;
1409 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1410 )
1411 )
1412 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1413 then
1414 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1415 [Define if the struct statfs is defined by <sys/statfs.h>])
1416 fi
1417 fi
1419 if test "$ac_cv_header_sys_mount_h" = "yes"
1420 then
1421 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1422 wine_cv_sys_mount_has_statfs,
1423 AC_TRY_COMPILE([
1424 #include <sys/types.h>
1425 #ifdef HAVE_SYS_PARAM_H
1426 # include <sys/param.h>
1427 #endif
1428 #include <sys/mount.h>
1429 ],[
1430 struct statfs stfs;
1431 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1432 )
1433 )
1434 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1435 then
1436 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1437 [Define if the struct statfs is defined by <sys/mount.h>])
1438 fi
1439 fi
1441 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1443 dnl Check for statfs members
1444 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1445 [#include <sys/types.h>
1446 #ifdef HAVE_SYS_PARAM_H
1447 # include <sys/param.h>
1448 #endif
1449 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1450 # include <sys/mount.h>
1451 #else
1452 # ifdef STATFS_DEFINED_BY_SYS_VFS
1453 # include <sys/vfs.h>
1454 # else
1455 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1456 # include <sys/statfs.h>
1457 # endif
1458 # endif
1459 #endif])
1461 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1462 [#ifdef HAVE_SYS_STATVFS_H
1463 #include <sys/statvfs.h>
1464 #endif])
1466 dnl Check for socket structure members
1467 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1468 [#include <sys/types.h>
1469 #ifdef HAVE_SYS_SOCKET_H
1470 # include <sys/socket.h>
1471 #endif
1472 #ifdef HAVE_SYS_UN_H
1473 # include <sys/un.h>
1474 #endif])
1476 dnl Check for scsireq_t and sg_io_hdr_t members
1477 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1478 [#include <sys/types.h>
1479 #ifdef HAVE_SCSI_SG_H
1480 #include <scsi/sg.h>
1481 #endif])
1483 dnl Check for siginfo_t members
1484 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1486 dnl Check for struct option
1487 AC_CHECK_MEMBERS([struct option.name],,,
1488 [#ifdef HAVE_GETOPT_H
1489 #include <getopt.h>
1490 #endif])
1492 dnl Check for stat.st_blocks
1493 AC_CHECK_MEMBERS([struct stat.st_blocks])
1495 dnl Check for the external timezone variables timezone and daylight
1496 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1497 AC_TRY_LINK([#include <time.h>],[timezone;],
1498 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1499 if test "$ac_cv_have_timezone" = "yes"
1500 then
1501 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1502 fi
1503 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1504 AC_TRY_LINK([#include <time.h>],[daylight;],
1505 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1506 if test "$ac_cv_have_daylight" = "yes"
1507 then
1508 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1509 fi
1511 dnl *** check for the need to define platform-specific symbols
1513 case $host_cpu in
1514 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1515 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1516 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1517 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1518 esac
1520 case $host_vendor in
1521 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1522 esac
1524 dnl **** Generate output files ****
1526 AH_TOP([#define __WINE_CONFIG_H])
1528 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1529 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1530 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1531 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1532 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1533 WINE_CONFIG_EXTRA_DIR(include/wine)
1534 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1536 MAKE_RULES=Make.rules
1537 AC_SUBST_FILE(MAKE_RULES)
1539 MAKE_DLL_RULES=dlls/Makedll.rules
1540 AC_SUBST_FILE(MAKE_DLL_RULES)
1542 MAKE_TEST_RULES=dlls/Maketest.rules
1543 AC_SUBST_FILE(MAKE_TEST_RULES)
1545 MAKE_LIB_RULES=libs/Makelib.rules
1546 AC_SUBST_FILE(MAKE_LIB_RULES)
1548 MAKE_PROG_RULES=programs/Makeprog.rules
1549 AC_SUBST_FILE(MAKE_PROG_RULES)
1551 AC_CONFIG_FILES([
1552 Make.rules
1553 dlls/Makedll.rules
1554 dlls/Maketest.rules
1555 libs/Makelib.rules
1556 programs/Makeprog.rules
1557 Makefile
1558 dlls/Makefile
1559 dlls/activeds/Makefile
1560 dlls/advapi32/Makefile
1561 dlls/advapi32/tests/Makefile
1562 dlls/advpack/Makefile
1563 dlls/advpack/tests/Makefile
1564 dlls/amstream/Makefile
1565 dlls/atl/Makefile
1566 dlls/avicap32/Makefile
1567 dlls/avifil32/Makefile
1568 dlls/cabinet/Makefile
1569 dlls/capi2032/Makefile
1570 dlls/cards/Makefile
1571 dlls/cfgmgr32/Makefile
1572 dlls/comcat/Makefile
1573 dlls/comctl32/Makefile
1574 dlls/comctl32/tests/Makefile
1575 dlls/commdlg/Makefile
1576 dlls/crtdll/Makefile
1577 dlls/crypt32/Makefile
1578 dlls/crypt32/tests/Makefile
1579 dlls/cryptdll/Makefile
1580 dlls/ctl3d/Makefile
1581 dlls/d3d8/Makefile
1582 dlls/d3d9/Makefile
1583 dlls/d3dim/Makefile
1584 dlls/d3drm/Makefile
1585 dlls/d3dx8/Makefile
1586 dlls/d3dxof/Makefile
1587 dlls/dbghelp/Makefile
1588 dlls/dciman32/Makefile
1589 dlls/ddraw/Makefile
1590 dlls/ddraw/tests/Makefile
1591 dlls/devenum/Makefile
1592 dlls/dinput/Makefile
1593 dlls/dinput/tests/Makefile
1594 dlls/dinput8/Makefile
1595 dlls/dmband/Makefile
1596 dlls/dmcompos/Makefile
1597 dlls/dmime/Makefile
1598 dlls/dmloader/Makefile
1599 dlls/dmscript/Makefile
1600 dlls/dmstyle/Makefile
1601 dlls/dmsynth/Makefile
1602 dlls/dmusic/Makefile
1603 dlls/dmusic32/Makefile
1604 dlls/dplay/Makefile
1605 dlls/dplayx/Makefile
1606 dlls/dpnet/Makefile
1607 dlls/dpnhpast/Makefile
1608 dlls/dsound/Makefile
1609 dlls/dsound/tests/Makefile
1610 dlls/dswave/Makefile
1611 dlls/dxdiagn/Makefile
1612 dlls/dxerr8/Makefile
1613 dlls/dxerr9/Makefile
1614 dlls/dxguid/Makefile
1615 dlls/gdi/Makefile
1616 dlls/gdi/tests/Makefile
1617 dlls/glu32/Makefile
1618 dlls/glut32/Makefile
1619 dlls/hhctrl.ocx/Makefile
1620 dlls/iccvid/Makefile
1621 dlls/icmp/Makefile
1622 dlls/ifsmgr.vxd/Makefile
1623 dlls/imagehlp/Makefile
1624 dlls/imm32/Makefile
1625 dlls/iphlpapi/Makefile
1626 dlls/iphlpapi/tests/Makefile
1627 dlls/itss/Makefile
1628 dlls/kernel/Makefile
1629 dlls/kernel/tests/Makefile
1630 dlls/lzexpand/Makefile
1631 dlls/lzexpand/tests/Makefile
1632 dlls/mapi32/Makefile
1633 dlls/mapi32/tests/Makefile
1634 dlls/midimap/Makefile
1635 dlls/mlang/Makefile
1636 dlls/mlang/tests/Makefile
1637 dlls/mmdevldr.vxd/Makefile
1638 dlls/monodebg.vxd/Makefile
1639 dlls/mpr/Makefile
1640 dlls/msacm/Makefile
1641 dlls/msacm/imaadp32/Makefile
1642 dlls/msacm/msadp32/Makefile
1643 dlls/msacm/msg711/Makefile
1644 dlls/msacm/winemp3/Makefile
1645 dlls/msacm/tests/Makefile
1646 dlls/mscms/Makefile
1647 dlls/mscms/tests/Makefile
1648 dlls/msdmo/Makefile
1649 dlls/mshtml/Makefile
1650 dlls/mshtml/tests/Makefile
1651 dlls/msi/Makefile
1652 dlls/msi/tests/Makefile
1653 dlls/msimg32/Makefile
1654 dlls/msisys/Makefile
1655 dlls/msnet32/Makefile
1656 dlls/msrle32/Makefile
1657 dlls/msvcrt/Makefile
1658 dlls/msvcrt/tests/Makefile
1659 dlls/msvcrt20/Makefile
1660 dlls/msvcrt40/Makefile
1661 dlls/msvcrtd/Makefile
1662 dlls/msvcrtd/tests/Makefile
1663 dlls/msvidc32/Makefile
1664 dlls/msvideo/Makefile
1665 dlls/mswsock/Makefile
1666 dlls/msxml3/Makefile
1667 dlls/netapi32/Makefile
1668 dlls/netapi32/tests/Makefile
1669 dlls/newdev/Makefile
1670 dlls/ntdll/Makefile
1671 dlls/ntdll/tests/Makefile
1672 dlls/objsel/Makefile
1673 dlls/odbc32/Makefile
1674 dlls/odbccp32/Makefile
1675 dlls/ole32/Makefile
1676 dlls/ole32/tests/Makefile
1677 dlls/oleacc/Makefile
1678 dlls/oleaut32/Makefile
1679 dlls/oleaut32/tests/Makefile
1680 dlls/olecli/Makefile
1681 dlls/oledlg/Makefile
1682 dlls/olepro32/Makefile
1683 dlls/olesvr/Makefile
1684 dlls/opengl32/Makefile
1685 dlls/powrprof/Makefile
1686 dlls/psapi/Makefile
1687 dlls/psapi/tests/Makefile
1688 dlls/qcap/Makefile
1689 dlls/quartz/Makefile
1690 dlls/quartz/tests/Makefile
1691 dlls/rasapi32/Makefile
1692 dlls/riched20/Makefile
1693 dlls/richedit/Makefile
1694 dlls/rpcrt4/Makefile
1695 dlls/rpcrt4/tests/Makefile
1696 dlls/rsabase/Makefile
1697 dlls/rsabase/tests/Makefile
1698 dlls/rsaenh/Makefile
1699 dlls/rsaenh/tests/Makefile
1700 dlls/secur32/Makefile
1701 dlls/sensapi/Makefile
1702 dlls/serialui/Makefile
1703 dlls/setupapi/Makefile
1704 dlls/shdocvw/Makefile
1705 dlls/shell32/Makefile
1706 dlls/shell32/tests/Makefile
1707 dlls/shfolder/Makefile
1708 dlls/shlwapi/Makefile
1709 dlls/shlwapi/tests/Makefile
1710 dlls/snmpapi/Makefile
1711 dlls/stdole2.tlb/Makefile
1712 dlls/stdole32.tlb/Makefile
1713 dlls/sti/Makefile
1714 dlls/strmiids/Makefile
1715 dlls/tapi32/Makefile
1716 dlls/ttydrv/Makefile
1717 dlls/twain/Makefile
1718 dlls/unicows/Makefile
1719 dlls/url/Makefile
1720 dlls/urlmon/Makefile
1721 dlls/urlmon/tests/Makefile
1722 dlls/user/Makefile
1723 dlls/user/tests/Makefile
1724 dlls/usp10/Makefile
1725 dlls/uuid/Makefile
1726 dlls/uxtheme/Makefile
1727 dlls/vdhcp.vxd/Makefile
1728 dlls/vdmdbg/Makefile
1729 dlls/version/Makefile
1730 dlls/version/tests/Makefile
1731 dlls/vmm.vxd/Makefile
1732 dlls/vnbt.vxd/Makefile
1733 dlls/vnetbios.vxd/Makefile
1734 dlls/vtdapi.vxd/Makefile
1735 dlls/vwin32.vxd/Makefile
1736 dlls/win32s/Makefile
1737 dlls/winaspi/Makefile
1738 dlls/wined3d/Makefile
1739 dlls/winedos/Makefile
1740 dlls/wineps/Makefile
1741 dlls/wininet/Makefile
1742 dlls/wininet/tests/Makefile
1743 dlls/winmm/Makefile
1744 dlls/winmm/joystick/Makefile
1745 dlls/winmm/mcianim/Makefile
1746 dlls/winmm/mciavi/Makefile
1747 dlls/mcicda/Makefile
1748 dlls/winmm/mciseq/Makefile
1749 dlls/winmm/mciwave/Makefile
1750 dlls/winmm/tests/Makefile
1751 dlls/winmm/wavemap/Makefile
1752 dlls/winmm/winealsa/Makefile
1753 dlls/winmm/winearts/Makefile
1754 dlls/winmm/wineaudioio/Makefile
1755 dlls/winmm/winejack/Makefile
1756 dlls/winmm/winenas/Makefile
1757 dlls/winmm/wineoss/Makefile
1758 dlls/winnls/Makefile
1759 dlls/winsock/Makefile
1760 dlls/winsock/tests/Makefile
1761 dlls/winspool/Makefile
1762 dlls/winspool/tests/Makefile
1763 dlls/wintab32/Makefile
1764 dlls/wintrust/Makefile
1765 dlls/wldap32/Makefile
1766 dlls/wow32/Makefile
1767 dlls/wsock32/Makefile
1768 dlls/wtsapi32/Makefile
1769 dlls/x11drv/Makefile
1770 documentation/Makefile
1771 fonts/Makefile
1772 include/Makefile
1773 libs/Makefile
1774 libs/port/Makefile
1775 libs/unicode/Makefile
1776 libs/wine/Makefile
1777 libs/wpp/Makefile
1778 loader/Makefile
1779 programs/Makefile
1780 programs/avitools/Makefile
1781 programs/clock/Makefile
1782 programs/cmdlgtst/Makefile
1783 programs/control/Makefile
1784 programs/expand/Makefile
1785 programs/hh/Makefile
1786 programs/msiexec/Makefile
1787 programs/notepad/Makefile
1788 programs/progman/Makefile
1789 programs/regedit/Makefile
1790 programs/regsvr32/Makefile
1791 programs/rpcss/Makefile
1792 programs/rundll32/Makefile
1793 programs/start/Makefile
1794 programs/taskmgr/Makefile
1795 programs/uninstaller/Makefile
1796 programs/view/Makefile
1797 programs/wcmd/Makefile
1798 programs/wineboot/Makefile
1799 programs/winebrowser/Makefile
1800 programs/winecfg/Makefile
1801 programs/wineconsole/Makefile
1802 programs/winedbg/Makefile
1803 programs/winefile/Makefile
1804 programs/winemenubuilder/Makefile
1805 programs/winemine/Makefile
1806 programs/winepath/Makefile
1807 programs/winetest/Makefile
1808 programs/winevdm/Makefile
1809 programs/winhelp/Makefile
1810 programs/winver/Makefile
1811 server/Makefile
1812 tools/Makefile
1813 tools/widl/Makefile
1814 tools/winapi/Makefile
1815 tools/winebuild/Makefile
1816 tools/winedump/Makefile
1817 tools/winegcc/Makefile
1818 tools/wmc/Makefile
1819 tools/wrc/Makefile])
1821 AC_OUTPUT
1823 if test "$have_x" = "no"
1824 then
1825 echo
1826 echo "*** Warning: X development files not found. Wine will be built without"
1827 echo "*** X support, which currently does not work, and would probably not be"
1828 echo "*** what you want anyway. You will need to install devel packages of"
1829 echo "*** Xlib/Xfree86 at the very least."
1830 fi
1832 if test "$wine_cv_opengl_version_OK" = "no"
1833 then
1834 echo
1835 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1836 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1837 fi
1839 if test "$wine_cv_msg_freetype" = "yes"
1840 then
1841 echo
1842 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1843 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1844 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1845 echo "*** enable Wine to use TrueType fonts."
1846 fi
1848 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1849 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1850 "$ac_cv_c_opensoundsystem" = "no"
1851 then
1852 echo "*** No sound system was found. Windows applications will be silent."
1853 echo "*** The currently supported sound systems are:"
1854 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1855 fi
1857 echo
1858 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1859 echo
1861 dnl Local Variables:
1862 dnl comment-start: "dnl "
1863 dnl comment-end: ""
1864 dnl comment-start-skip: "\\bdnl\\b\\s *"
1865 dnl compile-command: "autoconf"
1866 dnl End: