| blob | f714b3fc01859cb775e321ae122332484bb42ad5 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
138 dnl **** Check for some libraries ****
140 dnl Check for -li386 for NetBSD and OpenBSD
141 AC_CHECK_LIB(i386,i386_set_ldt)
142 dnl Check for -lossaudio for NetBSD
143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
144 dnl Check for -lw for Solaris
145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
146 dnl Check for -lnsl for Solaris
147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
148 dnl Check for -lsocket for Solaris
149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
150 dnl Check for -lresolv for Solaris
151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
152 dnl Check for -lxpg4 for FreeBSD
153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
154 dnl Check for -lpoll for Mac OS X/Darwin
155 AC_CHECK_LIB(poll,poll)
156 dnl Check for -lresolv for Mac OS X/Darwin
157 AC_CHECK_LIB(resolv,res_9_init)
158 dnl Check for -lpthread
159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
171 dnl **** Check for header files ****
173 AC_CHECK_HEADERS(\
174 arpa/inet.h \
175 arpa/nameser.h \
176 asm/types.h \
177 cups/cups.h \
178 direct.h \
179 elf.h \
180 float.h \
181 fontconfig/fontconfig.h \
182 getopt.h \
183 gif_lib.h \
184 ieeefp.h \
185 io.h \
186 jack/jack.h \
187 jpeglib.h \
188 lcms/lcms.h \
189 lcms.h \
190 link.h \
191 linux/cdrom.h \
192 linux/compiler.h \
193 linux/hdreg.h \
194 linux/input.h \
195 linux/ioctl.h \
196 linux/joystick.h \
197 linux/major.h \
198 linux/param.h \
199 linux/serial.h \
200 linux/ucdrom.h \
201 mach/machine.h \
202 machine/cpu.h \
203 machine/limits.h \
204 mntent.h \
205 netdb.h \
206 netinet/in.h \
207 netinet/in_systm.h \
208 netinet/tcp.h \
209 netinet/tcp_fsm.h \
210 openssl/ssl.h \
211 poll.h \
212 process.h \
213 pthread.h \
214 pwd.h \
215 regex.h \
216 sched.h \
217 scsi/sg.h \
218 scsi/scsi.h \
219 scsi/scsi_ioctl.h \
220 stdint.h \
221 strings.h \
222 sys/cdio.h \
223 sys/elf32.h \
224 sys/errno.h \
225 sys/epoll.h \
226 sys/exec_elf.h \
227 sys/filio.h \
228 sys/ioctl.h \
229 sys/ipc.h \
230 sys/link.h \
231 sys/lwp.h \
232 sys/mman.h \
233 sys/modem.h \
234 sys/msg.h \
235 sys/param.h \
236 sys/poll.h \
237 sys/ptrace.h \
238 sys/reg.h \
239 sys/scsiio.h \
240 sys/shm.h \
241 sys/signal.h \
242 sys/socket.h \
243 sys/sockio.h \
244 sys/statfs.h \
245 sys/statvfs.h \
246 sys/strtio.h \
247 sys/syscall.h \
248 sys/sysctl.h \
249 sys/time.h \
250 sys/times.h \
251 sys/uio.h \
252 sys/un.h \
253 sys/vfs.h \
254 sys/vm86.h \
255 sys/wait.h \
256 syscall.h \
257 termios.h \
258 unistd.h \
259 utime.h \
260 valgrind/memcheck.h
261 )
262 AC_HEADER_STAT()
264 dnl **** Check for X11 ****
266 if test "$have_x" = "yes"
267 then
268 XLIB="-lXext -lX11"
269 ac_save_CPPFLAGS="$CPPFLAGS"
270 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
272 dnl *** All of the following tests require X11/Xlib.h
273 AC_CHECK_HEADERS(X11/Xlib.h,
274 [
275 AC_CHECK_HEADERS([X11/XKBlib.h \
276 X11/Xutil.h \
277 X11/extensions/shape.h \
278 X11/extensions/XInput.h \
279 X11/extensions/XShm.h \
280 X11/extensions/Xrandr.h \
281 X11/extensions/Xrender.h \
282 X11/extensions/xf86dga.h \
283 X11/extensions/xf86vmode.h],,,
284 [#include <X11/Xlib.h>
285 #ifdef HAVE_X11_XUTIL_H
286 # include <X11/Xutil.h>
287 #endif])
289 dnl *** Check for X keyboard extension
290 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
291 then
292 AC_CHECK_LIB(X11, XkbQueryExtension,
293 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
294 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
295 fi
297 dnl *** Check for X Shm extension
298 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
299 then
300 AC_CHECK_LIB(Xext, XShmQueryExtension,
301 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
302 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
303 fi
305 dnl *** Check for X shape extension
306 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
307 then
308 AC_CHECK_LIB(Xext,XShapeQueryExtension,
309 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
310 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
311 fi
313 dnl *** Check for XFree86 DGA / DGA 2.0 extension
314 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
315 then
316 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
317 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
318 [Define if you have the Xxf86dga library version 2])
319 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
320 ],,
321 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
322 fi
324 dnl *** Check for XFree86 VMODE extension
325 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
326 then
327 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
328 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
329 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
330 ],,
331 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
332 fi
334 dnl *** Check for X RandR extension
335 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
336 then
337 AC_TRY_COMPILE([#include <X11/Xlib.h>
338 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
339 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
340 fi
342 dnl *** Check for Transform functions in Xrender
343 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
344 then
345 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
346 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
347 [Define if Xrender has the XRenderSetPictureTransform function])],,
348 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
349 fi
350 ]
351 ) dnl *** End of X11/Xlib.h check
353 dnl Check for the presence of OpenGL
354 if test "x$with_opengl" != "xno"
355 then
356 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so -a ! -f /usr/X11R6/lib/libGL.dylib
357 then
358 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
359 This prevents linking to OpenGL. Delete the file and restart configure.])
360 fi
362 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
363 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
364 then
365 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
366 dnl Check for some problems due to old Mesa versions
367 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
368 AC_TRY_COMPILE(
369 [#include <GL/gl.h>],
370 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
371 [wine_cv_opengl_version_OK="yes"],
372 [wine_cv_opengl_version_OK="no"]
373 )
374 )
376 if test "$wine_cv_opengl_version_OK" = "yes"
377 then
378 dnl Check for the presence of the library
379 AC_CHECK_LIB(GL,glXCreateContext,
380 OPENGL_LIBS="-lGL"
381 ,,
382 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
384 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
385 then
386 OPENGLFILES='$(OPENGLFILES)'
387 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
388 fi
389 dnl Check for GLU32 library.
390 AC_CHECK_LIB(GLU,gluLookAt,
391 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
392 GLU32FILES='$(GLU32FILES)']
393 ,,
394 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
395 )
396 fi
398 dnl Check for glut32 library.
399 AC_CHECK_LIB(glut,glutMainLoop,
400 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
401 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
402 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
403 fi
404 fi
406 dnl **** Check for NAS ****
407 AC_SUBST(NASLIBS,"")
408 AC_CHECK_HEADERS(audio/audiolib.h,
409 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
410 AC_CHECK_LIB(audio,AuCreateFlow,
411 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
412 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
413 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
415 CPPFLAGS="$ac_save_CPPFLAGS"
416 XFILES='$(XFILES)'
417 else
418 XLIB=""
419 X_CFLAGS=""
420 X_LIBS=""
421 fi
423 dnl **** Check which curses lib to use ***
424 CURSESLIBS=""
425 if test "x$with_curses" != "xno"
426 then
427 AC_CHECK_HEADERS(ncurses.h,
428 [AC_CHECK_LIB(ncurses,waddch,
429 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
430 CURSESLIBS="-lncurses"],
431 [AC_CHECK_HEADERS(curses.h,
432 [AC_CHECK_LIB(curses,waddch,
433 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
434 CURSESLIBS="-lcurses"])])])])
435 fi
436 AC_SUBST(CURSESLIBS)
438 dnl **** Check for SANE ****
439 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
440 if test "$sane_devel" = "no"
441 then
442 SANELIBS=""
443 SANEINCL=""
444 else
445 SANELIBS="`$sane_devel --libs`"
446 SANEINCL="`$sane_devel --cflags`"
447 ac_save_CPPFLAGS="$CPPFLAGS"
448 ac_save_LIBS="$LIBS"
449 CPPFLAGS="$CPPFLAGS $SANEINCL"
450 LIBS="$LIBS $SANELIBS"
451 AC_CHECK_HEADER(sane/sane.h,
452 [AC_CHECK_LIB(sane,sane_open,
453 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
454 [SANELIBS=""
455 SANEINCL=""])],
456 [SANELIBS=""
457 SANEINCL=""])
458 LIBS="$ac_save_LIBS"
459 CPPFLAGS="$ac_save_CPPFLAGS"
460 fi
461 AC_SUBST(SANELIBS)
462 AC_SUBST(SANEINCL)
464 dnl **** Check for the ICU library ****
465 AC_CHECK_HEADERS(unicode/ubidi.h)
466 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
467 then
468 saved_libs="$LIBS"
469 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
470 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
471 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
472 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
473 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
474 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
475 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
476 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
477 AC_MSG_RESULT(yes)],
478 [AC_MSG_RESULT(no)])
479 LIBS="$saved_libs"
480 fi
482 dnl **** Check for FreeType 2 ****
483 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
484 if test "$ft_lib" = "no"
485 then
486 FREETYPELIBS=""
487 FREETYPEINCL=""
488 wine_cv_msg_freetype=no
489 else
490 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
491 if test "$ft_devel" = "no"
492 then
493 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
494 if test "$ft_devel2" = "freetype2-config"
495 then
496 ft_devel=$ft_devel2
497 fi
498 fi
499 if test "$ft_devel" = "no"
500 then
501 FREETYPELIBS=""
502 FREETYPEINCL=""
503 wine_cv_msg_freetype=yes
504 else
505 FREETYPELIBS=`$ft_devel --libs`
506 FREETYPEINCL=`$ft_devel --cflags`
507 ac_save_CPPFLAGS="$CPPFLAGS"
508 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
509 AC_CHECK_HEADERS(ft2build.h \
510 freetype/freetype.h \
511 freetype/ftglyph.h \
512 freetype/tttables.h \
513 freetype/ftnames.h \
514 freetype/ftsnames.h \
515 freetype/ttnameid.h \
516 freetype/ftoutln.h \
517 freetype/ftwinfnt.h \
518 freetype/internal/sfnt.h,,,
519 [#if HAVE_FT2BUILD_H
520 #include <ft2build.h>
521 #endif])
522 AC_TRY_CPP([#include <ft2build.h>
523 #include <freetype/fttrigon.h>],
524 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
525 [Define if you have the <freetype/fttrigon.h> header file.])
526 wine_cv_fttrigon=yes],
527 wine_cv_fttrigon=no)
528 CPPFLAGS="$ac_save_CPPFLAGS"
529 dnl Check that we have at least freetype/freetype.h
530 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
531 then
532 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
533 wine_cv_msg_freetype=no
534 else
535 FREETYPELIBS=""
536 FREETYPEINCL=""
537 wine_cv_msg_freetype=yes
538 fi
539 fi
540 fi
541 AC_SUBST(FREETYPELIBS)
542 AC_SUBST(FREETYPEINCL)
544 dnl Only build the fonts dir if we have both freetype and fontforge
545 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
546 then
547 AC_SUBST(FONTSSUBDIRS,"fonts")
548 fi
550 dnl **** Check for parport (currently Linux only) ****
551 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
552 AC_TRY_COMPILE(
553 [#include <linux/ppdev.h>],
554 [ioctl (1,PPCLAIM,0)],
555 [ac_cv_c_ppdev="yes"],
556 [ac_cv_c_ppdev="no"])
557 )
558 if test "$ac_cv_c_ppdev" = "yes"
559 then
560 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
561 fi
563 dnl **** Check for va_copy ****
564 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
565 AC_TRY_LINK(
566 [#include <stdarg.h>],
567 [va_list ap1, ap2;
568 va_copy(ap1,ap2);
569 ],
570 [ac_cv_c_va_copy="yes"],
571 [ac_cv_c_va_copy="no"])
572 )
573 if test "$ac_cv_c_va_copy" = "yes"
574 then
575 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
576 fi
577 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
578 AC_TRY_LINK(
579 [#include <stdarg.h>],
580 [va_list ap1, ap2;
581 __va_copy(ap1,ap2);
582 ],
583 [ac_cv_c___va_copy="yes"],
584 [ac_cv_c___va_copy="no"])
585 )
586 if test "$ac_cv_c___va_copy" = "yes"
587 then
588 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
589 fi
591 dnl **** Check for sigsetjmp ****
592 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
593 AC_TRY_LINK(
594 [#include <setjmp.h>],
595 [sigjmp_buf buf;
596 sigsetjmp( buf, 1 );
597 siglongjmp( buf, 1 );],
598 [ac_cv_c_sigsetjmp="yes"],
599 [ac_cv_c_sigsetjmp="no"])
600 )
601 if test "$ac_cv_c_sigsetjmp" = "yes"
602 then
603 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
604 fi
606 dnl **** Check for pthread_rwlock_t ****
607 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
608 #include <pthread.h>])
610 dnl **** Check for pthread functions ****
611 ac_save_LIBS="$LIBS"
612 LIBS="$LIBS $LIBPTHREAD"
613 AC_CHECK_FUNCS(\
614 pthread_getattr_np \
615 pthread_get_stackaddr_np \
616 pthread_get_stacksize_np \
617 )
618 LIBS="$ac_save_LIBS"
620 dnl **** Check for Open Sound System ****
621 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
623 AC_CACHE_CHECK([for Open Sound System],
624 ac_cv_c_opensoundsystem,
625 AC_TRY_COMPILE([
626 #if defined(HAVE_SYS_SOUNDCARD_H)
627 #include <sys/soundcard.h>
628 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
629 #include <machine/soundcard.h>
630 #elif defined(HAVE_SOUNDCARD_H)
631 #include <soundcard.h>
632 #endif
633 ],[
635 /* check for one of the Open Sound System specific SNDCTL_ defines */
636 #if !defined(SNDCTL_DSP_STEREO)
637 #error No open sound system
638 #endif
639 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
641 if test "$ac_cv_c_opensoundsystem" = "yes"
642 then
643 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
644 fi
646 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
647 ac_cv_c_opensoundsystem_midi,
648 AC_TRY_COMPILE([
649 #if defined(HAVE_SYS_SOUNDCARD_H)
650 #include <sys/soundcard.h>
651 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
652 #include <machine/soundcard.h>
653 #elif defined(HAVE_SOUNDCARD_H)
654 #include <soundcard.h>
655 #endif
656 ],[
658 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
659 #if !defined(SNDCTL_SEQ_SYNC)
660 #error No open sound system MIDI interface
661 #endif
662 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
664 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
665 then
666 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
667 fi
669 dnl **** Check for aRts Sound Server ****
670 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
671 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
672 then
673 ARTSC_CFLAGS=""
674 for i in `$ARTSCCONFIG --cflags`
675 do
676 case "$i" in
677 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
678 esac
679 done
680 ARTSC_LIBS=`$ARTSCCONFIG --libs`
681 save_CFLAGS="$CFLAGS"
682 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
683 AC_CHECK_LIB(artsc,arts_init,
684 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
685 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
686 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
687 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],)
688 CFLAGS="$save_CFLAGS"
689 fi
691 dnl **** Check for ALSA 1.x ****
692 AC_SUBST(ALSALIBS,"")
693 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
694 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
695 then
696 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
697 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
698 #include <alsa/asoundlib.h>
699 #elif defined(HAVE_SYS_ASOUNDLIB_H)
700 #include <sys/asoundlib.h>
701 #endif],
702 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
703 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
704 ALSALIBS="-lasound"])])
705 fi
707 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
709 AC_SUBST(AUDIOIOLIBS,"")
710 AC_CHECK_HEADERS(libaudioio.h,
711 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
712 [AUDIOIOLIBS="-laudioio"
713 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
715 dnl **** Check for capi4linux ****
717 AC_CHECK_HEADERS(capi20.h,[
718 AC_CHECK_HEADERS(linux/capi.h,[
719 AC_CHECK_LIB(capi20,capi20_register,[
720 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
721 ])
722 ])
723 ])
725 dnl **** Check for broken glibc mmap64 ****
727 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
728 AC_TRY_RUN([
729 #define _FILE_OFFSET_BITS 64
730 #include <stdio.h>
731 #include <unistd.h>
732 #include <fcntl.h>
733 #include <sys/mman.h>
734 #include <errno.h>
736 int main(int argc,char **argv) {
737 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
738 if (fd == -1) exit(1);
740 unlink("conftest.map");
742 write(fd,"test",4);
744 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
745 (errno == EINVAL)
746 ) {
747 exit(1);
748 }
749 close(fd);
750 fprintf(stderr,"success!\n");
751 exit(0);
752 }
754 ],
755 ac_cv_mmap64_works="yes",
756 ac_cv_mmap64_works="no",
757 ac_cv_mmap64_works="no") )
759 if test "$ac_cv_mmap64_works" = "yes"
760 then
761 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
762 fi
764 dnl **** Check for gcc specific options ****
766 AC_SUBST(EXTRACFLAGS,"")
767 if test "x${GCC}" = "xyes"
768 then
769 EXTRACFLAGS="-Wall -pipe"
771 dnl Check for strength-reduce bug
772 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
773 AC_TRY_RUN([
774 int L[[4]] = {0,1,2,3};
775 int main(void) {
776 static int Array[[3]];
777 unsigned int B = 3;
778 int i;
779 for(i=0; i<B; i++) Array[[i]] = i - 3;
780 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
781 L[[i]] = 4;
783 exit( Array[[1]] != -2 || L[[2]] != 3);
784 }],
785 ac_cv_c_gcc_strength_bug="no",
786 ac_cv_c_gcc_strength_bug="yes",
787 ac_cv_c_gcc_strength_bug="yes") )
788 if test "$ac_cv_c_gcc_strength_bug" = "yes"
789 then
790 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
791 fi
793 dnl Check for -fshort-wchar
794 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
795 [WINE_TRY_CFLAGS([-fshort-wchar],
796 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
797 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
798 then
799 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
800 fi
802 dnl Check for -mpreferred-stack-boundary
803 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
804 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
805 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
806 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
807 then
808 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
809 fi
811 dnl Check for -fno-strict-aliasing
812 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
813 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
814 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
815 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
816 then
817 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
818 fi
820 dnl Check for -gstabs+ option
821 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
822 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
823 if test "$ac_cv_c_gcc_gstabs" = "yes"
824 then
825 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
826 fi
828 dnl Check for noisy string.h
829 saved_CFLAGS="$CFLAGS"
830 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
831 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
832 AC_TRY_COMPILE([#include <string.h>],[],
833 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
834 CFLAGS="$saved_CFLAGS"
835 if test "$ac_cv_c_string_h_warnings" = "no"
836 then
837 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
838 fi
839 fi
841 dnl **** Check how to define a function in assembly code ****
843 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
844 WINE_TRY_ASM_LINK(
845 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
846 ac_cv_asm_func_def=".def",
847 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
848 ac_cv_asm_func_def=".type @function",
849 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
850 ac_cv_asm_func_def=".type 2",
851 ac_cv_asm_func_def="unknown")])]))
853 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
854 case "$ac_cv_asm_func_def" in
855 ".def")
856 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
857 ".type @function")
858 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
859 ".type 2")
860 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
861 *)
862 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
863 esac
865 dnl **** Check for underscore on external symbols ****
867 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
868 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
869 [extern int ac_test;],
870 [if (ac_test) return 1],
871 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
873 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
874 if test "$ac_cv_c_extern_prefix" = "yes"
875 then
876 AC_DEFINE([__ASM_NAME(name)], ["_" name])
877 else
878 AC_DEFINE([__ASM_NAME(name)], [name])
879 fi
881 dnl **** Check for working dll ****
883 AC_SUBST(DLLEXT,"")
884 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
885 AC_SUBST(DLLIBS,"")
886 AC_SUBST(LDSHARED,"")
887 AC_SUBST(LDDLLFLAGS,"")
888 AC_SUBST(LIBEXT,"so")
889 AC_SUBST(IMPLIBEXT,"def")
891 case $host_os in
892 cygwin*|mingw32*)
893 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
894 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
895 if test "$DLLWRAP" = "false"; then
896 LIBEXT="a"
897 else
898 dnl FIXME - check whether dllwrap works correctly...
899 LIBEXT="dll"
900 fi
901 IMPLIBEXT="a"
902 dnl We can't build 16-bit NE dlls
903 WIN16_FILES=""
904 WIN16_INSTALL=""
905 ;;
906 *)
907 AC_CHECK_HEADERS(dlfcn.h,
908 [AC_CHECK_FUNCS(dlopen,,
909 [AC_CHECK_LIB(dl,dlopen,
910 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
911 DLLIBS="-ldl"],
912 [LIBEXT="a"])])],
913 [LIBEXT="a"])
915 if test "$LIBEXT" = "so"
916 then
917 DLLFLAGS="$DLLFLAGS -fPIC"
918 DLLEXT=".so"
919 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
920 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
921 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
922 if test "$ac_cv_c_dll_gnuelf" = "yes"
923 then
924 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
925 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
926 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
927 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
928 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
929 if test "$ac_cv_c_dll_zdefs" = "yes"
930 then
931 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
932 fi
934 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
935 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
936 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
937 if test "$ac_cv_c_dll_init_fini" = "yes"
938 then
939 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
940 fi
942 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
943 [echo '{ global: *; };' >conftest.map
944 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
945 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
946 rm -f conftest.map])
947 if test "$ac_cv_c_ld_version_scripts" = "yes"
948 then
949 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
950 fi
952 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
953 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
954 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
955 if test "$ac_cv_c_export_dynamic" = "yes"
956 then
957 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
958 fi
960 case $host_cpu in
961 *i[[3456789]]86*)
962 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
963 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
964 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
965 if test "$ac_cv_ld_reloc_exec" = "yes"
966 then
967 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
968 fi
969 ;;
970 esac
972 else
973 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
974 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
975 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
976 if test "$ac_cv_c_dll_unixware" = "yes"
977 then
978 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
979 LDDLLFLAGS="-Wl,-G,-B,symbolic"
981 else
982 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
983 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
984 if test "$ac_cv_c_dll_macho" = "yes"
985 then
986 LIBEXT="dylib"
987 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
988 LDSHARED="\$(CC) -dynamiclib"
989 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
990 STRIP="$STRIP -u -r"
991 dnl Relocate wine executable
992 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
993 dnl Relocate libwine.dyld too
994 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
995 dnl declare needed frameworks
996 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
997 AC_SUBST(IOKITLIB,"-framework IOKit")
998 dnl using IOKit imply we use CoreFoundation too
999 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1000 else
1001 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1002 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1003 if test "$ac_cv_c_dll_hpux" = "yes"
1004 then
1005 LIBEXT="sl"
1006 DLLEXT=".sl"
1007 LDDLLFLAGS="-shared -fPIC"
1008 LDSHARED="\$(CC) -shared"
1009 fi
1010 fi
1011 fi
1012 fi
1013 fi
1015 dnl Check for cross compiler to build test programs
1016 AC_SUBST(CROSSTEST,"")
1017 if test "$cross_compiling" = "no"
1018 then
1019 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1020 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1021 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1022 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1023 fi
1024 ;;
1025 esac
1027 if test "$LIBEXT" = "a"; then
1028 AC_MSG_ERROR(
1029 [could not find a way to build shared libraries.
1030 It is currently not possible to build Wine without shared library
1031 (.so) support to allow transparent switch between .so and .dll files.
1032 If you are using Linux, you will need a newer binutils.]
1033 )
1034 fi
1036 case $build_os in
1037 cygwin*|mingw32*)
1038 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1039 darwin*|macosx*)
1040 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1041 *)
1042 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1043 esac
1045 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1046 case $host_os in
1047 mingw32*)
1048 AC_SUBST(CRTLIBS,"-lmsvcrt")
1049 AC_SUBST(SOCKETLIBS,"-lws2_32")
1050 ;;
1051 esac
1053 case $host_os in
1054 linux*)
1055 case $host_cpu in
1056 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1057 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1058 esac
1059 AC_SUBST(MAIN_BINARY,"wine-glibc")
1060 ;;
1061 darwin*)
1062 AC_SUBST(WINE_BINARIES,"wine-pthread")
1063 AC_SUBST(MAIN_BINARY,"wine-pthread")
1064 ;;
1065 *)
1066 AC_SUBST(WINE_BINARIES,"wine-kthread")
1067 AC_SUBST(MAIN_BINARY,"wine-kthread")
1068 ;;
1069 esac
1071 dnl **** Get the soname for libraries that we load dynamically ****
1073 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1074 then
1075 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1076 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1077 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1078 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1079 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1080 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1081 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1082 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1083 WINE_GET_SONAME(cups,cupsGetDefault)
1084 WINE_GET_SONAME(jack,jack_client_new)
1085 WINE_GET_SONAME(fontconfig,FcInit)
1086 WINE_GET_SONAME(ssl,SSL_library_init)
1087 WINE_GET_SONAME(crypto,BIO_new_socket)
1088 WINE_GET_SONAME(ncurses,waddch)
1089 WINE_GET_SONAME(curses,waddch)
1090 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1091 WINE_GET_SONAME(ungif,DGifOpen)
1092 WINE_GET_SONAME(gif,DGifOpen)
1093 WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1094 WINE_GET_SONAME(capi20,capi20_isinstalled)
1095 fi
1098 dnl **** Check for functions ****
1100 AC_FUNC_ALLOCA()
1101 AC_CHECK_FUNCS(\
1102 _lwp_create \
1103 _lwp_self \
1104 _pclose \
1105 _popen \
1106 _snprintf \
1107 _spawnvp \
1108 _stricmp \
1109 _strnicmp \
1110 _vsnprintf \
1111 chsize \
1112 clone \
1113 epoll_create \
1114 ffs \
1115 finite \
1116 fork \
1117 fpclass \
1118 fstatfs \
1119 fstatvfs \
1120 ftruncate \
1121 futimes \
1122 futimesat \
1123 getnetbyname \
1124 getopt_long \
1125 getpagesize \
1126 getprotobyname \
1127 getprotobynumber \
1128 getpwuid \
1129 getservbyport \
1130 gettid \
1131 gettimeofday \
1132 getuid \
1133 inet_network \
1134 lstat \
1135 memmove \
1136 mmap \
1137 pclose \
1138 popen \
1139 pread \
1140 pwrite \
1141 readlink \
1142 rfork \
1143 sched_yield \
1144 select \
1145 sendmsg \
1146 settimeofday \
1147 sigaltstack \
1148 sigprocmask \
1149 snprintf \
1150 spawnvp \
1151 statfs \
1152 statvfs \
1153 strcasecmp \
1154 strerror \
1155 strncasecmp \
1156 tcgetattr \
1157 timegm \
1158 usleep \
1159 vsnprintf \
1160 wait4 \
1161 waitpid \
1162 )
1164 dnl **** Checks for headers that depend on other ones ****
1166 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1167 [#include <sys/types.h>
1168 #if HAVE_SYS_PARAM_H
1169 # include <sys/param.h>
1170 #endif])
1172 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1173 [#include <sys/types.h>
1174 #if HAVE_SYS_SOCKET_H
1175 # include <sys/socket.h>
1176 #endif])
1178 AC_CHECK_HEADERS([resolv.h],,,
1179 [#include <sys/types.h>
1180 #if HAVE_SYS_SOCKET_H
1181 # include <sys/socket.h>
1182 #endif
1183 #if HAVE_NETINET_IN_H
1184 # include <netinet/in.h>
1185 #endif
1186 #if HAVE_ARPA_NAMESER_H
1187 # include <arpa/nameser.h>
1188 #endif])
1190 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1192 dnl **** Check for v4l(2) headers ****
1194 AC_CHECK_HEADERS(linux/videodev.h,,,
1195 [#ifdef HAVE_SYS_TIME_H
1196 #include <sys/time.h>
1197 #endif
1198 #include <sys/types.h>
1199 #ifdef HAVE_ASM_TYPES_H
1200 #include <asm/types.h>
1201 #endif])
1203 dnl **** Check for IPX headers (currently Linux only) ****
1205 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1206 AC_TRY_COMPILE(
1207 [#include <sys/types.h>
1208 #ifdef HAVE_SYS_SOCKET_H
1209 # include <sys/socket.h>
1210 #endif
1211 #include <netipx/ipx.h>],
1212 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1213 [ac_cv_c_ipx_gnu="yes"],
1214 [ac_cv_c_ipx_gnu="no"])
1215 )
1216 if test "$ac_cv_c_ipx_gnu" = "yes"
1217 then
1218 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1219 fi
1221 if test "$ac_cv_c_ipx_gnu" = "no"
1222 then
1223 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1224 AC_TRY_COMPILE(
1225 [#include <sys/types.h>
1226 #ifdef HAVE_SYS_SOCKET_H
1227 # include <sys/socket.h>
1228 #endif
1229 #include <asm/types.h>
1230 #include <linux/ipx.h>],
1231 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1232 [ac_cv_c_ipx_linux="yes"],
1233 [ac_cv_c_ipx_linux="no"])
1234 )
1235 if test "$ac_cv_c_ipx_linux" = "yes"
1236 then
1237 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1238 fi
1239 fi
1241 dnl **** Check for types ****
1243 AC_C_CONST
1244 AC_C_INLINE
1245 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1246 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1248 AC_CACHE_CHECK([whether linux/input.h is for real],
1249 wine_cv_linux_input_h,
1250 AC_TRY_COMPILE([
1251 #include <linux/input.h>
1252 ] , [
1253 int foo = EVIOCGBIT(EV_ABS,42);
1254 int bar = BTN_PINKIE;
1255 int fortytwo = 42;
1256 ],
1257 wine_cv_linux_input_h=yes,
1258 wine_cv_linux_input_h=no,
1259 no
1260 )
1261 )
1262 if test "$wine_cv_linux_input_h" = "yes"
1263 then
1264 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1265 [Define if we have linux/input.h AND it contains the INPUT event API])
1266 fi
1268 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1269 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1270 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1271 if test "$wine_cv_have_sigaddset" = "yes"
1272 then
1273 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1274 fi
1277 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1278 wine_cv_linux_gethostbyname_r_6,
1279 AC_TRY_LINK([
1280 #include <netdb.h>
1281 ], [
1282 char *name=NULL;
1283 struct hostent he;
1284 struct hostent *result;
1285 char *buf=NULL;
1286 int bufsize=0;
1287 int res,errnr;
1288 char *addr=NULL;
1289 int addrlen=0;
1290 int addrtype=0;
1291 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1292 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1293 ],
1294 wine_cv_linux_gethostbyname_r_6=yes,
1295 wine_cv_linux_gethostbyname_r_6=no
1296 )
1297 )
1298 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1299 then
1300 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1301 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1302 fi
1304 if test "$ac_cv_header_linux_joystick_h" = "yes"
1305 then
1306 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1307 wine_cv_linux_joystick_22_api,
1308 AC_TRY_COMPILE([
1309 #include <sys/ioctl.h>
1310 #include <linux/joystick.h>
1312 struct js_event blub;
1313 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1314 #error "no 2.2 header"
1315 #endif
1316 ],/*empty*/,
1317 wine_cv_linux_joystick_22_api=yes,
1318 wine_cv_linux_joystick_22_api=no,
1319 wine_cv_linux_joystick_22_api=no
1320 )
1321 )
1322 if test "$wine_cv_linux_joystick_22_api" = "yes"
1323 then
1324 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1325 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1326 fi
1327 fi
1329 dnl **** statfs checks ****
1331 if test "$ac_cv_header_sys_vfs_h" = "yes"
1332 then
1333 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1334 wine_cv_sys_vfs_has_statfs,
1335 AC_TRY_COMPILE([
1336 #include <sys/types.h>
1337 #ifdef HAVE_SYS_PARAM_H
1338 # include <sys/param.h>
1339 #endif
1340 #include <sys/vfs.h>
1341 ],[
1342 struct statfs stfs;
1344 memset(&stfs,0,sizeof(stfs));
1345 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1346 )
1347 )
1348 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1349 then
1350 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1351 [Define if the struct statfs is defined by <sys/vfs.h>])
1352 fi
1353 fi
1355 if test "$ac_cv_header_sys_statfs_h" = "yes"
1356 then
1357 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1358 wine_cv_sys_statfs_has_statfs,
1359 AC_TRY_COMPILE([
1360 #include <sys/types.h>
1361 #ifdef HAVE_SYS_PARAM_H
1362 # include <sys/param.h>
1363 #endif
1364 #include <sys/statfs.h>
1365 ],[
1366 struct statfs stfs;
1367 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1368 )
1369 )
1370 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1371 then
1372 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1373 [Define if the struct statfs is defined by <sys/statfs.h>])
1374 fi
1375 fi
1377 if test "$ac_cv_header_sys_mount_h" = "yes"
1378 then
1379 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1380 wine_cv_sys_mount_has_statfs,
1381 AC_TRY_COMPILE([
1382 #include <sys/types.h>
1383 #ifdef HAVE_SYS_PARAM_H
1384 # include <sys/param.h>
1385 #endif
1386 #include <sys/mount.h>
1387 ],[
1388 struct statfs stfs;
1389 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1390 )
1391 )
1392 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1393 then
1394 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1395 [Define if the struct statfs is defined by <sys/mount.h>])
1396 fi
1397 fi
1399 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1401 dnl Check for statfs members
1402 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1403 [#include <sys/types.h>
1404 #ifdef HAVE_SYS_PARAM_H
1405 # include <sys/param.h>
1406 #endif
1407 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1408 # include <sys/mount.h>
1409 #else
1410 # ifdef STATFS_DEFINED_BY_SYS_VFS
1411 # include <sys/vfs.h>
1412 # else
1413 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1414 # include <sys/statfs.h>
1415 # endif
1416 # endif
1417 #endif])
1419 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1420 [#ifdef HAVE_SYS_STATVFS_H
1421 #include <sys/statvfs.h>
1422 #endif])
1424 dnl Check for socket structure members
1425 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_SOCKET_H
1428 # include <sys/socket.h>
1429 #endif
1430 #ifdef HAVE_SYS_UN_H
1431 # include <sys/un.h>
1432 #endif])
1434 dnl Check for scsireq_t and sg_io_hdr_t members
1435 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1436 [#include <sys/types.h>
1437 #ifdef HAVE_SCSI_SG_H
1438 #include <scsi/sg.h>
1439 #endif])
1441 dnl Check for siginfo_t members
1442 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1444 dnl Check for struct option
1445 AC_CHECK_MEMBERS([struct option.name],,,
1446 [#ifdef HAVE_GETOPT_H
1447 #include <getopt.h>
1448 #endif])
1450 dnl Check for stat.st_blocks
1451 AC_CHECK_MEMBERS([struct stat.st_blocks])
1453 dnl Check for the external timezone variables timezone and daylight
1454 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1455 AC_TRY_LINK([#include <time.h>],[timezone;],
1456 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1457 if test "$ac_cv_have_timezone" = "yes"
1458 then
1459 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1460 fi
1461 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1462 AC_TRY_LINK([#include <time.h>],[daylight;],
1463 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1464 if test "$ac_cv_have_daylight" = "yes"
1465 then
1466 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1467 fi
1469 dnl *** check for the need to define platform-specific symbols
1471 case $host_cpu in
1472 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1473 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1474 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1475 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1476 esac
1478 case $host_vendor in
1479 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1480 esac
1482 dnl **** Generate output files ****
1484 AH_TOP([#define __WINE_CONFIG_H])
1486 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1487 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1488 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1489 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1490 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1491 WINE_CONFIG_EXTRA_DIR(include/wine)
1492 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1494 MAKE_RULES=Make.rules
1495 AC_SUBST_FILE(MAKE_RULES)
1497 MAKE_DLL_RULES=dlls/Makedll.rules
1498 AC_SUBST_FILE(MAKE_DLL_RULES)
1500 MAKE_TEST_RULES=dlls/Maketest.rules
1501 AC_SUBST_FILE(MAKE_TEST_RULES)
1503 MAKE_LIB_RULES=libs/Makelib.rules
1504 AC_SUBST_FILE(MAKE_LIB_RULES)
1506 MAKE_PROG_RULES=programs/Makeprog.rules
1507 AC_SUBST_FILE(MAKE_PROG_RULES)
1509 AC_CONFIG_FILES([
1510 Make.rules
1511 dlls/Makedll.rules
1512 dlls/Maketest.rules
1513 libs/Makelib.rules
1514 programs/Makeprog.rules
1515 Makefile
1516 dlls/Makefile
1517 dlls/activeds/Makefile
1518 dlls/advapi32/Makefile
1519 dlls/advapi32/tests/Makefile
1520 dlls/advpack/Makefile
1521 dlls/advpack/tests/Makefile
1522 dlls/amstream/Makefile
1523 dlls/atl/Makefile
1524 dlls/avicap32/Makefile
1525 dlls/avifil32/Makefile
1526 dlls/cabinet/Makefile
1527 dlls/capi2032/Makefile
1528 dlls/cards/Makefile
1529 dlls/cfgmgr32/Makefile
1530 dlls/comcat/Makefile
1531 dlls/comctl32/Makefile
1532 dlls/comctl32/tests/Makefile
1533 dlls/commdlg/Makefile
1534 dlls/crtdll/Makefile
1535 dlls/crypt32/Makefile
1536 dlls/crypt32/tests/Makefile
1537 dlls/cryptdll/Makefile
1538 dlls/ctl3d/Makefile
1539 dlls/d3d8/Makefile
1540 dlls/d3d9/Makefile
1541 dlls/d3dim/Makefile
1542 dlls/d3drm/Makefile
1543 dlls/d3dx8/Makefile
1544 dlls/d3dxof/Makefile
1545 dlls/dbghelp/Makefile
1546 dlls/dciman32/Makefile
1547 dlls/ddraw/Makefile
1548 dlls/ddraw/tests/Makefile
1549 dlls/devenum/Makefile
1550 dlls/dinput/Makefile
1551 dlls/dinput/tests/Makefile
1552 dlls/dinput8/Makefile
1553 dlls/dmband/Makefile
1554 dlls/dmcompos/Makefile
1555 dlls/dmime/Makefile
1556 dlls/dmloader/Makefile
1557 dlls/dmscript/Makefile
1558 dlls/dmstyle/Makefile
1559 dlls/dmsynth/Makefile
1560 dlls/dmusic/Makefile
1561 dlls/dmusic32/Makefile
1562 dlls/dplay/Makefile
1563 dlls/dplayx/Makefile
1564 dlls/dpnet/Makefile
1565 dlls/dpnhpast/Makefile
1566 dlls/dsound/Makefile
1567 dlls/dsound/tests/Makefile
1568 dlls/dswave/Makefile
1569 dlls/dxdiagn/Makefile
1570 dlls/dxerr8/Makefile
1571 dlls/dxerr9/Makefile
1572 dlls/dxguid/Makefile
1573 dlls/gdi/Makefile
1574 dlls/gdi/tests/Makefile
1575 dlls/glu32/Makefile
1576 dlls/glut32/Makefile
1577 dlls/hhctrl.ocx/Makefile
1578 dlls/iccvid/Makefile
1579 dlls/icmp/Makefile
1580 dlls/ifsmgr.vxd/Makefile
1581 dlls/imagehlp/Makefile
1582 dlls/imm32/Makefile
1583 dlls/iphlpapi/Makefile
1584 dlls/iphlpapi/tests/Makefile
1585 dlls/itss/Makefile
1586 dlls/kernel/Makefile
1587 dlls/kernel/tests/Makefile
1588 dlls/lzexpand/Makefile
1589 dlls/lzexpand/tests/Makefile
1590 dlls/mapi32/Makefile
1591 dlls/mapi32/tests/Makefile
1592 dlls/mlang/Makefile
1593 dlls/mlang/tests/Makefile
1594 dlls/mmdevldr.vxd/Makefile
1595 dlls/monodebg.vxd/Makefile
1596 dlls/mpr/Makefile
1597 dlls/msacm/Makefile
1598 dlls/msacm/imaadp32/Makefile
1599 dlls/msacm/msadp32/Makefile
1600 dlls/msacm/msg711/Makefile
1601 dlls/msacm/winemp3/Makefile
1602 dlls/msacm/tests/Makefile
1603 dlls/mscms/Makefile
1604 dlls/mscms/tests/Makefile
1605 dlls/msdmo/Makefile
1606 dlls/mshtml/Makefile
1607 dlls/mshtml/tests/Makefile
1608 dlls/msi/Makefile
1609 dlls/msi/tests/Makefile
1610 dlls/msimg32/Makefile
1611 dlls/msisys/Makefile
1612 dlls/msnet32/Makefile
1613 dlls/msrle32/Makefile
1614 dlls/msvcrt/Makefile
1615 dlls/msvcrt/tests/Makefile
1616 dlls/msvcrt20/Makefile
1617 dlls/msvcrt40/Makefile
1618 dlls/msvcrtd/Makefile
1619 dlls/msvcrtd/tests/Makefile
1620 dlls/msvidc32/Makefile
1621 dlls/msvideo/Makefile
1622 dlls/mswsock/Makefile
1623 dlls/netapi32/Makefile
1624 dlls/netapi32/tests/Makefile
1625 dlls/newdev/Makefile
1626 dlls/ntdll/Makefile
1627 dlls/ntdll/tests/Makefile
1628 dlls/odbc32/Makefile
1629 dlls/odbccp32/Makefile
1630 dlls/ole32/Makefile
1631 dlls/ole32/tests/Makefile
1632 dlls/oleacc/Makefile
1633 dlls/oleaut32/Makefile
1634 dlls/oleaut32/tests/Makefile
1635 dlls/olecli/Makefile
1636 dlls/oledlg/Makefile
1637 dlls/olepro32/Makefile
1638 dlls/olesvr/Makefile
1639 dlls/opengl32/Makefile
1640 dlls/powrprof/Makefile
1641 dlls/psapi/Makefile
1642 dlls/psapi/tests/Makefile
1643 dlls/qcap/Makefile
1644 dlls/quartz/Makefile
1645 dlls/quartz/tests/Makefile
1646 dlls/rasapi32/Makefile
1647 dlls/riched20/Makefile
1648 dlls/richedit/Makefile
1649 dlls/rpcrt4/Makefile
1650 dlls/rpcrt4/tests/Makefile
1651 dlls/rsabase/Makefile
1652 dlls/rsabase/tests/Makefile
1653 dlls/rsaenh/Makefile
1654 dlls/rsaenh/tests/Makefile
1655 dlls/secur32/Makefile
1656 dlls/sensapi/Makefile
1657 dlls/serialui/Makefile
1658 dlls/setupapi/Makefile
1659 dlls/shdocvw/Makefile
1660 dlls/shell32/Makefile
1661 dlls/shell32/tests/Makefile
1662 dlls/shfolder/Makefile
1663 dlls/shlwapi/Makefile
1664 dlls/shlwapi/tests/Makefile
1665 dlls/snmpapi/Makefile
1666 dlls/stdole32.tlb/Makefile
1667 dlls/sti/Makefile
1668 dlls/strmiids/Makefile
1669 dlls/tapi32/Makefile
1670 dlls/ttydrv/Makefile
1671 dlls/twain/Makefile
1672 dlls/unicows/Makefile
1673 dlls/url/Makefile
1674 dlls/urlmon/Makefile
1675 dlls/urlmon/tests/Makefile
1676 dlls/user/Makefile
1677 dlls/user/tests/Makefile
1678 dlls/uuid/Makefile
1679 dlls/uxtheme/Makefile
1680 dlls/vdhcp.vxd/Makefile
1681 dlls/vdmdbg/Makefile
1682 dlls/version/Makefile
1683 dlls/version/tests/Makefile
1684 dlls/vmm.vxd/Makefile
1685 dlls/vnbt.vxd/Makefile
1686 dlls/vnetbios.vxd/Makefile
1687 dlls/vtdapi.vxd/Makefile
1688 dlls/vwin32.vxd/Makefile
1689 dlls/win32s/Makefile
1690 dlls/winaspi/Makefile
1691 dlls/wined3d/Makefile
1692 dlls/winedos/Makefile
1693 dlls/wineps/Makefile
1694 dlls/wininet/Makefile
1695 dlls/wininet/tests/Makefile
1696 dlls/winmm/Makefile
1697 dlls/winmm/joystick/Makefile
1698 dlls/winmm/mcianim/Makefile
1699 dlls/winmm/mciavi/Makefile
1700 dlls/winmm/mcicda/Makefile
1701 dlls/winmm/mciseq/Makefile
1702 dlls/winmm/mciwave/Makefile
1703 dlls/winmm/midimap/Makefile
1704 dlls/winmm/tests/Makefile
1705 dlls/winmm/wavemap/Makefile
1706 dlls/winmm/winealsa/Makefile
1707 dlls/winmm/winearts/Makefile
1708 dlls/winmm/wineaudioio/Makefile
1709 dlls/winmm/winejack/Makefile
1710 dlls/winmm/winenas/Makefile
1711 dlls/winmm/wineoss/Makefile
1712 dlls/winnls/Makefile
1713 dlls/winsock/Makefile
1714 dlls/winsock/tests/Makefile
1715 dlls/winspool/Makefile
1716 dlls/winspool/tests/Makefile
1717 dlls/wintab32/Makefile
1718 dlls/wintrust/Makefile
1719 dlls/wow32/Makefile
1720 dlls/wsock32/Makefile
1721 dlls/wtsapi32/Makefile
1722 dlls/x11drv/Makefile
1723 documentation/Makefile
1724 fonts/Makefile
1725 include/Makefile
1726 libs/Makefile
1727 libs/port/Makefile
1728 libs/unicode/Makefile
1729 libs/wine/Makefile
1730 libs/wpp/Makefile
1731 loader/Makefile
1732 programs/Makefile
1733 programs/avitools/Makefile
1734 programs/clock/Makefile
1735 programs/cmdlgtst/Makefile
1736 programs/control/Makefile
1737 programs/expand/Makefile
1738 programs/msiexec/Makefile
1739 programs/notepad/Makefile
1740 programs/progman/Makefile
1741 programs/regedit/Makefile
1742 programs/regsvr32/Makefile
1743 programs/rpcss/Makefile
1744 programs/rundll32/Makefile
1745 programs/start/Makefile
1746 programs/taskmgr/Makefile
1747 programs/uninstaller/Makefile
1748 programs/view/Makefile
1749 programs/wcmd/Makefile
1750 programs/wineboot/Makefile
1751 programs/winebrowser/Makefile
1752 programs/winecfg/Makefile
1753 programs/wineconsole/Makefile
1754 programs/winedbg/Makefile
1755 programs/winefile/Makefile
1756 programs/winemenubuilder/Makefile
1757 programs/winemine/Makefile
1758 programs/winepath/Makefile
1759 programs/winetest/Makefile
1760 programs/winevdm/Makefile
1761 programs/winhelp/Makefile
1762 programs/winver/Makefile
1763 server/Makefile
1764 tools/Makefile
1765 tools/widl/Makefile
1766 tools/winapi/Makefile
1767 tools/winebuild/Makefile
1768 tools/winedump/Makefile
1769 tools/winegcc/Makefile
1770 tools/wmc/Makefile
1771 tools/wrc/Makefile])
1773 AC_OUTPUT
1775 if test "$have_x" = "no"
1776 then
1777 echo
1778 echo "*** Warning: X development files not found. Wine will be built without"
1779 echo "*** X support, which currently does not work, and would probably not be"
1780 echo "*** what you want anyway. You will need to install devel packages of"
1781 echo "*** Xlib/Xfree86 at the very least."
1782 fi
1784 if test "$wine_cv_opengl_version_OK" = "no"
1785 then
1786 echo
1787 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1788 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1789 fi
1791 if test "$wine_cv_msg_freetype" = "yes"
1792 then
1793 echo
1794 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1795 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1796 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1797 echo "*** enable Wine to use TrueType fonts."
1798 fi
1800 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1801 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1802 "$ac_cv_c_opensoundsystem" = "no"
1803 then
1804 echo "*** No sound system was found. Windows applications will be silent."
1805 echo "*** The currently supported sound systems are:"
1806 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1807 fi
1809 echo
1810 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1811 echo
1813 dnl Local Variables:
1814 dnl comment-start: "dnl "
1815 dnl comment-end: ""
1816 dnl comment-start-skip: "\\bdnl\\b\\s *"
1817 dnl compile-command: "autoconf"
1818 dnl End: