tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of server/protocol.def.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (                     # size align format
  26     "int"           => [  4,   4,  "%d" ],
  27     "short int"     => [  2,   2,  "%d" ],
  28     "char"          => [  1,   1,  "%c" ],
  29     "unsigned char" => [  1,   1,  "%02x" ],
  30     "unsigned short"=> [  2,   2,  "%04x" ],
  31     "unsigned int"  => [  4,   4,  "%08x" ],
  32     "data_size_t"   => [  4,   4,  "%u" ],
  33     "obj_handle_t"  => [  4,   4,  "%04x" ],
  34     "atom_t"        => [  4,   4,  "%04x" ],
  35     "user_handle_t" => [  4,   4,  "%08x" ],
  36     "process_id_t"  => [  4,   4,  "%04x" ],
  37     "thread_id_t"   => [  4,   4,  "%04x" ],
  38     "client_ptr_t"  => [  8,   8,  "&dump_uint64" ],
  39     "mod_handle_t"  => [  8,   8,  "&dump_uint64" ],
  40     "lparam_t"      => [  8,   8,  "&dump_uint64" ],
  41     "apc_param_t"   => [  8,   8,  "&dump_uint64" ],
  42     "file_pos_t"    => [  8,   8,  "&dump_uint64" ],
  43     "mem_size_t"    => [  8,   8,  "&dump_uint64" ],
  44     "affinity_t"    => [  8,   8,  "&dump_uint64" ],
  45     "timeout_t"     => [  8,   8,  "&dump_timeout" ],
  46     "rectangle_t"   => [  16,  4,  "&dump_rectangle" ],
  47     "char_info_t"   => [  4,   2,  "&dump_char_info" ],
  48     "apc_call_t"    => [  40,  8,  "&dump_apc_call" ],
  49     "apc_result_t"  => [  40,  8,  "&dump_apc_result" ],
  50     "async_data_t"  => [  40,  8,  "&dump_async_data" ],
  51     "luid_t"        => [  8,   4,  "&dump_luid" ],
  52     "ioctl_code_t"  => [  4,   4,  "&dump_ioctl_code" ],
  53     "cpu_type_t"    => [  4,   4,  "&dump_cpu_type" ],
  54 );
  55
  56 my @requests = ();
  57 my %replies = ();
  58 my @asserts = ();
  59
  60 my @trace_lines = ();
  61
  62 my $max_req_size = 64;
  63
  64 my $warnings = scalar(@ARGV) && $ARGV[0] eq "-w";
  65
  66 sub add_padding($$)
  67 {
  68     my ($offset, $padding) = @_;
  69     if ($offset % $padding)
  70     {
  71         my $count = $padding - ($offset % $padding);
  72         print SERVER_PROT "    char __pad_$offset\[$count\];\n";
  73         $offset += $count;
  74     }
  75     return $offset;
  76 }
  77
  78 ### Generate a dumping function
  79
  80 sub DO_DUMP_FUNC($$@)
  81 {
  82     my $name = shift;
  83     my $req = shift;
  84     my $prefix = " ";
  85     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  86     while ($#_ >= 0)
  87     {
  88         my $type = shift;
  89         my $var = shift;
  90         next if $var =~ /^__pad/;
  91         if (defined($formats{$type}))
  92         {
  93             my $fmt = ${$formats{$type}}[2];
  94             if ($fmt =~ /^&(.*)/)
  95             {
  96                 my $func = $1;
  97                 push @trace_lines, "    $func( \"$prefix$var=\", &req->$var );\n";
  98             }
  99             elsif ($fmt =~ /^(%.*)\s+\((.*)\)/)
 100             {
 101                 my ($format, $cast) = ($1, $2);
 102                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$format\", ($cast)req->$var );\n";
 103             }
 104             else
 105             {
 106                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$fmt\", req->$var );\n";
 107             }
 108         }
 109         else  # must be some varargs format
 110         {
 111             push @trace_lines, "    " . sprintf($type, "$prefix$var=") . ";\n";
 112         }
 113         $prefix = ", ";
 114     }
 115     push @trace_lines, "}\n\n";
 116 }
 117
 118 ### Parse the request definitions
 119
 120 sub PARSE_REQUESTS()
 121 {
 122     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 123     my $state = 0;
 124     my $offset = 0;
 125     my $name = "";
 126     my @in_struct = ();
 127     my @out_struct = ();
 128
 129     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 130
 131     while (<PROTOCOL>)
 132     {
 133         my ($type, $var);
 134         # strip comments
 135         s!/\*.*\*/!!g;
 136         # strip white space at end of line
 137         s/\s+$//;
 138
 139         if (/^\@HEADER/)
 140         {
 141             die "Misplaced \@HEADER" unless $state == 0;
 142             $state++;
 143             next;
 144         }
 145
 146         # ignore everything while in state 0
 147         next if $state == 0;
 148
 149         if (/^\@REQ\(\s*(\w+)\s*\)/)
 150         {
 151             $name = $1;
 152             die "Misplaced \@REQ" unless $state == 1;
 153             # start a new request
 154             @in_struct = ();
 155             @out_struct = ();
 156             $offset = 12;
 157             print SERVER_PROT "struct ${name}_request\n{\n";
 158             print SERVER_PROT "    struct request_header __header;\n";
 159             $state++;
 160             next;
 161         }
 162
 163         if (/^\@REPLY/)
 164         {
 165             die "Misplaced \@REPLY" unless $state == 2;
 166             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 167             die "request $name too large ($offset)" if ($offset > $max_req_size);
 168             push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 169             print SERVER_PROT "};\n";
 170             print SERVER_PROT "struct ${name}_reply\n{\n";
 171             print SERVER_PROT "    struct reply_header __header;\n";
 172             die "request $name too large ($offset)" if ($offset > $max_req_size);
 173             $offset = 8;
 174             $state++;
 175             next;
 176         }
 177
 178         if (/^\@END/)
 179         {
 180             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 181
 182             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 183             print SERVER_PROT "};\n";
 184             if ($state == 2)  # build dummy reply struct
 185             {
 186                 die "request $name too large ($offset)" if ($offset > $max_req_size);
 187                 push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 188                 print SERVER_PROT "struct ${name}_reply\n{\n";
 189                 print SERVER_PROT "    struct reply_header __header;\n";
 190                 print SERVER_PROT "};\n";
 191             }
 192             else
 193             {
 194                 die "reply $name too large ($offset)" if ($offset > $max_req_size);
 195                 push @asserts, "C_ASSERT( sizeof(struct ${name}_reply) == $offset );\n";
 196             }
 197             # got a complete request
 198             push @requests, $name;
 199             DO_DUMP_FUNC( $name, "request", @in_struct);
 200             if ($#out_struct >= 0)
 201             {
 202                 $replies{$name} = 1;
 203                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 204             }
 205             $state = 1;
 206             next;
 207         }
 208
 209         if ($state != 1)
 210         {
 211             # skip empty lines (but keep them in output file)
 212             if (/^$/)
 213             {
 214                 print SERVER_PROT "\n";
 215                 next;
 216             }
 217
 218             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 219             {
 220                 $var = $1;
 221                 $type = "dump_varargs_" . $2 . "( \"%s\", min(cur_size,req->" . $3 . ") )";
 222                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 223             }
 224             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 225             {
 226                 $var = $1;
 227                 $type = "dump_varargs_" . $2 . "( \"%s\", cur_size )";
 228                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 229             }
 230             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 231             {
 232                 $type = $1;
 233                 $var = $3;
 234                 die "Unrecognized type $type" unless defined($formats{$type});
 235                 my @fmt = @{$formats{$type}};
 236                 if ($offset & ($fmt[1] - 1))
 237                 {
 238                     my $count = $fmt[1] - ($offset & ($fmt[1] - 1));
 239                     print "protocol.def:$.: warning: $name $offset $type $var needs padding\n" if $warnings;
 240                     print SERVER_PROT "    char __pad_$offset\[$count\];\n";
 241                     $offset += $count;
 242                 }
 243                 if ($state == 2)
 244                 {
 245                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_request, $var) == $offset );\n";
 246                 }
 247                 else
 248                 {
 249                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_reply, $var) == $offset );\n";
 250                 }
 251                 $offset += $fmt[0];
 252             }
 253             else
 254             {
 255                 die "Unrecognized syntax $_";
 256             }
 257             if ($state == 2) { push @in_struct, $type, $var; }
 258             if ($state == 3) { push @out_struct, $type, $var; }
 259         }
 260
 261         # Pass it through into the output file
 262         print SERVER_PROT $_ . "\n";
 263     }
 264     close PROTOCOL;
 265 }
 266
 267 ### Retrieve the server protocol version from the existing server_protocol.h file
 268
 269 sub GET_PROTOCOL_VERSION()
 270 {
 271     my $protocol = 0;
 272     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 273     while (<SERVER_PROT>)
 274     {
 275         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 276     }
 277     close SERVER_PROT;
 278     return $protocol;
 279 }
 280
 281 ### Retrieve the list of status and errors used in the server
 282
 283 sub GET_ERROR_NAMES()
 284 {
 285     my %errors = ();
 286     foreach my $f (glob "server/*.c")
 287     {
 288         next if $f eq "server/trace.c";
 289         open FILE, $f or die "Can't open $f";
 290         while (<FILE>)
 291         {
 292             if (/STATUS_(\w+)/)
 293             {
 294                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 295             }
 296             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 297             {
 298                 $errors{$1} = "0xc0010000 | $1";
 299             }
 300         }
 301         close FILE;
 302     }
 303     return %errors;
 304 }
 305
 306 # update a file if changed
 307 sub update_file($)
 308 {
 309     my $file = shift;
 310     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 311     if (!$ret)
 312     {
 313         unlink "$file.new";
 314     }
 315     else
 316     {
 317         rename "$file.new", "$file";
 318         print "$file updated\n";
 319     }
 320     return $ret;
 321 }
 322
 323 # replace some lines in a file between two markers
 324 sub replace_in_file($$$@)
 325 {
 326     my $file = shift;
 327     my $start = shift;
 328     my $end = shift;
 329
 330     open NEW_FILE, ">$file.new" or die "cannot create $file.new";
 331
 332     if (defined($start))
 333     {
 334         open OLD_FILE, "$file" or die "cannot open $file";
 335         while (<OLD_FILE>)
 336         {
 337             print NEW_FILE $_;
 338             last if /$start/;
 339         }
 340     }
 341
 342     print NEW_FILE "\n", @_, "\n";
 343
 344     if (defined($end))
 345     {
 346         my $skip=1;
 347         while (<OLD_FILE>)
 348         {
 349             $skip = 0 if /$end/;
 350             print NEW_FILE $_ unless $skip;
 351         }
 352     }
 353
 354     close OLD_FILE if defined($start);
 355     close NEW_FILE;
 356     return update_file($file);
 357 }
 358
 359 ### Main
 360
 361 # Get the server protocol version
 362 my $protocol = GET_PROTOCOL_VERSION();
 363
 364 my %errors = GET_ERROR_NAMES();
 365
 366 ### Create server_protocol.h and print header
 367
 368 open SERVER_PROT, ">include/wine/server_protocol.h.new" or die "Cannot create include/wine/server_protocol.h.new";
 369 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 370 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 371 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 372 print SERVER_PROT " */\n\n";
 373 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 374 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 375
 376 ### Parse requests to find request/reply structure definitions
 377
 378 PARSE_REQUESTS();
 379
 380 ### Build the request list and structures
 381
 382 print SERVER_PROT "\n\nenum request\n{\n";
 383 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 384 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 385
 386 print SERVER_PROT "union generic_request\n{\n";
 387 print SERVER_PROT "    struct request_max_size max_size;\n";
 388 print SERVER_PROT "    struct request_header request_header;\n";
 389 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 390 print SERVER_PROT "};\n";
 391
 392 print SERVER_PROT "union generic_reply\n{\n";
 393 print SERVER_PROT "    struct request_max_size max_size;\n";
 394 print SERVER_PROT "    struct reply_header reply_header;\n";
 395 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 396 print SERVER_PROT "};\n\n";
 397
 398 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 399 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 400 close SERVER_PROT;
 401 update_file( "include/wine/server_protocol.h" );
 402
 403 ### Output the dumping function tables
 404
 405 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 406 foreach my $req (@requests)
 407 {
 408     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 409 }
 410 push @trace_lines, "};\n\n";
 411
 412 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 413 foreach my $req (@requests)
 414 {
 415     push @trace_lines, "    ", $replies{$req} ? "(dump_func)dump_${req}_reply,\n" : "NULL,\n";
 416 }
 417 push @trace_lines, "};\n\n";
 418
 419 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 420 foreach my $req (@requests)
 421 {
 422     push @trace_lines, "    \"$req\",\n";
 423 }
 424 push @trace_lines, "};\n\n";
 425
 426 push @trace_lines, "static const struct\n{\n";
 427 push @trace_lines, "    const char  *name;\n";
 428 push @trace_lines, "    unsigned int value;\n";
 429 push @trace_lines, "} status_names[] =\n{\n";
 430
 431 foreach my $err (sort keys %errors)
 432 {
 433     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 434 }
 435 push @trace_lines, "    { NULL, 0 }\n";
 436 push @trace_lines, "};\n";
 437
 438 replace_in_file( "server/trace.c",
 439                  "### make_requests begin ###",
 440                  "### make_requests end ###",
 441                  @trace_lines );
 442
 443 ### Output the request handlers list
 444
 445 my @request_lines = ();
 446
 447 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 448 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 449 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 450 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 451 foreach my $req (@requests)
 452 {
 453     push @request_lines, "    (req_handler)req_$req,\n";
 454 }
 455 push @request_lines, "};\n\n";
 456
 457 foreach my $type (sort keys %formats)
 458 {
 459     my $size = ${$formats{$type}}[0];
 460     push @request_lines, "C_ASSERT( sizeof($type) == $size );\n";
 461 }
 462 push @request_lines, @asserts;
 463 push @request_lines, "\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 464
 465 replace_in_file( "server/request.h",
 466                  "### make_requests begin ###",
 467                  "### make_requests end ###",
 468                  @request_lines );