epan/dtd_preparse.l

   1 %top {
   2 /* Include this before everything else, for various large-file definitions */
   3 #include "config.h"
   4 #include <wireshark.h>
   5 }
   6
   7 /*
   8  * We want a reentrant scanner.
   9  */
  10 %option reentrant
  11
  12 /*
  13  * We don't use input, so don't generate code for it.
  14  */
  15 %option noinput
  16
  17 /*
  18  * We don't use unput, so don't generate code for it.
  19  */
  20 %option nounput
  21
  22 /*
  23  * We don't read interactively from the terminal.
  24  */
  25 %option never-interactive
  26
  27 /*
  28  * We want to stop processing when we get to the end of the input.
  29  */
  30 %option noyywrap
  31
  32 /*
  33  * The type for the state we keep for a scanner.
  34  */
  35 %option extra-type="Dtd_PreParse_scanner_state_t *"
  36
  37 /*
  38  * The language we're scanning is case-insensitive.
  39  */
  40 %option caseless
  41
  42 /*
  43  * Prefix scanner routines with "Dtd_PreParse_" rather than "yy", so this
  44  * scanner can coexist with other scanners.
  45  */
  46 %option prefix="Dtd_PreParse_"
  47
  48 %option outfile="dtd_preparse.c"
  49
  50 /*
  51  * We have to override the memory allocators so that we don't get
  52  * "unused argument" warnings from the yyscanner argument (which
  53  * we don't use, as we have a global memory allocator).
  54  *
  55  * We provide, as macros, our own versions of the routines generated by Flex,
  56  * which just call malloc()/realloc()/free() (as the Flex versions do),
  57  * discarding the extra argument.
  58  */
  59 %option noyyalloc
  60 %option noyyrealloc
  61 %option noyyfree
  62
  63 %{
  64         /*
  65          * dtd_preparse.l
  66          *
  67          * an XML dissector for wireshark
  68          *
  69          * DTD Preparser -  import a dtd file into a GString
  70          *                  including files, removing comments
  71          *                  and resolving %entities;
  72          *
  73          * Copyright 2004, Luis E. Garcia Ontanon <luis@ontanon.org>
  74          *
  75          * Wireshark - Network traffic analyzer
  76          * By Gerald Combs <gerald@wireshark.org>
  77          * Copyright 1998 Gerald Combs
  78          *
  79          * This program is free software; you can redistribute it and/or
  80          * modify it under the terms of the GNU General Public License
  81          * as published by the Free Software Foundation; either version 2
  82          * of the License, or (at your option) any later version.
  83          *
  84          * This program is distributed in the hope that it will be useful,
  85          * but WITHOUT ANY WARRANTY; without even the implied warranty of
  86          * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  87          * GNU General Public License for more details.
  88          *
  89          * You should have received a copy of the GNU General Public License
  90          * along with this program; if not, write to the Free Software
  91          * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  92          */
  93
  94 #include <glib.h>
  95 #include <string.h>
  96 #include <errno.h>
  97 #include <stdio.h>
  98 #include "dtd.h"
  99 #include <wsutil/file_util.h>
 100
 101 /*
 102  * Disable diagnostics in the code generated by Flex.
 103  */
 104 DIAG_OFF_FLEX()
 105
 106 #define ECHO g_string_append(yyextra->current,yytext);
 107
 108 struct _dtd_preparse_scanner_state {
 109         const char* dtd_dirname;
 110         const char* filename;
 111         unsigned linenum;
 112
 113         GString* error;
 114
 115         GHashTable* entities;
 116         GString* current;
 117         GString* output;
 118         char* entity_name;
 119 };
 120
 121 static const char* replace_entity(Dtd_PreParse_scanner_state_t* state, char* s);
 122
 123 #define YY_USER_INIT { \
 124         BEGIN OUTSIDE; \
 125 }
 126
 127 /*
 128  * Flex (v 2.5.35) uses this symbol to "exclude" unistd.h
 129  */
 130 #ifdef _WIN32
 131 #define YY_NO_UNISTD_H
 132 #endif
 133
 134 /*
 135  * Sleazy hack to suppress compiler warnings in yy_fatal_error().
 136  */
 137 #define YY_EXIT_FAILURE ((void)yyscanner, 2)
 138
 139 /*
 140  * Macros for the allocators, to discard the extra argument.
 141  */
 142 #define Dtd_PreParse_alloc(size, yyscanner)             (void *)malloc(size)
 143 #define Dtd_PreParse_realloc(ptr, size, yyscanner)      (void *)realloc((char *)(ptr), (size))
 144 #define Dtd_PreParse_free(ptr, yyscanner)               free((char *)ptr)
 145
 146 %}
 147 xmlpi_start "<?"
 148 xmlpi_stop  "?>"
 149 xmlpi_chars .
 150
 151 comment_start "<!--"
 152 comment_stop "-->"
 153 special_start "<!"
 154 special_stop ">"
 155
 156 entity_start     "<!"[[:blank:]\n]*entity[[:blank:]\n]*"%"
 157 system     SYSTEM
 158 filename   [^"]+
 159
 160
 161 name [A-Za-z][-:A-Za-z0-9_\.]*
 162
 163 quote "\""
 164 percent [%]
 165 escaped_quote "\\\""
 166 non_quote [^"%]+
 167
 168 avoid_editor_bug ["]
 169
 170 entity        [%&][A-Za-z][-A-Za-z0-9_]*;
 171
 172 whitespace [[blank:]]+
 173 newline    \n
 174 %START OUTSIDE IN_COMMENT IN_ENTITY NAMED_ENTITY IN_QUOTE ENTITY_DONE XMLPI
 175 %%
 176
 177
 178 {entity}                                if (yyextra->current) g_string_append_printf(yyextra->current,"%s\n%s\n",replace_entity(yyextra, yytext),dtd_location(yyextra));
 179
 180 {whitespace}                            if (yyextra->current) g_string_append(yyextra->current," ");
 181
 182 <OUTSIDE>{xmlpi_start}                  { g_string_append(yyextra->current,yytext); BEGIN XMLPI; }
 183 <XMLPI>{xmlpi_chars}                    { g_string_append(yyextra->current,yytext); }
 184 <XMLPI>{newline}                        { g_string_append(yyextra->current,yytext); }
 185 <XMLPI>{xmlpi_stop}                     { g_string_append(yyextra->current,yytext); BEGIN OUTSIDE; }
 186
 187 <OUTSIDE>{comment_start}                { yyextra->current = NULL; BEGIN IN_COMMENT; }
 188 <IN_COMMENT>[^-]?                       |
 189 <IN_COMMENT>[-]                         ;
 190 <IN_COMMENT>{comment_stop}              { yyextra->current = yyextra->output; BEGIN OUTSIDE; }
 191
 192 {newline}                               {
 193         yyextra->linenum++;
 194         if (yyextra->current) g_string_append_printf(yyextra->current,"%s\n",dtd_location(yyextra));
 195 }
 196
 197
 198 <OUTSIDE>{entity_start}                 { BEGIN IN_ENTITY; }
 199 <IN_ENTITY>{name}                       { yyextra->entity_name = ws_strdup_printf("%%%s;",yytext); BEGIN NAMED_ENTITY; }
 200 <NAMED_ENTITY>{quote}                   { yyextra->current = g_string_new(dtd_location(yyextra)); BEGIN IN_QUOTE; }
 201 <IN_QUOTE>{quote}                       { g_hash_table_insert(yyextra->entities,yyextra->entity_name,yyextra->current);  BEGIN ENTITY_DONE; }
 202 <IN_QUOTE>{percent}                     |
 203 <IN_QUOTE>{non_quote}                   |
 204 <IN_QUOTE>{escaped_quote}               g_string_append(yyextra->current,yytext);
 205 <NAMED_ENTITY>{system}                  {
 206         g_string_append_printf(yyextra->error,"at %s:%u: file inclusion is not supported!", yyextra->filename, yyextra->linenum);
 207         yyterminate();
 208 }
 209 <ENTITY_DONE>{special_stop}             { yyextra->current = yyextra->output; g_string_append(yyextra->current,"\n"); BEGIN OUTSIDE; }
 210
 211 %%
 212
 213 /*
 214  * Turn diagnostics back on, so we check the code that we've written.
 215  */
 216 DIAG_ON_FLEX()
 217
 218 static const char* replace_entity(Dtd_PreParse_scanner_state_t* state, char* entity) {
 219         GString* replacement;
 220
 221         *entity = '%';
 222
 223         replacement = (GString*)g_hash_table_lookup(state->entities,entity);
 224
 225         if (replacement) {
 226                 return replacement->str;
 227         } else {
 228                 g_string_append_printf(state->error,"dtd_preparse: in file '%s': entity %s does not exists\n", state->filename, entity);
 229                 return "";
 230         }
 231
 232 }
 233
 234 const char* dtd_location(Dtd_PreParse_scanner_state_t* state) {
 235         static char* loc = NULL;
 236
 237         g_free(loc);
 238
 239         if (!state) return NULL;
 240
 241         loc = ws_strdup_printf("<? wireshark:location %s:%u ?>", state->filename, state->linenum);
 242
 243         return loc;
 244 }
 245
 246 static gboolean free_gstring_hash_items(void *k,void *v,void *p _U_) {
 247         g_free(k);
 248         g_string_free((GString*)v,true);
 249         return true;
 250 }
 251
 252 extern GString* dtd_preparse(const char* dname,const  char* fname, GString* err) {
 253         char* fullname = ws_strdup_printf("%s%c%s",dname,G_DIR_SEPARATOR,fname);
 254         FILE *in;
 255         yyscan_t scanner;
 256         Dtd_PreParse_scanner_state_t state;
 257
 258         in = ws_fopen(fullname,"r");
 259
 260         if (!in) {
 261                 if (err)
 262                         g_string_append_printf(err, "Could not open file: '%s', error: %s",fullname,g_strerror(errno));
 263                 g_free(fullname);
 264                 return NULL;
 265         }
 266
 267         if (Dtd_PreParse_lex_init(&scanner) != 0) {
 268                 if (err)
 269                         g_string_append_printf(err, "Can't initialize scanner: %s",
 270                             strerror(errno));
 271                 fclose(in);
 272                 g_free(fullname);
 273                 return NULL;
 274         }
 275
 276         Dtd_PreParse_set_in(in, scanner);
 277
 278         state.dtd_dirname = dname;
 279         state.filename = fname;
 280         state.linenum = 1;
 281
 282         state.error = err;
 283
 284         state.entities = g_hash_table_new(g_str_hash,g_str_equal);
 285         state.current = state.output = g_string_new(dtd_location(&state));
 286         state.entity_name = NULL;
 287
 288         /* Associate the state with the scanner */
 289         Dtd_PreParse_set_extra(&state, scanner);
 290
 291         Dtd_PreParse_lex(scanner);
 292
 293         Dtd_PreParse_lex_destroy(scanner);
 294         fclose(in);
 295
 296         g_hash_table_foreach_remove(state.entities,free_gstring_hash_items,NULL);
 297         g_hash_table_destroy(state.entities);
 298
 299         g_free(fullname);
 300
 301         return state.output;
 302 }