doc/plugins.example/CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # SPDX-License-Identifier: GPL-2.0-or-later
   8 #
   9
  10 cmake_minimum_required(VERSION 3.16)
  11
  12 project(Hello VERSION 0.0.1 DESCRIPTION "Wireshark Hello Plugin" LANGUAGES C)
  13
  14 find_package(Wireshark CONFIG REQUIRED)
  15
  16 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  17         set(CMAKE_INSTALL_PREFIX "${Wireshark_INSTALL_PREFIX}"
  18                 CACHE PATH "Installation prefix" FORCE
  19         )
  20 endif()
  21
  22 if(NOT Wireshark_PLUGINS_ENABLED)
  23         message(WARNING "Wireshark was compiled without support for plugins")
  24 endif()
  25
  26 # External plugins must define HAVE_SSIZE_T for the plugin toolchain.
  27 include(CheckTypeSize)
  28 check_type_size("ssize_t" SSIZE_T)
  29
  30 set(CMAKE_C_VISIBILITY_PRESET hidden)
  31 if(CMAKE_COMPILER_IS_GNUCC)
  32     set(CMAKE_C_FLAGS  "-Wall -Wextra ${CMAKE_C_FLAGS}")
  33 endif()
  34
  35 add_compile_definitions(
  36         VERSION=\"${PROJECT_VERSION}\"
  37         $<$<BOOL:${HAVE_SSIZE_T}>:HAVE_SSIZE_T>
  38 )
  39
  40 add_library(hello MODULE hello.c)
  41 set_target_properties(hello PROPERTIES PREFIX "" DEFINE_SYMBOL "")
  42 target_link_libraries(hello epan)
  43
  44 # This is the normal installation target to CMAKE_INSTALL_PREFIX. It is relocatable
  45 # using DESTDIR or cmake --install. By default CMAKE_INSTALL_PREFIX should be configured
  46 # correctly for Wireshark's system installation prefix.
  47 install(TARGETS hello
  48         LIBRARY DESTINATION "${Wireshark_PLUGIN_LIBDIR}/epan" NAMELINK_SKIP
  49 )
  50
  51 # This custom target installs the plugin to the plugin dir in WiresharkConfig.cmake.
  52 # It does not use CMAKE_INSTALL_PREFIX.
  53 add_custom_target(copy_plugin
  54         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:hello> "${Wireshark_PLUGIN_INSTALL_DIR}/epan"
  55         COMMENT "Installing plugin to: ${Wireshark_PLUGIN_INSTALL_DIR}/epan"
  56 )
  57
  58 string(TOLOWER "${PROJECT_NAME}-${PROJECT_VERSION}" _pkgname)
  59
  60 add_custom_target(package_prep
  61         COMMAND ${CMAKE_COMMAND} -E make_directory  ${CMAKE_BINARY_DIR}/${_pkgname}
  62         COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_SOURCE_DIR}/README $<TARGET_FILE:hello> ${CMAKE_BINARY_DIR}/${_pkgname}
  63 )
  64
  65 add_custom_target(package
  66         COMMAND ${CMAKE_COMMAND} -E tar czf ${CMAKE_BINARY_DIR}/${_pkgname}.tar.gz --format=gnutar -- ${CMAKE_BINARY_DIR}/${_pkgname}
  67 )
  68 add_dependencies(package package_prep)
  69
  70 add_custom_target(package_zip
  71         COMMAND ${CMAKE_COMMAND} -E tar cf ${CMAKE_BINARY_DIR}/${_pkgname}.zip --format=zip -- ${CMAKE_BINARY_DIR}/${_pkgname}
  72 )
  73 add_dependencies(package_zip package_prep)