packaging/msys2/mingw-w64-wireshark-git/PKGBUILD

   1 # Maintainer: Wireshark Core Team <wireshark-dev@wireshark.org>
   2
   3 _realname=wireshark
   4 pkgbase=mingw-w64-${_realname}-git
   5 pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}-git")
   6 pkgver=4.1.0rc0.1408.gd00bd20fea
   7 pkgrel=1
   8 pkgdesc="Network traffic and protocol analyzer/sniffer"
   9 arch=('any')
  10 mingw_arch=('mingw64' 'ucrt64' 'clang64')
  11 url="https://www.wireshark.org"
  12 license=('GPL2')
  13 depends=("${MINGW_PACKAGE_PREFIX}-bcg729"
  14          "${MINGW_PACKAGE_PREFIX}-brotli"
  15          "${MINGW_PACKAGE_PREFIX}-c-ares"
  16          "${MINGW_PACKAGE_PREFIX}-glib2"
  17          "${MINGW_PACKAGE_PREFIX}-gnutls"
  18          "${MINGW_PACKAGE_PREFIX}-libgcrypt"
  19          "${MINGW_PACKAGE_PREFIX}-libilbc"
  20          "${MINGW_PACKAGE_PREFIX}-libmaxminddb"
  21          "${MINGW_PACKAGE_PREFIX}-libpcap"
  22          "${MINGW_PACKAGE_PREFIX}-libsmi"
  23          "${MINGW_PACKAGE_PREFIX}-libssh"
  24          "${MINGW_PACKAGE_PREFIX}-libxml2"
  25          "${MINGW_PACKAGE_PREFIX}-lz4"
  26          "${MINGW_PACKAGE_PREFIX}-minizip"
  27          "${MINGW_PACKAGE_PREFIX}-nghttp2"
  28          "${MINGW_PACKAGE_PREFIX}-opencore-amr"
  29          "${MINGW_PACKAGE_PREFIX}-opus"
  30          "${MINGW_PACKAGE_PREFIX}-pcre2"
  31          "${MINGW_PACKAGE_PREFIX}-qt6-base"
  32          "${MINGW_PACKAGE_PREFIX}-qt6-multimedia"
  33          "${MINGW_PACKAGE_PREFIX}-qt6-5compat"
  34          "${MINGW_PACKAGE_PREFIX}-sbc"
  35          "${MINGW_PACKAGE_PREFIX}-snappy"
  36          "${MINGW_PACKAGE_PREFIX}-spandsp"
  37          "${MINGW_PACKAGE_PREFIX}-speexdsp"
  38          "${MINGW_PACKAGE_PREFIX}-zlib"
  39          "${MINGW_PACKAGE_PREFIX}-zstd")
  40 makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
  41              "${MINGW_PACKAGE_PREFIX}-ninja"
  42              "${MINGW_PACKAGE_PREFIX}-cc"
  43              "${MINGW_PACKAGE_PREFIX}-python"
  44              "${MINGW_PACKAGE_PREFIX}-qt6-tools"
  45              "${MINGW_PACKAGE_PREFIX}-asciidoctor"
  46              "${MINGW_PACKAGE_PREFIX}-docbook-xsl"
  47              "${MINGW_PACKAGE_PREFIX}-libxslt"
  48              'git')
  49 checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest"
  50               "${MINGW_PACKAGE_PREFIX}-python-pytest-xdist")
  51 provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
  52 conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
  53 _commit=${PKG_COMMIT:-HEAD}
  54 source=("${_realname}"::"git+https://gitlab.com/wireshark/wireshark.git#commit=${_commit}")
  55 sha256sums=('SKIP')
  56
  57 pkgver() {
  58   cd "${_realname}"
  59
  60   git describe --long "${_commit}" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
  61 }
  62
  63 build() {
  64   mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
  65
  66   declare -a extra_config
  67   if check_option "debug" "n"; then
  68     extra_config+=("-DCMAKE_BUILD_TYPE=Release")
  69   else
  70     extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
  71   fi
  72
  73   MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
  74     "${MINGW_PREFIX}"/bin/cmake.exe \
  75       -GNinja \
  76       -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
  77       "${extra_config[@]}" \
  78       -DENABLE_WERROR=OFF \
  79       -DUSE_qt6=ON \
  80       -DENABLE_WINSPARKLE=OFF \
  81       -DFETCH_lua=ON \
  82       ../${_realname}
  83
  84   "${MINGW_PREFIX}"/bin/cmake.exe --build .
  85   "${MINGW_PREFIX}"/bin/cmake.exe --build . --target user_guide_html
  86 }
  87
  88 check() {
  89   cd "${srcdir}/build-${MSYSTEM}"
  90
  91   "${MINGW_PREFIX}"/bin/cmake.exe --build . --target test-programs
  92   "${MINGW_PREFIX}"/bin/pytest.exe
  93 }
  94
  95 package() {
  96   cd "${srcdir}/build-${MSYSTEM}"
  97
  98   DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
  99   DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install . --component UserGuide
 100   DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install . --component Development
 101
 102   install -Dm644 "${srcdir}/${_realname}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
 103 }