arch/arm/kernel/head-common.S

   1 /*
   2  *  linux/arch/arm/kernel/head-common.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  */
  13
  14 <<<<<<< HEAD:arch/arm/kernel/head-common.S
  15 =======
  16 #define ATAG_CORE 0x54410001
  17 #define ATAG_CORE_SIZE ((2*4 + 3*4) >> 2)
  18
  19 >>>>>>> 264e3e889d86e552b4191d69bb60f4f3b383135a:arch/arm/kernel/head-common.S
  20         .type   __switch_data, %object
  21 __switch_data:
  22         .long   __mmap_switched
  23         .long   __data_loc                      @ r4
  24         .long   __data_start                    @ r5
  25         .long   __bss_start                     @ r6
  26         .long   _end                            @ r7
  27         .long   processor_id                    @ r4
  28         .long   __machine_arch_type             @ r5
  29         .long   __atags_pointer                 @ r6
  30         .long   cr_alignment                    @ r7
  31         .long   init_thread_union + THREAD_START_SP @ sp
  32
  33 /*
  34  * The following fragment of code is executed with the MMU on in MMU mode,
  35  * and uses absolute addresses; this is not position independent.
  36  *
  37  *  r0  = cp#15 control register
  38  *  r1  = machine ID
  39  *  r2  = atags pointer
  40  *  r9  = processor ID
  41  */
  42         .type   __mmap_switched, %function
  43 __mmap_switched:
  44         adr     r3, __switch_data + 4
  45
  46         ldmia   r3!, {r4, r5, r6, r7}
  47         cmp     r4, r5                          @ Copy data segment if needed
  48 1:      cmpne   r5, r6
  49         ldrne   fp, [r4], #4
  50         strne   fp, [r5], #4
  51         bne     1b
  52
  53         mov     fp, #0                          @ Clear BSS (and zero fp)
  54 1:      cmp     r6, r7
  55         strcc   fp, [r6],#4
  56         bcc     1b
  57
  58         ldmia   r3, {r4, r5, r6, r7, sp}
  59         str     r9, [r4]                        @ Save processor ID
  60         str     r1, [r5]                        @ Save machine type
  61         str     r2, [r6]                        @ Save atags pointer
  62         bic     r4, r0, #CR_A                   @ Clear 'A' bit
  63         stmia   r7, {r0, r4}                    @ Save control register values
  64         b       start_kernel
  65
  66 /*
  67  * Exception handling.  Something went wrong and we can't proceed.  We
  68  * ought to tell the user, but since we don't have any guarantee that
  69  * we're even running on the right architecture, we do virtually nothing.
  70  *
  71  * If CONFIG_DEBUG_LL is set we try to print out something about the error
  72  * and hope for the best (useful if bootloader fails to pass a proper
  73  * machine ID for example).
  74  */
  75
  76         .type   __error_p, %function
  77 __error_p:
  78 #ifdef CONFIG_DEBUG_LL
  79         adr     r0, str_p1
  80         bl      printascii
  81         b       __error
  82 str_p1: .asciz  "\nError: unrecognized/unsupported processor variant.\n"
  83         .align
  84 #endif
  85
  86         .type   __error_a, %function
  87 __error_a:
  88 #ifdef CONFIG_DEBUG_LL
  89         mov     r4, r1                          @ preserve machine ID
  90         adr     r0, str_a1
  91         bl      printascii
  92         mov     r0, r4
  93         bl      printhex8
  94         adr     r0, str_a2
  95         bl      printascii
  96         adr     r3, 3f
  97         ldmia   r3, {r4, r5, r6}                @ get machine desc list
  98         sub     r4, r3, r4                      @ get offset between virt&phys
  99         add     r5, r5, r4                      @ convert virt addresses to
 100         add     r6, r6, r4                      @ physical address space
 101 1:      ldr     r0, [r5, #MACHINFO_TYPE]        @ get machine type
 102         bl      printhex8
 103         mov     r0, #'\t'
 104         bl      printch
 105         ldr     r0, [r5, #MACHINFO_NAME]        @ get machine name
 106         add     r0, r0, r4
 107         bl      printascii
 108         mov     r0, #'\n'
 109         bl      printch
 110         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 111         cmp     r5, r6
 112         blo     1b
 113         adr     r0, str_a3
 114         bl      printascii
 115         b       __error
 116 str_a1: .asciz  "\nError: unrecognized/unsupported machine ID (r1 = 0x"
 117 str_a2: .asciz  ").\n\nAvailable machine support:\n\nID (hex)\tNAME\n"
 118 str_a3: .asciz  "\nPlease check your kernel config and/or bootloader.\n"
 119         .align
 120 #endif
 121
 122         .type   __error, %function
 123 __error:
 124 #ifdef CONFIG_ARCH_RPC
 125 /*
 126  * Turn the screen red on a error - RiscPC only.
 127  */
 128         mov     r0, #0x02000000
 129         mov     r3, #0x11
 130         orr     r3, r3, r3, lsl #8
 131         orr     r3, r3, r3, lsl #16
 132         str     r3, [r0], #4
 133         str     r3, [r0], #4
 134         str     r3, [r0], #4
 135         str     r3, [r0], #4
 136 #endif
 137 1:      mov     r0, r0
 138         b       1b
 139
 140
 141 /*
 142  * Read processor ID register (CP#15, CR0), and look up in the linker-built
 143  * supported processor list.  Note that we can't use the absolute addresses
 144  * for the __proc_info lists since we aren't running with the MMU on
 145  * (and therefore, we are not in the correct address space).  We have to
 146  * calculate the offset.
 147  *
 148  *      r9 = cpuid
 149  * Returns:
 150  *      r3, r4, r6 corrupted
 151  *      r5 = proc_info pointer in physical address space
 152  *      r9 = cpuid (preserved)
 153  */
 154         .type   __lookup_processor_type, %function
 155 __lookup_processor_type:
 156         adr     r3, 3f
 157         ldmda   r3, {r5 - r7}
 158         sub     r3, r3, r7                      @ get offset between virt&phys
 159         add     r5, r5, r3                      @ convert virt addresses to
 160         add     r6, r6, r3                      @ physical address space
 161 1:      ldmia   r5, {r3, r4}                    @ value, mask
 162         and     r4, r4, r9                      @ mask wanted bits
 163         teq     r3, r4
 164         beq     2f
 165         add     r5, r5, #PROC_INFO_SZ           @ sizeof(proc_info_list)
 166         cmp     r5, r6
 167         blo     1b
 168         mov     r5, #0                          @ unknown processor
 169 2:      mov     pc, lr
 170
 171 /*
 172  * This provides a C-API version of the above function.
 173  */
 174 ENTRY(lookup_processor_type)
 175         stmfd   sp!, {r4 - r7, r9, lr}
 176         mov     r9, r0
 177         bl      __lookup_processor_type
 178         mov     r0, r5
 179         ldmfd   sp!, {r4 - r7, r9, pc}
 180
 181 /*
 182  * Look in include/asm-arm/procinfo.h and arch/arm/kernel/arch.[ch] for
 183  * more information about the __proc_info and __arch_info structures.
 184  */
 185         .long   __proc_info_begin
 186         .long   __proc_info_end
 187 3:      .long   .
 188         .long   __arch_info_begin
 189         .long   __arch_info_end
 190
 191 /*
 192  * Lookup machine architecture in the linker-build list of architectures.
 193  * Note that we can't use the absolute addresses for the __arch_info
 194  * lists since we aren't running with the MMU on (and therefore, we are
 195  * not in the correct address space).  We have to calculate the offset.
 196  *
 197  *  r1 = machine architecture number
 198  * Returns:
 199  *  r3, r4, r6 corrupted
 200  *  r5 = mach_info pointer in physical address space
 201  */
 202         .type   __lookup_machine_type, %function
 203 __lookup_machine_type:
 204         adr     r3, 3b
 205         ldmia   r3, {r4, r5, r6}
 206         sub     r3, r3, r4                      @ get offset between virt&phys
 207         add     r5, r5, r3                      @ convert virt addresses to
 208         add     r6, r6, r3                      @ physical address space
 209 1:      ldr     r3, [r5, #MACHINFO_TYPE]        @ get machine type
 210         teq     r3, r1                          @ matches loader number?
 211         beq     2f                              @ found
 212         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 213         cmp     r5, r6
 214         blo     1b
 215         mov     r5, #0                          @ unknown machine
 216 2:      mov     pc, lr
 217
 218 /*
 219  * This provides a C-API version of the above function.
 220  */
 221 ENTRY(lookup_machine_type)
 222         stmfd   sp!, {r4 - r6, lr}
 223         mov     r1, r0
 224         bl      __lookup_machine_type
 225         mov     r0, r5
 226         ldmfd   sp!, {r4 - r6, pc}
 227
 228 /* Determine validity of the r2 atags pointer.  The heuristic requires
 229  * that the pointer be aligned, in the first 16k of physical RAM and
 230  * that the ATAG_CORE marker is first and present.  Future revisions
 231  * of this function may be more lenient with the physical address and
 232  * may also be able to move the ATAGS block if necessary.
 233  *
 234  * r8  = machinfo
 235  *
 236  * Returns:
 237  *  r2 either valid atags pointer, or zero
 238  *  r5, r6 corrupted
 239  */
 240
 241         .type   __vet_atags, %function
 242 __vet_atags:
 243         tst     r2, #0x3                        @ aligned?
 244         bne     1f
 245
 246         ldr     r5, [r2, #0]                    @ is first tag ATAG_CORE?
 247         subs    r5, r5, #ATAG_CORE_SIZE
 248         bne     1f
 249         ldr     r5, [r2, #4]
 250         ldr     r6, =ATAG_CORE
 251         cmp     r5, r6
 252         bne     1f
 253
 254         mov     pc, lr                          @ atag pointer is ok
 255
 256 1:      mov     r2, #0
 257         mov     pc, lr