arch/sparc64/kernel/hvtramp.S

   1 /* hvtramp.S: Hypervisor start-cpu trampoline code.
   2  *
   3  * Copyright (C) 2007 David S. Miller <davem@davemloft.net>
   4  */
   5
   6 <<<<<<< HEAD:arch/sparc64/kernel/hvtramp.S
   7 =======
   8 #include <linux/init.h>
   9
  10 >>>>>>> 264e3e889d86e552b4191d69bb60f4f3b383135a:arch/sparc64/kernel/hvtramp.S
  11 #include <asm/thread_info.h>
  12 #include <asm/hypervisor.h>
  13 #include <asm/scratchpad.h>
  14 #include <asm/spitfire.h>
  15 #include <asm/hvtramp.h>
  16 #include <asm/pstate.h>
  17 #include <asm/ptrace.h>
  18 #include <asm/head.h>
  19 #include <asm/asi.h>
  20
  21 <<<<<<< HEAD:arch/sparc64/kernel/hvtramp.S
  22         .text
  23 =======
  24         __CPUINIT
  25 >>>>>>> 264e3e889d86e552b4191d69bb60f4f3b383135a:arch/sparc64/kernel/hvtramp.S
  26         .align          8
  27         .globl          hv_cpu_startup, hv_cpu_startup_end
  28
  29         /* This code executes directly out of the hypervisor
  30          * with physical addressing (va==pa).  %o0 contains
  31          * our client argument which for Linux points to
  32          * a descriptor data structure which defines the
  33          * MMU entries we need to load up.
  34          *
  35          * After we set things up we enable the MMU and call
  36          * into the kernel.
  37          *
  38          * First setup basic privileged cpu state.
  39          */
  40 hv_cpu_startup:
  41         SET_GL(0)
  42         wrpr            %g0, 15, %pil
  43         wrpr            %g0, 0, %canrestore
  44         wrpr            %g0, 0, %otherwin
  45         wrpr            %g0, 6, %cansave
  46         wrpr            %g0, 6, %cleanwin
  47         wrpr            %g0, 0, %cwp
  48         wrpr            %g0, 0, %wstate
  49         wrpr            %g0, 0, %tl
  50
  51         sethi           %hi(sparc64_ttable_tl0), %g1
  52         wrpr            %g1, %tba
  53
  54         mov             %o0, %l0
  55
  56         lduw            [%l0 + HVTRAMP_DESCR_CPU], %g1
  57         mov             SCRATCHPAD_CPUID, %g2
  58         stxa            %g1, [%g2] ASI_SCRATCHPAD
  59
  60         ldx             [%l0 + HVTRAMP_DESCR_FAULT_INFO_VA], %g2
  61         stxa            %g2, [%g0] ASI_SCRATCHPAD
  62
  63         mov             0, %l1
  64         lduw            [%l0 + HVTRAMP_DESCR_NUM_MAPPINGS], %l2
  65         add             %l0, HVTRAMP_DESCR_MAPS, %l3
  66
  67 1:      ldx             [%l3 + HVTRAMP_MAPPING_VADDR], %o0
  68         clr             %o1
  69         ldx             [%l3 + HVTRAMP_MAPPING_TTE], %o2
  70         mov             HV_MMU_IMMU | HV_MMU_DMMU, %o3
  71         mov             HV_FAST_MMU_MAP_PERM_ADDR, %o5
  72         ta              HV_FAST_TRAP
  73
  74         brnz,pn         %o0, 80f
  75          nop
  76
  77         add             %l1, 1, %l1
  78         cmp             %l1, %l2
  79         blt,a,pt        %xcc, 1b
  80          add            %l3, HVTRAMP_MAPPING_SIZE, %l3
  81
  82         ldx             [%l0 + HVTRAMP_DESCR_FAULT_INFO_PA], %o0
  83         mov             HV_FAST_MMU_FAULT_AREA_CONF, %o5
  84         ta              HV_FAST_TRAP
  85
  86         brnz,pn         %o0, 80f
  87          nop
  88
  89         wrpr            %g0, (PSTATE_PRIV | PSTATE_PEF), %pstate
  90
  91         ldx             [%l0 + HVTRAMP_DESCR_THREAD_REG], %l6
  92
  93         mov             1, %o0
  94         set             1f, %o1
  95         mov             HV_FAST_MMU_ENABLE, %o5
  96         ta              HV_FAST_TRAP
  97
  98         ba,pt           %xcc, 80f
  99          nop
 100
 101 1:
 102         wr              %g0, 0, %fprs
 103         wr              %g0, ASI_P, %asi
 104
 105         mov             PRIMARY_CONTEXT, %g7
 106         stxa            %g0, [%g7] ASI_MMU
 107         membar          #Sync
 108
 109         mov             SECONDARY_CONTEXT, %g7
 110         stxa            %g0, [%g7] ASI_MMU
 111         membar          #Sync
 112
 113         mov             %l6, %g6
 114         ldx             [%g6 + TI_TASK], %g4
 115
 116         mov             1, %g5
 117         sllx            %g5, THREAD_SHIFT, %g5
 118         sub             %g5, (STACKFRAME_SZ + STACK_BIAS), %g5
 119         add             %g6, %g5, %sp
 120         mov             0, %fp
 121
 122         call            init_irqwork_curcpu
 123          nop
 124         call            hard_smp_processor_id
 125          nop
 126
 127         call            sun4v_register_mondo_queues
 128          nop
 129
 130         call            init_cur_cpu_trap
 131          mov            %g6, %o0
 132
 133         wrpr            %g0, (PSTATE_PRIV | PSTATE_PEF | PSTATE_IE), %pstate
 134
 135         call            smp_callin
 136          nop
 137         call            cpu_idle
 138          mov            0, %o0
 139         call            cpu_panic
 140          nop
 141
 142 80:     ba,pt           %xcc, 80b
 143          nop
 144
 145         .align          8
 146 hv_cpu_startup_end: