arch/x86/boot/compressed/vmlinux_64.lds

   1 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
   2 OUTPUT_ARCH(i386:x86-64)
   3 ENTRY(startup_64)
   4 SECTIONS
   5 {
   6         /* Be careful parts of head_64.S assume startup_32 is at
   7          * address 0.
   8          */
   9         . = 0;
  10         .text.head : {
  11                 _head = . ;
  12                 *(.text.head)
  13                 _ehead = . ;
  14         }
  15         .rodata.compressed : {
  16                 *(.rodata.compressed)
  17         }
  18         .text : {
  19                 _text = .;      /* Text */
  20                 *(.text)
  21                 *(.text.*)
  22                 _etext = . ;
  23         }
  24         .rodata : {
  25                 _rodata = . ;
  26                 *(.rodata)       /* read-only data */
  27                 *(.rodata.*)
  28                 _erodata = . ;
  29         }
  30         .data : {
  31                 _data = . ;
  32                 *(.data)
  33                 *(.data.*)
  34                 _edata = . ;
  35         }
  36         .bss : {
  37                 _bss = . ;
  38                 *(.bss)
  39                 *(.bss.*)
  40                 *(COMMON)
  41                 . = ALIGN(8);
  42                 _end = . ;
  43                 . = ALIGN(4096);
  44                 pgtable = . ;
  45                 . = . + 4096 * 6;
  46                 _heap = .;
  47         }
  48 }