CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.16)
   2 if(WIN32)
   3   # Version 3.20 is required for multi-config generator expressions to work
   4   cmake_minimum_required(VERSION 3.20)
   5 endif()
   6 project(kodi LANGUAGES CXX C ASM)
   7
   8 if(POLICY CMP0069)
   9   set(CMAKE_POLICY_DEFAULT_CMP0069 NEW)
  10   cmake_policy(SET CMP0069 NEW)
  11 endif()
  12
  13 # https://cmake.org/cmake/help/latest/policy/CMP0074.html
  14 # find_package() uses <PackageName>_ROOT variables
  15 if(POLICY CMP0074)
  16   set(CMAKE_POLICY_DEFAULT_CMP0074 NEW)
  17   cmake_policy(SET CMP0074 NEW)
  18 endif()
  19
  20 if(POLICY CMP0079)
  21   set(CMAKE_POLICY_DEFAULT_CMP0079 NEW)
  22   cmake_policy(SET CMP0079 NEW)
  23 endif()
  24
  25 if(POLICY CMP0135)
  26   set(CMAKE_POLICY_DEFAULT_CMP0135 NEW)
  27   cmake_policy(SET CMP0135 NEW)
  28 endif()
  29
  30 list(APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 list(APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules/buildtools)
  32 if(DEPENDS_DIR)
  33   list(APPEND CMAKE_PREFIX_PATH ${DEPENDS_DIR})
  34 endif()
  35
  36 # Variable to indicate if the project is targeting a Multi Config Generator (VS/Xcode primarily)
  37 get_property(_multiconfig_generator GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
  38 if(_multiconfig_generator)
  39   # Target to encompass an optional way to build all internal dependencies
  40   # Must set EXCLUDE_FROM_ALL property so the ALL target doesnt include this, and therefore
  41   # build all internal dependencies
  42   add_custom_target(build_internal_depends)
  43   set_target_properties(build_internal_depends PROPERTIES EXCLUDE_FROM_ALL TRUE)
  44 endif()
  45
  46 # Set CORE_BUILD_DIR
  47 set(CORE_BUILD_DIR build)
  48 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  49
  50 # set KODI_MIRROR to the default if not already set
  51 if(NOT DEFINED KODI_MIRROR)
  52   set(KODI_MIRROR "http://mirrors.kodi.tv")
  53 endif()
  54
  55 message(STATUS "Mirror download location: ${KODI_MIRROR}")
  56 message(STATUS "Source directory: ${CMAKE_SOURCE_DIR}")
  57 message(STATUS "Build directory: ${CMAKE_BINARY_DIR}")
  58 if(CMAKE_BINARY_DIR STREQUAL CMAKE_SOURCE_DIR)
  59   message(WARNING "In-source build detected. It is recommended to build out-of-source.")
  60 endif()
  61
  62 # Hide messages from Check*.cmake (e.g. CheckCSourceCompiles)
  63 if(NOT VERBOSE)
  64   set(CMAKE_REQUIRED_QUIET ON)
  65 endif()
  66
  67 # Includes
  68 include(cmake/modules/extra/ECMEnableSanitizers.cmake)
  69 include(cmake/scripts/common/GeneratorSetup.cmake)
  70 include(cmake/scripts/common/AddOptions.cmake)
  71 include(cmake/scripts/common/Platform.cmake)
  72 include(cmake/scripts/common/ArchSetup.cmake)
  73 include(cmake/scripts/common/Macros.cmake)
  74 include(cmake/scripts/common/ProjectMacros.cmake)
  75 core_find_versions()
  76 include(cmake/scripts/common/PathSetup.cmake)
  77 include(cmake/scripts/common/CompilerSettings.cmake)
  78 include(ExternalProject)
  79 include(CMakeDependentOption)
  80 include(cmake/scripts/common/DependencyOptions.cmake)
  81
  82 # general
  83 option(VERBOSE            "Enable verbose output?" OFF)
  84 option(ENABLE_CLANGTIDY   "Enable clang-tidy support?" OFF)
  85 option(ENABLE_CPPCHECK    "Enable cppcheck support?" OFF)
  86 option(ENABLE_DVDCSS      "Enable libdvdcss support?" ON)
  87 option(ENABLE_INCLUDEWHATYOUUSE "Enable include-what-you-use support?" OFF)
  88 option(ENABLE_UPNP        "Enable UPnP support?" ON)
  89 option(ENABLE_AIRTUNES    "Enable AirTunes support?" ON)
  90 option(ENABLE_OPTICAL     "Enable optical support?" ON)
  91 option(ENABLE_PYTHON      "Enable python support?" ON)
  92 option(ENABLE_TESTING     "Enable testing support?" ON)
  93
  94 # Internal Depends - supported on all platforms
  95
  96 # These are required enabled for all CI platforms, and recommended for all builds
  97 option(ENABLE_INTERNAL_CROSSGUID "Enable internal crossguid?" ON)
  98
  99 # use ffmpeg from depends or system
 100 option(ENABLE_INTERNAL_FFMPEG "Enable internal ffmpeg?" OFF)
 101
 102 # These are built for all platforms not using system libs or disabled by user
 103 dependent_option(ENABLE_INTERNAL_CEC "Enable internal libcec?")
 104 dependent_option(ENABLE_INTERNAL_CURL "Enable internal libcurl?")
 105 dependent_option(ENABLE_INTERNAL_EXIV2 "Enable internal exiv2?")
 106 dependent_option(ENABLE_INTERNAL_FLATBUFFERS "Enable internal flatbuffers?")
 107 dependent_option(ENABLE_INTERNAL_FMT "Enable internal fmt?")
 108 dependent_option(ENABLE_INTERNAL_NFS "Enable internal libnfs?")
 109 dependent_option(ENABLE_INTERNAL_PCRE2 "Enable internal pcre2?")
 110 dependent_option(ENABLE_INTERNAL_RapidJSON "Enable internal rapidjson?")
 111
 112 # If ENABLE_INTERNAL_FMT is ON, we force ENABLE_INTERNAL_SPDLOG ON as it has a hard
 113 # dependency on fmt
 114 if(ENABLE_INTERNAL_FMT)
 115   option(ENABLE_INTERNAL_SPDLOG "Enable internal spdlog Forced" ON)
 116 else()
 117   dependent_option(ENABLE_INTERNAL_SPDLOG "Enable internal spdlog?")
 118 endif()
 119
 120 dependent_option(ENABLE_INTERNAL_TAGLIB "Enable internal taglib?")
 121
 122 if(KODI_DEPENDSBUILD OR WIN32 OR WINDOWS_STORE)
 123   dependent_option(ENABLE_INTERNAL_TINYXML2 "Enable internal TinyXML2?")
 124 endif()
 125
 126 # Internal Depends - supported on UNIX platforms
 127 if(UNIX)
 128   option(FFMPEG_PATH        "Path to external ffmpeg?" "")
 129   option(ENABLE_INTERNAL_FSTRCMP "Enable internal fstrcmp?" OFF)
 130   option(ENABLE_INTERNAL_DAV1D "Enable internal dav1d?" OFF)
 131   option(ENABLE_INTERNAL_GTEST "Enable internal gtest?" OFF)
 132   option(ENABLE_INTERNAL_UDFREAD "Enable internal udfread?" OFF)
 133 endif()
 134
 135 # System options
 136 if(NOT WIN32)
 137   option(WITH_ARCH              "build with given arch" OFF)
 138   option(WITH_CPU               "build with given cpu" OFF)
 139 endif()
 140 if(CORE_SYSTEM_NAME STREQUAL linux)
 141   option(ENABLE_EVENTCLIENTS    "Enable event clients support?" OFF)
 142   option(ADDONS_CONFIGURE_AT_STARTUP "Configure binary addons at startup?" ON)
 143 endif()
 144
 145 # Build static libraries per directory
 146 if(NOT CMAKE_GENERATOR MATCHES "Visual Studio" AND NOT CMAKE_GENERATOR STREQUAL Xcode)
 147   set(ENABLE_STATIC_LIBS TRUE)
 148 else()
 149   set(ENABLE_STATIC_LIBS FALSE)
 150 endif()
 151
 152 core_find_git_rev(APP_SCMID FULL)
 153
 154 set(AUDIO_BACKENDS_LIST "" CACHE STRING "Available audio backends")
 155 set(GL_INTERFACES_LIST "" CACHE STRING "Available GL interfaces")
 156
 157 # Dynamically loaded libraries built with the project
 158 add_custom_target(${APP_NAME_LC}-libraries)
 159 set(LIBRARY_FILES "" CACHE STRING "" FORCE)
 160 mark_as_advanced(LIBRARY_FILES)
 161
 162 set(INCLUDES ${CMAKE_SOURCE_DIR}
 163              ${CMAKE_SOURCE_DIR}/lib
 164              ${CMAKE_SOURCE_DIR}/xbmc
 165              ${CMAKE_SOURCE_DIR}/xbmc/${PLATFORM_DIR}
 166              ${CMAKE_SOURCE_DIR}/xbmc/cores/VideoPlayer
 167              ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}
 168              ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/include)
 169
 170 if (NOT PLATFORMDEFS_DIR STREQUAL "")
 171   list(APPEND INCLUDES ${CMAKE_SOURCE_DIR}/xbmc/${PLATFORMDEFS_DIR})
 172 endif()
 173
 174 find_package(PkgConfig)
 175 set(THREADS_PREFER_PTHREAD_FLAG ON)
 176 find_package(Threads REQUIRED QUIET)
 177 list(APPEND DEPLIBS ${CMAKE_THREAD_LIBS_INIT})
 178
 179 # Clean any existing generated build dir cmake files
 180 file(REMOVE ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/ExportFiles.cmake)
 181 file(REMOVE ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/GeneratedPackSkins.cmake)
 182
 183 foreach(depspec ${PLATFORM_REQUIRED_DEPS})
 184   # We need to specify ENABLE_${PLATFORM_REQUIRED_DEPS} in order for the
 185   # optional subdirectory for the specified platform to get built.
 186   split_dependency_specification(${depspec} dep version)
 187   string(TOUPPER ${dep} depup)
 188   if(NOT ${ENABLE_${depup}} STREQUAL AUTO AND NOT ${ENABLE_${depup}})
 189     message(WARNING "Your request to disable the dependency ${dep} required on platform ${CORE_PLATFORM_NAME} was ignored. Please choose another platform or add \"-DENABLE_${depup}=ON\" to your CMake command line to resolve this warning.")
 190   endif()
 191   set(ENABLE_${depup} "ON" CACHE BOOL "Force enabling required ${depup} support" FORCE)
 192 endforeach()
 193
 194 # Required tools. Keep in alphabetical order please
 195 set(required_buildtools FlatC
 196                         JsonSchemaBuilder
 197                         TexturePacker
 198                         ${PLATFORM_REQUIRED_TOOLS}
 199 )
 200
 201 # Optional build tools
 202 set(optional_buildtools CCache
 203                         ClangFormat
 204                         ClangTidy
 205                         Cppcheck
 206                         IncludeWhatYouUse)
 207
 208 # Find build tools - Optional and required
 209 core_optional_dep(${optional_buildtools})
 210 core_require_dep(${required_buildtools})
 211
 212 # We want to explicitly ignore NATIVEPREFIX for any find calls to build target dependencies
 213 if(NATIVEPREFIX)
 214   set(CMAKE_IGNORE_PREFIX_PATH ${NATIVEPREFIX})
 215 endif()
 216
 217 # Required dependencies. Keep in alphabetical order please
 218 set(required_deps ASS>=0.15.0
 219                   Cdio
 220                   CrossGUID
 221                   Curl
 222                   Exiv2
 223                   FFMPEG
 224                   FlatBuffers
 225                   Fmt
 226                   FreeType
 227                   FriBidi
 228                   Fstrcmp
 229                   HarfBuzz
 230                   Iconv
 231                   LibDvd
 232                   Lzo2
 233                   OpenSSL>=1.1.0
 234                   PCRE2
 235                   RapidJSON>=1.0.2
 236                   Spdlog
 237                   Sqlite3
 238                   TagLib>=1.9.0
 239                   TinyXML
 240                   TinyXML2
 241                   ZLIB
 242                   ${PLATFORM_REQUIRED_DEPS})
 243
 244 # Optional dependencies. Keep in alphabetical order please
 245 set(optional_deps Alsa>=1.0.27
 246                   Avahi
 247                   Bluetooth
 248                   Bluray>=0.9.3
 249                   CAP
 250                   CEC>=4.0.0
 251                   Dav1d
 252                   DBus
 253                   Iso9660pp>=2.1.0
 254                   LCMS2>=2.10
 255                   LircClient
 256                   MDNS
 257                   MicroHttpd>=0.9.40
 258                   NFS>=3.0.0
 259                   Pipewire>=0.3.50
 260                   Plist
 261                   PulseAudio>=11.0.0
 262                   Python
 263                   SmbClient
 264                   Sndio
 265                   UDEV
 266                   Udfread
 267                   XSLT
 268                   ${PLATFORM_OPTIONAL_DEPS})
 269
 270 # Remove excluded platform specific optional_deps
 271 foreach(excludedep ${PLATFORM_OPTIONAL_DEPS_EXCLUDE})
 272   list(FILTER optional_deps EXCLUDE REGEX ${excludedep})
 273 endforeach()
 274
 275 # Check optional deps first, since their availability can influence required ones, e.g. ffmpeg
 276 core_optional_dep(${optional_deps})
 277 core_require_dep(${required_deps})
 278
 279 if(ENABLE_MARIADBCLIENT AND NOT ENABLE_MARIADBCLIENT STREQUAL AUTO AND ENABLE_MYSQLCLIENT AND NOT ENABLE_MYSQLCLIENT STREQUAL AUTO)
 280   MESSAGE(FATAL_ERROR "You can not use MySql and MariaDB at the same time. Disable one by adding -DENABLE_MYSQLCLIENT=OFF or -DENABLE_MARIADBCLIENT=OFF.")
 281 elseif(ENABLE_MYSQLCLIENT AND NOT ENABLE_MYSQLCLIENT STREQUAL AUTO)
 282   set(ENABLE_MARIADBCLIENT OFF CACHE BOOL "")
 283 endif()
 284
 285 core_optional_dep(MariaDBClient)
 286 if(NOT TARGET ${APP_NAME_LC}::MariaDBClient)
 287   core_optional_dep(MySqlClient)
 288 endif()
 289
 290 if(NOT TARGET ${APP_NAME_LC}::UDEV)
 291   core_optional_dep(LibUSB)
 292 endif()
 293
 294 if(ENABLE_UPNP)
 295   list(APPEND DEP_DEFINES "-DHAS_UPNP=1")
 296 endif()
 297
 298 if(ENABLE_OPTICAL)
 299   list(APPEND DEP_DEFINES -DHAS_OPTICAL_DRIVE -DHAS_CDDA_RIPPER)
 300 endif()
 301
 302 if(ENABLE_AIRTUNES)
 303   find_package(Shairplay)
 304   if(TARGET ${APP_NAME_LC}::Shairplay)
 305     core_require_dep(Shairplay)
 306   endif()
 307 endif()
 308
 309 # We unset this after the bulk of our find calls are complete. Ideally we would want this enabled
 310 # for anything that is build target related, and only remove for native buildtools, however
 311 # thats more complicated for the need right now.
 312 if(NATIVEPREFIX)
 313   unset(CMAKE_IGNORE_PREFIX_PATH)
 314 endif()
 315
 316 # find all folders containing addon.xml.in
 317 # used to define ADDON_XML_OUTPUTS, ADDON_XML_DEPENDS and ADDON_INSTALL_DATA
 318 # Function defined in ./cmake/scripts/common/Macros.cmake
 319 set(outputFilterRegex "addons/xbmc.json")
 320 find_addon_xml_in_files(${outputFilterRegex})
 321
 322 if(TARGET ${APP_NAME_LC}::Alsa AND TARGET ${APP_NAME_LC}::PulseAudio)
 323   list(APPEND AUDIO_BACKENDS_LIST "alsa+pulseaudio")
 324 endif()
 325
 326 # Compile Info
 327 add_custom_command(OUTPUT ${CORE_BUILD_DIR}/xbmc/CompileInfo.cpp
 328                    COMMAND ${CMAKE_COMMAND} -DCORE_SOURCE_DIR=${CMAKE_SOURCE_DIR}
 329                                             -DCORE_SYSTEM_NAME=${CORE_SYSTEM_NAME}
 330                                             -DCORE_PLATFORM_NAME_LC="${CORE_PLATFORM_NAME_LC}"
 331                                             -DAUDIO_BACKENDS="${AUDIO_BACKENDS_LIST}"
 332                                             -DGL_INTERFACES="${GL_INTERFACES_LIST}"
 333                                             -DCORE_BUILD_DIR=${CORE_BUILD_DIR}
 334                                             -DCMAKE_BINARY_DIR=${CMAKE_BINARY_DIR}
 335                                             -DARCH_DEFINES="${ARCH_DEFINES}"
 336                                             -DAPP_SCMID=${APP_SCMID}
 337                                             -DAPP_COPYRIGHT_YEARS=${APP_COPYRIGHT_YEARS}
 338                                             -DAPP_BUILD_DATE=${APP_BUILD_DATE}
 339                                             -DAPP_SHARED_LIBRARY_SUFFIX="${APP_SHARED_LIBRARY_SUFFIX}"
 340                                             -DPYTHON_VERSION=${PYTHON_VERSION}
 341                                             -Dprefix=${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}
 342                                             -DKODI_WEBSERVER_EXTRA_WHITELIST="${KODI_WEBSERVER_EXTRA_WHITELIST}"
 343                                             -P ${CMAKE_SOURCE_DIR}/cmake/scripts/common/GenerateCompileInfo.cmake
 344                    DEPENDS ${CMAKE_SOURCE_DIR}/version.txt
 345                            ${CMAKE_SOURCE_DIR}/xbmc/CompileInfo.cpp.in)
 346 list(APPEND install_data ${ADDON_INSTALL_DATA})
 347 add_library(compileinfo OBJECT ${CORE_BUILD_DIR}/xbmc/CompileInfo.cpp)
 348 set_target_properties(compileinfo PROPERTIES FOLDER "Build Utilities")
 349 target_compile_options(compileinfo PRIVATE ${SYSTEM_DEFINES} ${ARCH_DEFINES})
 350 target_link_libraries(compileinfo PRIVATE ${APP_NAME_LC}::Fmt)
 351
 352 if(NOT MSVC)
 353   target_compile_options(compileinfo PUBLIC ${CORE_COMPILE_OPTIONS})
 354 endif()
 355
 356 # RC File
 357 if(WIN32)
 358   configure_file(${CMAKE_SOURCE_DIR}/xbmc/platform/win32/XBMC_PC.rc.in
 359                  ${CORE_BUILD_DIR}/xbmc/platform/win32/XBMC_PC.rc @ONLY)
 360   add_library(resources OBJECT ${CORE_BUILD_DIR}/xbmc/platform/win32/XBMC_PC.rc)
 361   set_target_properties(resources PROPERTIES FOLDER "Build Utilities")
 362   target_include_directories(resources PRIVATE ${CMAKE_SOURCE_DIR}/tools/windows/packaging/media)
 363   set(RESOURCES $<TARGET_OBJECTS:resources>)
 364 endif()
 365
 366 # Generate messages
 367 core_add_subdirs_from_filelist(${CMAKE_SOURCE_DIR}/cmake/messages/flatbuffers/*.txt)
 368
 369 include_directories(${INCLUDES})
 370 add_compile_options(${ARCH_DEFINES} "${SYSTEM_DEFINES}" ${DEP_DEFINES} ${PATH_DEFINES})
 371
 372 set(core_DEPENDS "" CACHE STRING "" FORCE)
 373 set(test_archives "" CACHE STRING "" FORCE)
 374 set(test_sources "" CACHE STRING "" FORCE)
 375 mark_as_advanced(core_DEPENDS)
 376 mark_as_advanced(test_archives)
 377 mark_as_advanced(test_sources)
 378
 379 # copy files to build tree
 380 copy_files_from_filelist_to_buildtree(${CMAKE_SOURCE_DIR}/cmake/installdata/common/*.txt
 381                                       ${CMAKE_SOURCE_DIR}/cmake/installdata/${CORE_SYSTEM_NAME}/*.txt)
 382
 383 list(APPEND SKINS "${CMAKE_SOURCE_DIR}/addons/skin.estuary\;${CMAKE_SOURCE_DIR}")
 384
 385 if(NOT ${CORE_SYSTEM_NAME} MATCHES "windows")
 386   file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/system/players/VideoPlayer)
 387 endif()
 388
 389 if(NOT CORE_SYSTEM_NAME STREQUAL windows AND NOT CORE_SYSTEM_NAME STREQUAL android AND NOT CORE_SYSTEM_NAME STREQUAL windowsstore)
 390   configure_file(${CMAKE_SOURCE_DIR}/xbmc/DllPaths_generated.h.in
 391                  ${CORE_BUILD_DIR}/DllPaths_generated.h @ONLY)
 392 elseif(CORE_SYSTEM_NAME STREQUAL android)
 393   configure_file(${CMAKE_SOURCE_DIR}/xbmc/DllPaths_generated_android.h.in
 394                  ${CORE_BUILD_DIR}/DllPaths_generated_android.h @ONLY)
 395 endif()
 396
 397 # main library (used for main binary and tests)
 398 if(CORE_SYSTEM_NAME STREQUAL "darwin_embedded")
 399   # $<TARGET_OBJECTS:> as at 3.26.4 provides incorrect paths for ios/tvos platforms
 400   # Even if XCODE_EMIT_EFFECTIVE_PLATFORM_NAME global property is used, the xcode project
 401   # still sets int dir paths to $(CONFIGURATION)$(EFFECTIVE_PLATFORM_NAME) and the generator
 402   # expression only provides a path using $(CONFIGURATION)
 403   add_library(compileinfo_obj OBJECT IMPORTED)
 404   set_property(TARGET compileinfo_obj PROPERTY IMPORTED_OBJECTS
 405     "${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/compileinfo.build/$(CONFIGURATION)$(EFFECTIVE_PLATFORM_NAME)/$(OBJECT_FILE_DIR_normal:base)/$(CURRENT_ARCH)/CompileInfo.o"
 406   )
 407   add_library(lib${APP_NAME_LC} STATIC)
 408   add_dependencies(lib${APP_NAME_LC} compileinfo)
 409   target_link_libraries(lib${APP_NAME_LC} PUBLIC compileinfo_obj)
 410 else()
 411   add_library(lib${APP_NAME_LC} STATIC $<TARGET_OBJECTS:compileinfo>)
 412 endif()
 413 set_target_properties(lib${APP_NAME_LC} PROPERTIES PREFIX "")
 414
 415 # Other files (IDE)
 416 set(OTHER_FILES cmake/README.md)
 417
 418 # Subdirs
 419 foreach(CORE_PLATFORM_LC ${CORE_PLATFORM_NAME_LC})
 420   core_add_subdirs_from_filelist(${CMAKE_SOURCE_DIR}/cmake/treedata/common/${CORE_PLATFORM_LC}/*.txt
 421                                  ${CMAKE_SOURCE_DIR}/cmake/treedata/${CORE_SYSTEM_NAME}/${CORE_PLATFORM_LC}/*.txt)
 422 endforeach()
 423
 424 core_add_subdirs_from_filelist(${CMAKE_SOURCE_DIR}/cmake/treedata/common/*.txt
 425                                ${CMAKE_SOURCE_DIR}/cmake/treedata/${CORE_SYSTEM_NAME}/*.txt)
 426 core_add_optional_subdirs_from_filelist(${CMAKE_SOURCE_DIR}/cmake/treedata/optional/common/*.txt
 427                                         ${CMAKE_SOURCE_DIR}/cmake/treedata/optional/${CORE_SYSTEM_NAME}/*.txt)
 428
 429 # core_DEPENDS: these are the artifact/object files of /xbmc/*
 430 # SYSTEM_LDFLAGS: system linker flags
 431 # DEPLIBS: system libraries for linking
 432 target_link_libraries(lib${APP_NAME_LC} PUBLIC ${core_DEPENDS} ${SYSTEM_LDFLAGS} ${DEPLIBS} ${CMAKE_DL_LIBS})
 433 core_target_link_libraries(lib${APP_NAME_LC})
 434 set_target_properties(lib${APP_NAME_LC} PROPERTIES PROJECT_LABEL "xbmc")
 435 source_group_by_folder(lib${APP_NAME_LC} RELATIVE ${CMAKE_SOURCE_DIR}/xbmc)
 436 if(WIN32)
 437   add_precompiled_header(lib${APP_NAME_LC} pch.h ${CMAKE_SOURCE_DIR}/xbmc/platform/win32/pch.cpp)
 438 endif()
 439
 440 # main binary
 441 if(NOT CORE_SYSTEM_NAME STREQUAL android)
 442   if(CORE_SYSTEM_NAME STREQUAL windowsstore)
 443     winstore_add_target_properties(${APP_NAME_LC})
 444   endif()
 445   add_executable(${APP_NAME_LC} ${CORE_MAIN_SOURCE} "${RESOURCES}" ${OTHER_FILES})
 446   set_target_properties(${APP_NAME_LC} PROPERTIES ENABLE_EXPORTS ON)
 447 else()
 448   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined")
 449   add_library(${APP_NAME_LC} SHARED ${CORE_MAIN_SOURCE} "${RESOURCES}" ${OTHER_FILES})
 450
 451   # Statically resolve global references to shared library (ie. ffmpeg) definitions.
 452   # Related to https://stackoverflow.com/questions/46307266/including-objects-to-a-shared-library-from-a-c-archive-a
 453   set_target_properties(${APP_NAME_LC} PROPERTIES LINK_FLAGS "-Wl,-Bsymbolic")
 454 endif()
 455 add_dependencies(${APP_NAME_LC} ${APP_NAME_LC}-libraries)
 456
 457 whole_archive(_MAIN_LIBRARIES ${core_DEPENDS})
 458 target_link_libraries(${APP_NAME_LC} ${_MAIN_LIBRARIES} lib${APP_NAME_LC} ${DEPLIBS})
 459 unset(_MAIN_LIBRARIES)
 460
 461 if(${CORE_SYSTEM_NAME} MATCHES "windows")
 462   set(_bundle_dir $<TARGET_FILE_DIR:${APP_NAME_LC}>)
 463 else()
 464   set(_bundle_dir ${CMAKE_BINARY_DIR})
 465 endif()
 466
 467 # These are skins that are copied into place from the source tree
 468 set(XBT_SOURCE_FILELIST "")
 469 foreach(skin ${SKINS})
 470   list(GET skin 0 dir)
 471   list(GET skin 1 relative)
 472   copy_skin_to_buildtree(${dir} ${relative})
 473 endforeach()
 474
 475 # Generate system addons
 476 add_custom_target(gen_system_addons
 477                     COMMAND ${CMAKE_COMMAND} -DCORE_SOURCE_DIR=${CMAKE_SOURCE_DIR}
 478                                              -DCORE_SYSTEM_NAME=${CORE_SYSTEM_NAME}
 479                                              -DCORE_PLATFORM_NAME_LC="${CORE_PLATFORM_NAME_LC}"
 480                                              -DCORE_BUILD_DIR=${CORE_BUILD_DIR}
 481                                              -DCMAKE_BINARY_DIR=${CMAKE_BINARY_DIR}
 482                                              -DBUNDLEDIR=${_bundle_dir}
 483                                              -P ${CMAKE_SOURCE_DIR}/cmake/scripts/common/GenerateSystemAddons.cmake
 484                     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 485
 486 if(_multiconfig_generator)
 487   # Generator expressions in add_custom_command(OUTPUT) are only available in cmake 3.20+
 488   # we dont really need config aware locations for a single config generator, so we only
 489   # set this for multi config generators who all use newer cmake
 490   set(CONFIG_VAR $<CONFIG>)
 491 endif()
 492
 493 # Pack skins and copy to correct build dir (MultiConfig Generator aware)
 494 add_custom_command(
 495   OUTPUT ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/${CONFIG_VAR}/gen_skin.timestamp
 496   COMMAND ${CMAKE_COMMAND} -DBUNDLEDIR=${_bundle_dir}
 497                            -DTEXTUREPACKER_EXECUTABLE=$<TARGET_FILE:TexturePacker::TexturePacker::Executable>
 498                            -P ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/GeneratedPackSkins.cmake
 499   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/${CONFIG_VAR}
 500   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/${CONFIG_VAR}/gen_skin.timestamp
 501   DEPENDS ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/GeneratedPackSkins.cmake
 502           ${XBT_SOURCE_FILELIST}
 503   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 504   COMMENT "Generating skin xbt"
 505 )
 506 add_custom_target(gen_skin_pack DEPENDS ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/${CONFIG_VAR}/gen_skin.timestamp)
 507
 508 # Packaging target. This generates system addon, xbt creation, copy files to build tree
 509 add_custom_target(generate-packaging ALL
 510                   DEPENDS TexturePacker::TexturePacker::Executable export-files gen_skin_pack gen_system_addons)
 511
 512 core_target_add_dependencies(export-files)
 513
 514 # Add to lib${APP_NAME_LC} solely for Win UWP. msix building doesnt seem to pick up the
 515 # generated buildtree if we do it later. Other platforms dont care when this happens.
 516 add_dependencies(lib${APP_NAME_LC} generate-packaging)
 517
 518 set_target_properties(generate-packaging PROPERTIES FOLDER "Build Utilities")
 519
 520 if(WIN32)
 521   set_target_properties(${APP_NAME_LC} PROPERTIES WIN32_EXECUTABLE ON)
 522   set_property(DIRECTORY PROPERTY VS_STARTUP_PROJECT ${APP_NAME_LC})
 523   if(NOT CORE_SYSTEM_NAME STREQUAL windowsstore)
 524     target_sources(${APP_NAME_LC} PRIVATE ${CMAKE_SOURCE_DIR}/xbmc/platform/win32/app.manifest)
 525   else()
 526     set_target_properties(${APP_NAME_LC} PROPERTIES VS_USER_PROPS ${VCPROJECT_PROPS_FILE}
 527                           VS_WINDOWS_TARGET_PLATFORM_MIN_VERSION ${VS_MINIMUM_SDK_VERSION})
 528   endif()
 529 elseif(CORE_SYSTEM_NAME STREQUAL android)
 530   # Nothing
 531 elseif(CORE_SYSTEM_NAME STREQUAL darwin_embedded OR CORE_SYSTEM_NAME STREQUAL osx)
 532   # Build all apple app target as bundled and dont sign.
 533   # We do all signing post build of the app target manually
 534   set_target_properties(${APP_NAME_LC} PROPERTIES OUTPUT_NAME ${APP_NAME}
 535                                                   MACOSX_BUNDLE YES
 536                                                   MACOSX_BUNDLE_INFO_PLIST ${PLATFORM_BUNDLE_INFO_PLIST}
 537                                                   XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
 538                                                   XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "")
 539 else()
 540   set_target_properties(${APP_NAME_LC} PROPERTIES SUFFIX ${APP_BINARY_SUFFIX})
 541 endif()
 542
 543 # testing
 544 if(HOST_CAN_EXECUTE_TARGET AND ENABLE_TESTING)
 545   find_package(Gtest 1.10.0 REQUIRED)
 546
 547   copy_files_from_filelist_to_buildtree(${CMAKE_SOURCE_DIR}/cmake/installdata/test-reference-data.txt NO_INSTALL)
 548   add_executable(${APP_NAME_LC}-test EXCLUDE_FROM_ALL ${CMAKE_SOURCE_DIR}/xbmc/test/xbmc-test.cpp ${test_sources})
 549
 550   set_target_properties(PROPERTIES ENABLE_EXPORTS ON)
 551
 552   whole_archive(_TEST_LIBRARIES ${core_DEPENDS} ${GTEST_LIBRARY})
 553   target_link_libraries(${APP_NAME_LC}-test PRIVATE ${SYSTEM_LDFLAGS} ${_TEST_LIBRARIES} lib${APP_NAME_LC} ${DEPLIBS} ${CMAKE_DL_LIBS})
 554   unset(_TEST_LIBRARIES)
 555
 556   if (ENABLE_INTERNAL_GTEST)
 557     add_dependencies(${APP_NAME_LC}-test ${APP_NAME_LC}-libraries generate-packaging gtest)
 558   endif()
 559
 560   # Enable unit-test related targets
 561   enable_testing()
 562   gtest_add_tests(${APP_NAME_LC}-test "" ${test_sources})
 563   add_custom_target(check ${CMAKE_CTEST_COMMAND} WORKING_DIRECTORY ${PROJECT_BINARY_DIR})
 564   add_dependencies(check ${APP_NAME_LC}-test)
 565
 566   # Valgrind (memcheck)
 567   find_program(VALGRIND_EXECUTABLE NAMES valgrind)
 568   if(VALGRIND_EXECUTABLE)
 569     set(CTEST_MEMORYCHECK_COMMAND ${VALGRIND_EXECUTABLE})
 570     set(CTEST_MEMORYCHECK_COMMAND_OPTIONS "-q --trace-children=yes --leak-check=yes --track-origins=yes")
 571     include(CTest)
 572     add_custom_target(check-valgrind ${CMAKE_CTEST_COMMAND} -D ExperimentalMemCheck \${ARGS} WORKING_DIRECTORY ${PROJECT_BINARY_DIR})
 573     add_dependencies(check-valgrind ${APP_NAME_LC}-test)
 574   endif()
 575
 576   # For testing commit series
 577   add_custom_target(check-commits ${CMAKE_COMMAND} -P ${CMAKE_SOURCE_DIR}/cmake/scripts/common/CheckCommits.cmake
 578                                                    -DCMAKE_BINARY_DIR=${CMAKE_BINARY_DIR})
 579   set_target_properties(check-commits PROPERTIES FOLDER "Build Utilities")
 580
 581   include(${CMAKE_SOURCE_DIR}/cmake/scripts/common/StaticAnalysis.cmake)
 582
 583   # code coverage
 584   if(CMAKE_BUILD_TYPE STREQUAL Coverage)
 585     if(EXISTS ${CMAKE_SOURCE_DIR}/cmake/scripts/${CORE_SYSTEM_NAME}/CodeCoverage.cmake)
 586       include(${CMAKE_SOURCE_DIR}/cmake/scripts/${CORE_SYSTEM_NAME}/CodeCoverage.cmake)
 587     else()
 588       message(FATAL_ERROR "Code coverage not (yet) implemented for platform ${CORE_SYSTEM_NAME}")
 589     endif()
 590   endif()
 591 endif()
 592
 593 # Documentation
 594 find_package(Doxygen)
 595 if(DOXYGEN_FOUND)
 596   add_custom_target(doc
 597                     COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_SOURCE_DIR}/docs/doxygen/Doxyfile.doxy
 598                     COMMAND ${CMAKE_COMMAND} -E echo "Documentation built to: file://${CMAKE_SOURCE_DIR}/docs/html/index.html"
 599                     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/docs/doxygen
 600                     COMMENT "Generating Doxygen documentation" VERBATIM)
 601 endif()
 602
 603 # link wrapper
 604 if(FFMPEG_LINK_EXECUTABLE)
 605   set(CMAKE_CXX_LINK_EXECUTABLE "${FFMPEG_LINK_EXECUTABLE}")
 606 endif()
 607 if(FFMPEG_CREATE_SHARED_LIBRARY)
 608   set(CMAKE_CXX_CREATE_SHARED_LIBRARY "${FFMPEG_CREATE_SHARED_LIBRARY}")
 609 endif()
 610
 611 # Platform specific additional extra targets
 612 if(EXISTS ${CMAKE_SOURCE_DIR}/cmake/scripts/${CORE_SYSTEM_NAME}/ExtraTargets.cmake)
 613   include(${CMAKE_SOURCE_DIR}/cmake/scripts/${CORE_SYSTEM_NAME}/ExtraTargets.cmake)
 614 endif()
 615
 616 include(cmake/scripts/${CORE_SYSTEM_NAME}/Install.cmake)
 617
 618 # Add uninstall target
 619 if(CMAKE_GENERATOR MATCHES Makefile)
 620   add_custom_target(uninstall COMMAND ${CMAKE_COMMAND} -P ${CMAKE_SOURCE_DIR}/cmake/scripts/common/Uninstall.cmake)
 621   set_target_properties(uninstall PROPERTIES FOLDER "Build Utilities")
 622 endif()
 623
 624 # Create target that allows to build binary-addons.
 625 # Use make binary-addons ADDONS="visualization.spectrum" to select the addons to build.
 626 if(CMAKE_GENERATOR STREQUAL "Unix Makefiles")
 627   if(CMAKE_CROSSCOMPILING)
 628     set(_cross_args CROSS_COMPILING=yes)
 629   endif()
 630   if(NOT CORE_SYSTEM_NAME STREQUAL android)
 631     set(_prefix ${CMAKE_BINARY_DIR}/addons)
 632     set(_extra "CMAKE_EXTRA=-DPACKAGE_ZIP=ON")
 633   else()
 634     set(_prefix ${CMAKE_INSTALL_PREFIX})
 635   endif()
 636   add_custom_target(binary-addons
 637     COMMAND $(MAKE) -C ${CMAKE_SOURCE_DIR}/tools/depends/target/binary-addons clean
 638     COMMAND $(MAKE) -C ${CMAKE_SOURCE_DIR}/tools/depends/target/binary-addons VERBOSE=1 V=99
 639                     PREFIX=${_prefix} INSTALL_PREFIX=${_prefix} ${_cross_args} ${_extra})
 640   unset(_cross_args)
 641   unset(_prefix)
 642 endif()
 643
 644 # Prepare add-on build env
 645 include(${CORE_SOURCE_DIR}/xbmc/addons/AddonBindings.cmake)
 646 file(COPY ${CORE_ADDON_BINDINGS_FILES} ${CORE_ADDON_BINDINGS_DIRS}/
 647      DESTINATION ${CORE_BUILD_DIR}/include/${APP_NAME_LC}
 648      REGEX ".txt" EXCLUDE)
 649
 650 set(APP_LIB_DIR ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/lib/${APP_NAME_LC})
 651 set(APP_INCLUDE_DIR ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/include/${APP_NAME_LC})
 652 configure_file(${CMAKE_SOURCE_DIR}/cmake/KodiConfig.cmake.in
 653                ${CORE_BUILD_DIR}/lib/${APP_NAME_LC}/${APP_NAME}Config.cmake @ONLY)
 654 configure_file(${CMAKE_SOURCE_DIR}/cmake/scripts/common/AddonHelpers.cmake
 655                ${CORE_BUILD_DIR}/lib/${APP_NAME_LC}/AddonHelpers.cmake COPYONLY)
 656 configure_file(${CMAKE_SOURCE_DIR}/cmake/scripts/common/AddOptions.cmake
 657                ${CORE_BUILD_DIR}/lib/${APP_NAME_LC}/AddOptions.cmake COPYONLY)
 658
 659 # Status
 660 message(STATUS "#---- CONFIGURATION ----#")
 661 foreach(msg ${final_message})
 662   message(STATUS ${msg})
 663 endforeach()
 664
 665 if(VERBOSE)
 666   message(STATUS "\n#--------------- Internal Variables -------------#")
 667   message(STATUS "DEPLIBS: ${DEPLIBS}")
 668   message(STATUS "core_DEPENDS: ${core_DEPENDS}")
 669   message(STATUS "#---------------------------------------------#")
 670   message(STATUS "SYSTEM_LDFLAGS        : ${SYSTEM_LDFLAGS}")
 671   message(STATUS "CMAKE_DL_LIBS         : ${CMAKE_DL_LIBS}")
 672   message(STATUS "CMAKE_C_FLAGS         : ${CMAKE_C_FLAGS}")
 673   message(STATUS "CMAKE_CXX_FLAGS       : ${CMAKE_CXX_FLAGS}")
 674   message(STATUS "CMAKE_EXE_LINKER_FLAGS: ${CMAKE_EXE_LINKER_FLAGS}")
 675   message(STATUS "LTO_OPTIMIZATION      : ${CMAKE_INTERPROCEDURAL_OPTIMIZATION}")
 676   if(CMAKE_INTERPROCEDURAL_OPTIMIZATION)
 677     message(STATUS "CMAKE_CXX_COMPILE_OPTIONS_IPO: ${CMAKE_CXX_COMPILE_OPTIONS_IPO}")
 678     message(STATUS "CMAKE_C_COMPILE_OPTIONS_IPO  : ${CMAKE_C_COMPILE_OPTIONS_IPO}")
 679     message(STATUS "CMAKE_AR                     : ${CMAKE_AR}")
 680     message(STATUS "CMAKE_NM                     : ${CMAKE_NM}")
 681     message(STATUS "CMAKE_LINKER                 : ${CMAKE_LINKER}")
 682   endif()
 683   message(STATUS "#---------------------------------------------#")
 684   message(STATUS "bindir     : ${bindir}")
 685   message(STATUS "includedir : ${includedir}")
 686   message(STATUS "libdir     : ${libdir}")
 687   message(STATUS "datarootdir: ${datarootdir}")
 688   message(STATUS "#---------------------------------------------#")
 689   message(STATUS "BINARY: ${APP_NAME_LC}${APP_BINARY_SUFFIX}")
 690   message(STATUS "#---------------------------------------------#")
 691   message(STATUS "GIT_REV: ${APP_SCMID}")
 692   message(STATUS "Build date: ${APP_BUILD_DATE}")
 693   message(STATUS "#---------------------------------------------#")
 694   message(STATUS "CPACK_GENERATOR       : ${CPACK_GENERATOR}")
 695   message(STATUS "CPACK_SOURCE_GENERATOR: ${CPACK_SOURCE_GENERATOR}")
 696   message(STATUS "#---------------------------------------------#")
 697 endif()