cmake/modules/FindCEC.cmake

   1 #.rst:
   2 # FindCEC
   3 # -------
   4 # Finds the libCEC library
   5 #
   6 # This will define the following variables::
   7 #
   8 # CEC_FOUND - system has libCEC
   9 # CEC_INCLUDE_DIRS - the libCEC include directory
  10 # CEC_LIBRARIES - the libCEC libraries
  11 # CEC_DEFINITIONS - the libCEC compile definitions
  12 #
  13 # and the following imported targets::
  14 #
  15 #   CEC::CEC   - The libCEC library
  16
  17 if(PKG_CONFIG_FOUND)
  18   pkg_check_modules(PC_CEC libcec QUIET)
  19 endif()
  20
  21 find_path(CEC_INCLUDE_DIR NAMES libcec/cec.h libCEC/CEC.h
  22                           PATHS ${PC_CEC_INCLUDEDIR})
  23
  24 if(PC_CEC_VERSION)
  25   set(CEC_VERSION ${PC_CEC_VERSION})
  26 elseif(CEC_INCLUDE_DIR AND EXISTS "${CEC_INCLUDE_DIR}/libcec/version.h")
  27   file(STRINGS "${CEC_INCLUDE_DIR}/libcec/version.h" cec_version_str REGEX "^[\t ]+LIBCEC_VERSION_TO_UINT\\(.*\\)")
  28   string(REGEX REPLACE "^[\t ]+LIBCEC_VERSION_TO_UINT\\(([0-9]+), ([0-9]+), ([0-9]+)\\)" "\\1.\\2.\\3" CEC_VERSION "${cec_version_str}")
  29   unset(cec_version_str)
  30 endif()
  31
  32 if(NOT CEC_FIND_VERSION)
  33   set(CEC_FIND_VERSION 4.0.0)
  34 endif()
  35
  36 find_library(CEC_LIBRARY NAMES cec
  37                          PATHS ${PC_CEC_LIBDIR})
  38
  39 include(FindPackageHandleStandardArgs)
  40 find_package_handle_standard_args(CEC
  41                                   REQUIRED_VARS CEC_LIBRARY CEC_INCLUDE_DIR
  42                                   VERSION_VAR CEC_VERSION)
  43
  44 if(CEC_FOUND)
  45   set(CEC_LIBRARIES ${CEC_LIBRARY})
  46   set(CEC_INCLUDE_DIRS ${CEC_INCLUDE_DIR})
  47   set(CEC_DEFINITIONS -DHAVE_LIBCEC=1)
  48
  49   if(NOT TARGET CEC::CEC)
  50     add_library(CEC::CEC UNKNOWN IMPORTED)
  51     if(CEC_LIBRARY)
  52       set_target_properties(CEC::CEC PROPERTIES
  53                                      IMPORTED_LOCATION "${CEC_LIBRARY}")
  54     endif()
  55     set_target_properties(CEC::CEC PROPERTIES
  56                                    INTERFACE_INCLUDE_DIRECTORIES "${CEC_INCLUDE_DIR}"
  57                                    INTERFACE_COMPILE_DEFINITIONS HAVE_LIBCEC=1)
  58   endif()
  59 endif()
  60
  61 mark_as_advanced(CEC_INCLUDE_DIR CEC_LIBRARY)