cmake/modules/FindFreeType.cmake

   1 #.rst:
   2 # FindFreetype
   3 # ------------
   4 # Finds the FreeType library
   5 #
   6 # This will define the following variables::
   7 #
   8 # FREETYPE_FOUND - system has FreeType
   9 # FREETYPE_INCLUDE_DIRS - the FreeType include directory
  10 # FREETYPE_LIBRARIES - the FreeType libraries
  11 #
  12 # and the following imported targets::
  13 #
  14 #   FreeType::FreeType   - The FreeType library
  15
  16 if(PKG_CONFIG_FOUND)
  17   pkg_check_modules(PC_FREETYPE freetype2 QUIET)
  18 endif()
  19
  20 find_path(FREETYPE_INCLUDE_DIR NAMES freetype/freetype.h freetype.h
  21                                PATHS ${PC_FREETYPE_INCLUDEDIR}
  22                                      ${PC_FREETYPE_INCLUDE_DIRS}
  23                                PATH_SUFFIXES freetype2)
  24 find_library(FREETYPE_LIBRARY NAMES freetype freetype246MT
  25                               PATHS ${PC_FREETYPE_LIBDIR})
  26
  27 set(FREETYPE_VERSION ${PC_FREETYPE_VERSION})
  28
  29 include(FindPackageHandleStandardArgs)
  30 find_package_handle_standard_args(FreeType
  31                                   REQUIRED_VARS FREETYPE_LIBRARY FREETYPE_INCLUDE_DIR
  32                                   VERSION_VAR FREETYPE_VERSION)
  33
  34 if(FREETYPE_FOUND)
  35   set(FREETYPE_LIBRARIES ${FREETYPE_LIBRARY})
  36   set(FREETYPE_INCLUDE_DIRS ${FREETYPE_INCLUDE_DIR})
  37
  38   if(NOT TARGET FreeType::FreeType)
  39     add_library(FreeType::FreeType UNKNOWN IMPORTED)
  40     set_target_properties(FreeType::FreeType PROPERTIES
  41                                              IMPORTED_LOCATION "${FREETYPE_LIBRARY}"
  42                                              INTERFACE_INCLUDE_DIRECTORIES "${FREETYPE_INCLUDE_DIR}")
  43   endif()
  44 endif()
  45
  46 mark_as_advanced(FREETYPE_INCLUDE_DIR FREETYPE_LIBRARY)