cmake/modules/FindPulseAudio.cmake

   1 #.rst:
   2 # FindPulseAudio
   3 # --------------
   4 # Finds the PulseAudio library
   5 #
   6 # This will define the following variables::
   7 #
   8 #  PULSEAUDIO_FOUND - system has the PulseAudio library
   9 #  PULSEAUDIO_INCLUDE_DIRS - the PulseAudio include directory
  10 #  PULSEAUDIO_LIBRARIES - the libraries needed to use PulseAudio
  11 #  PULSEAUDIO_DEFINITIONS - the definitions needed to use PulseAudio
  12 #
  13 # and the following imported targets::
  14 #
  15 #   PulseAudio::PulseAudio   - The PulseAudio library
  16
  17 if(PKG_CONFIG_FOUND)
  18   pkg_check_modules(PC_PULSEAUDIO libpulse>=11.0.0 QUIET)
  19   pkg_check_modules(PC_PULSEAUDIO_MAINLOOP libpulse-mainloop-glib>=11.0.0 QUIET)
  20   pkg_check_modules(PC_PULSEAUDIO_SIMPLE libpulse-simple>=11.0.0 QUIET)
  21 endif()
  22
  23 find_path(PULSEAUDIO_INCLUDE_DIR NAMES pulse/pulseaudio.h pulse/simple.h
  24                                  PATHS ${PC_PULSEAUDIO_INCLUDEDIR} ${PC_PULSEAUDIO_INCLUDE_DIRS})
  25
  26 find_library(PULSEAUDIO_LIBRARY NAMES pulse libpulse
  27                                 PATHS ${PC_PULSEAUDIO_LIBDIR} ${PC_PULSEAUDIO_LIBRARY_DIRS})
  28
  29 find_library(PULSEAUDIO_SIMPLE_LIBRARY NAMES pulse-simple libpulse-simple
  30                                 PATHS ${PC_PULSEAUDIO_LIBDIR} ${PC_PULSEAUDIO_LIBRARY_DIRS})
  31
  32 find_library(PULSEAUDIO_MAINLOOP_LIBRARY NAMES pulse-mainloop pulse-mainloop-glib libpulse-mainloop-glib
  33                                          PATHS ${PC_PULSEAUDIO_LIBDIR} ${PC_PULSEAUDIO_LIBRARY_DIRS})
  34
  35 if(PC_PULSEAUDIO_VERSION)
  36   set(PULSEAUDIO_VERSION_STRING ${PC_PULSEAUDIO_VERSION})
  37 elseif(PULSEAUDIO_INCLUDE_DIR AND EXISTS "${PULSEAUDIO_INCLUDE_DIR}/pulse/version.h")
  38   file(STRINGS "${PULSEAUDIO_INCLUDE_DIR}/pulse/version.h" pulseaudio_version_str REGEX "^#define[\t ]+pa_get_headers_version\\(\\)[\t ]+\\(\".*\"\\).*")
  39   string(REGEX REPLACE "^#define[\t ]+pa_get_headers_version\\(\\)[\t ]+\\(\"([^\"]+)\"\\).*" "\\1" PULSEAUDIO_VERSION_STRING "${pulseaudio_version_str}")
  40   unset(pulseaudio_version_str)
  41 endif()
  42
  43 include(FindPackageHandleStandardArgs)
  44 find_package_handle_standard_args(PulseAudio
  45                                   REQUIRED_VARS PULSEAUDIO_LIBRARY PULSEAUDIO_MAINLOOP_LIBRARY PULSEAUDIO_SIMPLE_LIBRARY PULSEAUDIO_INCLUDE_DIR
  46                                   VERSION_VAR PULSEAUDIO_VERSION_STRING)
  47
  48 if(PULSEAUDIO_FOUND)
  49   set(PULSEAUDIO_INCLUDE_DIRS ${PULSEAUDIO_INCLUDE_DIR})
  50   set(PULSEAUDIO_LIBRARIES ${PULSEAUDIO_LIBRARY} ${PULSEAUDIO_MAINLOOP_LIBRARY} ${PULSEAUDIO_SIMPLE_LIBRARY})
  51   set(PULSEAUDIO_DEFINITIONS -DHAS_PULSEAUDIO=1)
  52
  53   if(NOT TARGET PulseAudio::PulseAudioMainloop)
  54     add_library(PulseAudio::PulseAudioMainloop UNKNOWN IMPORTED)
  55     set_target_properties(PulseAudio::PulseAudioMainloop PROPERTIES
  56                                                          IMPORTED_LOCATION "${PULSEAUDIO_MAINLOOP_LIBRARY}")
  57   endif()
  58   if(NOT TARGET PulseAudio::PulseAudio)
  59     add_library(PulseAudio::PulseAudio UNKNOWN IMPORTED)
  60     set_target_properties(PulseAudio::PulseAudio PROPERTIES
  61                                                  IMPORTED_LOCATION "${PULSEAUDIO_LIBRARY}"
  62                                                  INTERFACE_INCLUDE_DIRECTORIES "${PULSEAUDIO_INCLUDE_DIR}"
  63                                                  INTERFACE_COMPILE_DEFINITIONS HAVE_LIBPULSE=1
  64                                                  INTERFACE_LINK_LIBRARIES PulseAudio::PulseAudioMainloop)
  65   endif()
  66 endif()
  67
  68 mark_as_advanced(PULSEAUDIO_INCLUDE_DIR PULSEAUDIO_LIBRARY PULSEAUDIO_MAINLOOP_LIBRARY PULSEAUDIO_SIMPLE_LIBRARY)