cmake/modules/FindUdfread.cmake

   1 #.rst:
   2 # FindUdfread
   3 # --------
   4 # Finds the udfread library
   5 #
   6 # This will define the following variables::
   7 #
   8 # UDFREAD_FOUND - system has udfread
   9 # UDFREAD_INCLUDE_DIRS - the udfread include directory
  10 # UDFREAD_LIBRARIES - the udfread libraries
  11 # UDFREAD_DEFINITIONS - the udfread definitions
  12
  13 if(ENABLE_INTERNAL_UDFREAD)
  14   include(cmake/scripts/common/ModuleHelpers.cmake)
  15
  16   set(MODULE_LC udfread)
  17
  18   SETUP_BUILD_VARS()
  19
  20   set(UDFREAD_VERSION ${${MODULE}_VER})
  21
  22   set(CONFIGURE_COMMAND autoreconf -vif &&
  23                         ./configure
  24                         --enable-static
  25                         --disable-shared
  26                         --prefix=${DEPENDS_PATH})
  27   set(BUILD_IN_SOURCE 1)
  28
  29   BUILD_DEP_TARGET()
  30
  31   set_property(GLOBAL APPEND PROPERTY INTERNAL_DEPS_PROP udfread)
  32 else()
  33   if(PKG_CONFIG_FOUND)
  34     pkg_search_module(PC_UDFREAD QUIET libudfread>=1.0.0 udfread>=1.0.0)
  35   endif()
  36
  37   find_path(UDFREAD_INCLUDE_DIR NAMES udfread/udfread.h
  38                             PATHS ${PC_UDFREAD_INCLUDEDIR})
  39
  40   find_library(UDFREAD_LIBRARY NAMES udfread libudfread
  41                            PATHS ${PC_UDFREAD_LIBDIR})
  42
  43   set(UDFREAD_VERSION ${PC_UDFREAD_VERSION})
  44 endif()
  45
  46 include(FindPackageHandleStandardArgs)
  47 find_package_handle_standard_args(Udfread
  48                                   REQUIRED_VARS UDFREAD_LIBRARY UDFREAD_INCLUDE_DIR
  49                                   VERSION_VAR UDFREAD_VERSION)
  50
  51 if(UDFREAD_FOUND)
  52   set(UDFREAD_LIBRARIES ${UDFREAD_LIBRARY})
  53   set(UDFREAD_INCLUDE_DIRS ${UDFREAD_INCLUDE_DIR})
  54   set(UDFREAD_DEFINITIONS -DHAS_UDFREAD=1)
  55 endif()
  56
  57 mark_as_advanced(UDFREAD_INCLUDE_DIR UDFREAD_LIBRARY)