cmake/modules/FindAcbAPI.cmake

   1 #.rst:
   2 # FindAcbAPI
   3 # --------
   4 # Finds the AcbAPI library
   5 #
   6 # This will define the following target:
   7 #
   8 #   ${APP_NAME_LC}::AcbAPI   - The acbAPI library
   9
  10 if(NOT TARGET ${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME})
  11   find_package(PkgConfig)
  12   if(PKG_CONFIG_FOUND)
  13     pkg_check_modules(PC_ACBAPI libAcbAPI QUIET)
  14   endif()
  15
  16   find_path(ACBAPI_INCLUDE_DIR NAMES appswitching-control-block/AcbAPI.h
  17                                HINTS ${PC_ACBAPI_INCLUDEDIR}
  18                                NO_CACHE)
  19   find_library(ACBAPI_LIBRARY NAMES AcbAPI
  20                               HINTS ${PC_ACBAPI_LIBDIR}
  21                               NO_CACHE)
  22
  23   set(ACBAPI_VERSION ${PC_ACBAPI_VERSION})
  24
  25   include(FindPackageHandleStandardArgs)
  26   find_package_handle_standard_args(AcbAPI
  27                                     REQUIRED_VARS ACBAPI_LIBRARY ACBAPI_INCLUDE_DIR
  28                                     VERSION_VAR ACBAPI_VERSION)
  29
  30   if(ACBAPI_FOUND)
  31     add_library(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} UNKNOWN IMPORTED)
  32     set_target_properties(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} PROPERTIES
  33                                                                      IMPORTED_LOCATION "${ACBAPI_LIBRARY}"
  34                                                                      INTERFACE_INCLUDE_DIRECTORIES "${ACBAPI_INCLUDE_DIR}")
  35
  36     # creates an empty library to install on webOS 5+ devices
  37     file(TOUCH dummy.c)
  38     add_library(AcbAPI SHARED dummy.c)
  39     set_target_properties(AcbAPI PROPERTIES VERSION 1.0.0 SOVERSION 1)
  40   else()
  41     if(AcbAPI_FIND_REQUIRED)
  42       message(FATAL_ERROR "AcbAPI libraries were not found.")
  43     endif()
  44   endif()
  45 endif()