cmake/modules/FindFreeType.cmake

   1 #.rst:
   2 # FindFreetype
   3 # ------------
   4 # Finds the FreeType library
   5 #
   6 # This will define the following target:
   7 #
   8 #   ${APP_NAME_LC}::FreeType   - The FreeType library
   9
  10 if(NOT TARGET ${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME})
  11   find_package(PkgConfig)
  12   # Do not use pkgconfig on windows
  13   if(PKG_CONFIG_FOUND AND NOT (WIN32 OR WINDOWS_STORE))
  14     pkg_check_modules(PC_FREETYPE freetype2 QUIET)
  15   endif()
  16
  17   find_path(FREETYPE_INCLUDE_DIR NAMES freetype/freetype.h freetype.h
  18                                  HINTS ${DEPENDS_PATH}/include
  19                                        ${PC_FREETYPE_INCLUDEDIR}
  20                                        ${PC_FREETYPE_INCLUDE_DIRS}
  21                                  PATH_SUFFIXES freetype2
  22                                  ${${CORE_PLATFORM_LC}_SEARCH_CONFIG})
  23   find_library(FREETYPE_LIBRARY NAMES freetype freetype246MT
  24                                 HINTS ${DEPENDS_PATH}/lib ${PC_FREETYPE_LIBDIR}
  25                                 ${${CORE_PLATFORM_LC}_SEARCH_CONFIG})
  26
  27   set(FREETYPE_VERSION ${PC_FREETYPE_VERSION})
  28
  29   include(FindPackageHandleStandardArgs)
  30   find_package_handle_standard_args(FreeType
  31                                     REQUIRED_VARS FREETYPE_LIBRARY FREETYPE_INCLUDE_DIR
  32                                     VERSION_VAR FREETYPE_VERSION)
  33
  34   if(FREETYPE_FOUND)
  35     add_library(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} UNKNOWN IMPORTED)
  36     set_target_properties(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} PROPERTIES
  37                                                                      IMPORTED_LOCATION "${FREETYPE_LIBRARY}"
  38                                                                      INTERFACE_INCLUDE_DIRECTORIES "${FREETYPE_INCLUDE_DIR}")
  39   else()
  40     if(Freetype_FIND_REQUIRED)
  41       message(FATAL_ERROR "Freetype libraries were not found.")
  42     endif()
  43   endif()
  44 endif()